acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 4; then
 137        if test "$version" = 4 && test "$patchlevel" -le 3; then
 138           : # Linux 4.x
 139        else
 140           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.3.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 143        : # Linux 3.x
 144     else
 145        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 146     fi
 147     if (test ! -e "$KBUILD"/include/linux/version.h && \
 148         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 149        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 150         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 151         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 152     fi
 153     OVS_CHECK_LINUX_COMPAT
 154   fi
 155   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 156 ])
 157
 158 dnl OVS_CHECK_DPDK
 159 dnl
 160 dnl Configure DPDK source tree
 161 AC_DEFUN([OVS_CHECK_DPDK], [
 162   AC_ARG_WITH([dpdk],
 163               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 164                               [Specify the DPDK build directory])],
 165               [have_dpdk=true])
 166
 167   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 168   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 169     AC_MSG_RESULT([no])
 170     DPDKLIB_FOUND=false
 171   else
 172     AC_MSG_RESULT([yes])
 173     case "$with_dpdk" in
 174       yes)
 175         DPDK_AUTO_DISCOVER="true"
 176         DPDK_INCLUDE="/usr/local/include/dpdk -I/usr/include/dpdk"
 177         ;;
 178       *)
 179         DPDK_AUTO_DISCOVER="false"
 180         DPDK_INCLUDE="$with_dpdk/include"
 181         # If 'with_dpdk' is passed install directory, point to headers
 182         # installed in $DESTDIR/$prefix/include/dpdk
 183         AC_CHECK_FILE([$DPDK_INCLUDE/rte_config.h], [],
 184                       [AC_CHECK_FILE([$DPDK_INCLUDE/dpdk/rte_config.h],
 185                                      [DPDK_INCLUDE=$DPDK_INCLUDE/dpdk], [])])
 186         DPDK_LIB_DIR="$with_dpdk/lib"
 187         ;;
 188     esac
 189
 190     DPDK_LIB="-ldpdk"
 191     DPDK_EXTRA_LIB=""
 192
 193     ovs_save_CFLAGS="$CFLAGS"
 194     ovs_save_LDFLAGS="$LDFLAGS"
 195     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 196     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 197       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 198     fi
 199
 200     AC_COMPILE_IFELSE([
 201       AC_LANG_PROGRAM(
 202         [
 203           #include <rte_config.h>
 204 #if !RTE_LIBRTE_VHOST_USER
 205 #error
 206 #endif
 207         ], [])
 208       ], [],
 209       [AC_DEFINE([VHOST_CUSE], [1], [DPDK vhost-cuse support enabled, vhost-user disabled.])
 210        DPDK_EXTRA_LIB="-lfuse"])
 211
 212     AC_SEARCH_LIBS([get_mempolicy],[numa],[],[AC_MSG_ERROR([unable to find libnuma, install the dependency package])])
 213
 214     # On some systems we have to add -ldl to link with dpdk
 215     #
 216     # This code, at first, tries to link without -ldl (""),
 217     # then adds it and tries again.
 218     # Before each attempt the search cache must be unset,
 219     # otherwise autoconf will stick with the old result
 220
 221     DPDKLIB_FOUND=false
 222     save_LIBS=$LIBS
 223     for extras in "" "-ldl"; do
 224         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB -lnuma"
 225         AC_LINK_IFELSE(
 226            [AC_LANG_PROGRAM([#include <rte_config.h>
 227                              #include <rte_eal.h>],
 228                             [int rte_argc; char ** rte_argv;
 229                              rte_eal_init(rte_argc, rte_argv);])],
 230            [DPDKLIB_FOUND=true])
 231         if $DPDKLIB_FOUND; then
 232             break
 233         fi
 234     done
 235
 236     # If linking unsuccessful
 237     if test "$DPDKLIB_FOUND" = "false" ; then
 238       if $DPDK_AUTO_DISCOVER; then
 239         AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
 240       else
 241         AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 242       fi
 243     fi
 244     CFLAGS="$ovs_save_CFLAGS"
 245     LDFLAGS="$ovs_save_LDFLAGS"
 246     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 247       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 248     fi
 249     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE"
 250     OVS_ENABLE_OPTION([-mssse3])
 251
 252     # DPDK pmd drivers are not linked unless --whole-archive is used.
 253     #
 254     # This happens because the rest of the DPDK code doesn't use any symbol in
 255     # the pmd driver objects, and the drivers register themselves using an
 256     # __attribute__((constructor)) function.
 257     #
 258     # These options are specified inside a single -Wl directive to prevent
 259     # autotools from reordering them.
 260     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 261     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 262     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 263   fi
 264
 265   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 266 ])
 267
 268 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 269 dnl
 270 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 271 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 272 dnl <REGEX> translated to uppercase.
 273 AC_DEFUN([OVS_GREP_IFELSE], [
 274   AC_MSG_CHECKING([whether $2 matches in $1])
 275   if test -f $1; then
 276     grep '$2' $1 >/dev/null 2>&1
 277     status=$?
 278     case $status in
 279       0)
 280         AC_MSG_RESULT([yes])
 281         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 282         ;;
 283       1)
 284         AC_MSG_RESULT([no])
 285         $4
 286         ;;
 287       *)
 288         AC_MSG_ERROR([grep exited with status $status])
 289         ;;
 290     esac
 291   else
 292     AC_MSG_RESULT([file not found])
 293     $4
 294   fi
 295 ])
 296
 297 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 298 dnl
 299 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 300 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 301 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 302 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 303 dnl translated to uppercase.
 304 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 305   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 306   if test -f $1; then
 307     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 308     status=$?
 309     case $status in
 310       0)
 311         AC_MSG_RESULT([yes])
 312         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 313         ;;
 314       1)
 315         AC_MSG_RESULT([no])
 316         $5
 317         ;;
 318       *)
 319         AC_MSG_ERROR([grep exited with status $status])
 320         ;;
 321     esac
 322   else
 323     AC_MSG_RESULT([file not found])
 324     $5
 325   fi
 326 ])
 327
 328 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 329 dnl
 330 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 331 dnl the function signature starting from the line matching FUNCTION
 332 dnl and ending with the line containing the closing parenthesis.  If
 333 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 334 dnl IF-MATCH is empty then it defines to
 335 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 336 dnl <REGEX> translated to uppercase.
 337 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 338   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 339   if test -f $1; then
 340     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 341     status=$?
 342     case $status in
 343       0)
 344         AC_MSG_RESULT([yes])
 345         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 346         ;;
 347       1)
 348         AC_MSG_RESULT([no])
 349         $5
 350         ;;
 351       *)
 352         AC_MSG_ERROR([grep exited with status $status])
 353         ;;
 354     esac
 355   else
 356     AC_MSG_RESULT([file not found])
 357     $5
 358   fi
 359 ])
 360
 361 dnl OVS_DEFINE(NAME)
 362 dnl
 363 dnl Defines NAME to 1 in kcompat.h.
 364 AC_DEFUN([OVS_DEFINE], [
 365   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 366 ])
 367
 368 dnl OVS_CHECK_LINUX_COMPAT
 369 dnl
 370 dnl Runs various Autoconf checks on the Linux kernel source in
 371 dnl the directory in $KBUILD.
 372 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 373   rm -f datapath/linux/kcompat.h.new
 374   mkdir -p datapath/linux
 375   : > datapath/linux/kcompat.h.new
 376
 377   echo '#include <linux/version.h>
 378 #ifndef RHEL_RELEASE_CODE
 379 #define RHEL_RELEASE_CODE 0
 380 #define RHEL_RELEASE_VERSION(a, b) 0
 381 #endif' >> datapath/linux/kcompat.h.new
 382
 383   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 384                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 385
 386   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 387                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 388   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 389
 390   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 391   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 392
 393   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 394   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 395   OVS_GREP_IFELSE([$KSRC/nclude/linux/if_ether.h], [inner_eth_hdr])
 396
 397   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 398   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 399   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 400   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 401   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 402
 403   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 404   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 405   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 406                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 407   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 408                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 409
 410   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 411                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 412   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 413                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 414   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 415                         [ip_do_fragment], [net],
 416                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 417   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 418
 419   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 420                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 421   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 422   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 423                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 424   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 425                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 426   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 427   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 428                         [frags_work])
 429   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 430                         [rwlock])
 431   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 432                         [list_evictor])
 433   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 434                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 435
 436   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 437   dnl OVS does not really need ipv6 label field, but its presence signifies that
 438   dnl the stack has all required ipv6 support.
 439   dnl OVS also does not need dst_cache But this dependency allows us to write
 440   dnl much cleaner code.
 441
 442   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 443                         [label],
 444                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 445                                          [iptunnel_pull_offloads],
 446                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 447                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])
 448
 449   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 450                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 451   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 452   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 453   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 454   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 455   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 456   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 457   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 458   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 459   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 460   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 461   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 462   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 463   dnl So check type of tstats.
 464   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 465                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 466   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 467                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 468   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 469   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 470                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 471   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 472
 473   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 474   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 475   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 476                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 477   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 478                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 479
 480   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 481                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 482                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 483   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 484                   [nf_ct_get_tuplepr], [struct.net],
 485                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 486   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 487                   [nf_ct_zone_init])
 488   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 489                   [nf_connlabels_get])
 490   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 491                   [nf_connlabels_get], [int bit],
 492                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 493   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 494                   [nf_ct_frag6_consume_orig])
 495   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 496                   [nf_ct_frag6_output])
 497   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 498   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 499   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 500
 501   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 502   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 503
 504   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 505   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 506   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 507                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 508   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 509
 510   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 511                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 512                                    [rcu_read_lock_held])])
 513   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 514
 515   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 516   # is necessary because some versions of this header remove the
 517   # member but retain the kerneldoc comment that describes it (which
 518   # starts with @).  The brackets must be doubled because of m4
 519   # quoting rules.
 520   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 521                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 522   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 523   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 524   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 525   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 526   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 527   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_scrub_packet.*xnet],
 528                   [OVS_DEFINE([HAVE_SKB_SCRUB_PACKET_XNET])])
 529   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 530   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 531                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 532   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 533                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 534   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 535                   [skb_copy_from_linear_data_offset])
 536   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 537                   [skb_reset_tail_pointer])
 538   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 539   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 540                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 541   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 542   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 543   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 544   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 545   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 546   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 547   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 548   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 549                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 550   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 551   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 552                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 553   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 554                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 555   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 556   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 557   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 558   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 559
 560   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 561                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 562   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 563                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 564   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 565                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 566
 567   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 568   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 569
 570   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 571   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 572
 573   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 574   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 575   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 576   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 577   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 578                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 579   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 580   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 581                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 582
 583   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 584                         [genl_multicast_group], [id])
 585   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 586
 587   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 588   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 589   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 590   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 591   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 592   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 593                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 594   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 595                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 596
 597   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 598   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 599   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 600   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 601   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 602   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 603   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 604   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 605                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 606
 607   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 608
 609   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 610                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 611   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 612   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 613   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 614
 615   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 616
 617   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 618                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 619   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 620                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 621                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 622   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 623   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum])
 624   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 625   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 626                         [gro_receive])
 627
 628   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 629                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 630   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 631                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 632
 633   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 634   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 635   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 636                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 637
 638   if cmp -s datapath/linux/kcompat.h.new \
 639             datapath/linux/kcompat.h >/dev/null 2>&1; then
 640     rm datapath/linux/kcompat.h.new
 641   else
 642     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 643   fi
 644 ])
 645
 646 dnl Checks for net/if_packet.h.
 647 AC_DEFUN([OVS_CHECK_IF_PACKET],
 648   [AC_CHECK_HEADER([net/if_packet.h],
 649                    [HAVE_IF_PACKET=yes],
 650                    [HAVE_IF_PACKET=no])
 651    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 652    if test "$HAVE_IF_PACKET" = yes; then
 653       AC_DEFINE([HAVE_IF_PACKET], [1],
 654                 [Define to 1 if net/if_packet.h is available.])
 655    fi])
 656
 657 dnl Checks for net/if_dl.h.
 658 dnl
 659 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 660 dnl or NetBSD.)
 661 AC_DEFUN([OVS_CHECK_IF_DL],
 662   [AC_CHECK_HEADER([net/if_dl.h],
 663                    [HAVE_IF_DL=yes],
 664                    [HAVE_IF_DL=no])
 665    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 666    if test "$HAVE_IF_DL" = yes; then
 667       AC_DEFINE([HAVE_IF_DL], [1],
 668                 [Define to 1 if net/if_dl.h is available.])
 669
 670       # On these platforms we use libpcap to access network devices.
 671       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 672    fi])
 673
 674 dnl Checks for buggy strtok_r.
 675 dnl
 676 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 677 dnl with optimization that can cause segfaults:
 678 dnl
 679 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 680 AC_DEFUN([OVS_CHECK_STRTOK_R],
 681   [AC_CACHE_CHECK(
 682      [whether strtok_r macro segfaults on some inputs],
 683      [ovs_cv_strtok_r_bug],
 684      [AC_RUN_IFELSE(
 685         [AC_LANG_PROGRAM([#include <stdio.h>
 686                           #include <string.h>
 687                          ],
 688                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 689                            /* Assume bug is present, because relatively minor
 690                               changes in compiler settings (e.g. optimization
 691                               level) can make it crop up. */
 692                            return 1;
 693                            #else
 694                            char string[] = ":::";
 695                            char *save_ptr = (char *) 0xc0ffee;
 696                            char *token1, *token2;
 697                            token1 = strtok_r(string, ":", &save_ptr);
 698                            token2 = strtok_r(NULL, ":", &save_ptr);
 699                            freopen ("/dev/null", "w", stdout);
 700                            printf ("%s %s\n", token1, token2);
 701                            return 0;
 702                            #endif
 703                           ]])],
 704         [ovs_cv_strtok_r_bug=no],
 705         [ovs_cv_strtok_r_bug=yes],
 706         [ovs_cv_strtok_r_bug=yes])])
 707    if test $ovs_cv_strtok_r_bug = yes; then
 708      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 709                [Define if strtok_r macro segfaults on some inputs])
 710    fi
 711 ])
 712
 713 dnl ----------------------------------------------------------------------
 714 dnl These macros are from GNU PSPP, with the following original license:
 715 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 716 dnl This file is free software; the Free Software Foundation
 717 dnl gives unlimited permission to copy and/or distribute it,
 718 dnl with or without modifications, as long as this notice is preserved.
 719
 720 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 721   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 722   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 723     [ovs_save_CFLAGS="$CFLAGS"
 724      dnl Include -Werror in the compiler options, because without -Werror
 725      dnl clang's GCC-compatible compiler driver does not return a failure
 726      dnl exit status even though it complains about options it does not
 727      dnl understand.
 728      dnl
 729      dnl Also, check stderr as gcc exits with status 0 for options
 730      dnl rejected at getopt level.
 731      dnl    % touch /tmp/a.c
 732      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 733      dnl    gcc: unrecognized option '-Qunused-arguments'
 734      dnl    0
 735      dnl    %
 736      CFLAGS="$CFLAGS $WERROR $1"
 737      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
 738      CFLAGS="$ovs_save_CFLAGS"])
 739   if test $ovs_cv_name = yes; then
 740     m4_if([$2], [], [:], [$2])
 741   else
 742     m4_if([$3], [], [:], [$3])
 743   fi
 744 ])
 745
 746 dnl OVS_CHECK_WERROR
 747 dnl
 748 dnl Check whether the C compiler accepts -Werror.
 749 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 750 AC_DEFUN([OVS_CHECK_WERROR],
 751   [WERROR=
 752    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 753
 754 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 755 dnl Check whether the given C compiler OPTION is accepted.
 756 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 757 AC_DEFUN([OVS_CHECK_CC_OPTION],
 758   [AC_REQUIRE([OVS_CHECK_WERROR])
 759    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 760
 761 dnl OVS_ENABLE_OPTION([OPTION])
 762 dnl Check whether the given C compiler OPTION is accepted.
 763 dnl If so, add it to WARNING_FLAGS.
 764 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 765 AC_DEFUN([OVS_ENABLE_OPTION],
 766   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 767    AC_SUBST([WARNING_FLAGS])])
 768
 769 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 770 dnl Check whether the given C compiler OPTION is accepted.
 771 dnl If so, enable the given Automake CONDITIONAL.
 772
 773 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 774 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 775   [OVS_CHECK_CC_OPTION(
 776     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 777    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 778 dnl ----------------------------------------------------------------------
 779
 780 dnl Check for too-old XenServer.
 781 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 782   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 783     [if test -e /etc/redhat-release; then
 784        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 785      fi
 786      if test -z "$ovs_cv_xsversion"; then
 787        ovs_cv_xsversion=none
 788      fi])
 789   case $ovs_cv_xsversion in
 790     none)
 791       ;;
 792
 793     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 794     [[6-9]]* |                           dnl XenServer 6 or later
 795     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 796     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 797     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 798     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 799       ;;
 800
 801     *)
 802       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 803       ;;
 804   esac])
 805
 806 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 807 dnl
 808 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 809 dnl Runs 'if-true' if so, 'if-false' otherwise.
 810 AC_DEFUN([OVS_CHECK_MAKE_IF],
 811   [AC_CACHE_CHECK(
 812      [whether ${MAKE-make} has GNU make \$(if) extension],
 813      [ovs_cv_gnu_make_if],
 814      [cat <<'EOF' > conftest.mk
 815 conftest.out:
 816         echo $(if x,y,z) > conftest.out
 817 .PHONY: all
 818 EOF
 819       rm -f conftest.out
 820       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 821       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 822       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 823       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 824       result=`cat conftest.out`
 825       rm -f conftest.mk conftest.out
 826       if test "X$result" = "Xy"; then
 827         ovs_cv_gnu_make_if=yes
 828       else
 829         ovs_cv_gnu_make_if=no
 830       fi])])
 831
 832 dnl OVS_CHECK_GNU_MAKE
 833 dnl
 834 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 835 dnl only work with GNU make).
 836 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 837   [AC_CACHE_CHECK(
 838      [whether ${MAKE-make} is GNU make],
 839      [ovs_cv_gnu_make],
 840      [rm -f conftest.out
 841       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 842       ${MAKE-make} --version >conftest.out 2>&1
 843       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 844       result=`cat conftest.out`
 845       rm -f conftest.mk conftest.out
 846
 847       case $result in # (
 848         GNU*) ovs_cv_gnu_make=yes ;; # (
 849         *) ovs_cv_gnu_make=no ;;
 850       esac])
 851    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 852
 853 dnl OVS_CHECK_SPARSE_TARGET
 854 dnl
 855 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 856 dnl target for which the code is being built.  This helps it out.
 857 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 858   [AC_CACHE_CHECK(
 859     [target hint for cgcc],
 860     [ac_cv_sparse_target],
 861     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 862        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 863        [x86_64-*], [ac_cv_sparse_target=x86_64],
 864        [ac_cv_sparse_target=other])])
 865    AS_CASE([$ac_cv_sparse_target],
 866      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 867      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 868      [SPARSEFLAGS= CGCCFLAGS=])
 869    AC_SUBST([SPARSEFLAGS])
 870    AC_SUBST([CGCCFLAGS])])
 871
 872 dnl OVS_SPARSE_EXTRA_INCLUDES
 873 dnl
 874 dnl The cgcc script from "sparse" does not search gcc's default
 875 dnl search path. Get the default search path from GCC and pass
 876 dnl them to sparse.
 877 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 878     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 879            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 880
 881 dnl OVS_ENABLE_SPARSE
 882 AC_DEFUN([OVS_ENABLE_SPARSE],
 883   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 884    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 885    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 886    : ${SPARSE=sparse}
 887    AC_SUBST([SPARSE])
 888    AC_CONFIG_COMMANDS_PRE(
 889      [if test $ovs_cv_gnu_make_if = yes; then
 890         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 891       fi])])
 892
 893 dnl OVS_PTHREAD_SET_NAME
 894 dnl
 895 dnl This checks for three known variants of pthreads functions for setting
 896 dnl the name of the current thread:
 897 dnl
 898 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 899 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 900 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 901 dnl
 902 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 903 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 904 dnl provide to it.
 905 dnl
 906 dnl This macro defines:
 907 dnl
 908 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 909 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 910 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 911 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 912   [AC_CHECK_FUNCS([pthread_set_name_np])
 913    if test $ac_cv_func_pthread_set_name_np != yes; then
 914      AC_CACHE_CHECK(
 915        [for pthread_setname_np() variant],
 916        [ovs_cv_pthread_setname_np],
 917        [AC_LINK_IFELSE(
 918          [AC_LANG_PROGRAM([#include <pthread.h>
 919   ], [pthread_setname_np(pthread_self(), "name");])],
 920          [ovs_cv_pthread_setname_np=glibc],
 921          [AC_LINK_IFELSE(
 922            [AC_LANG_PROGRAM([#include <pthread.h>
 923 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 924            [ovs_cv_pthread_setname_np=netbsd],
 925            [ovs_cv_pthread_setname_np=none])])])
 926      case $ovs_cv_pthread_setname_np in # (
 927        glibc)
 928           AC_DEFINE(
 929             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 930             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 931           ;; # (
 932        netbsd)
 933           AC_DEFINE(
 934             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 935             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 936           ;;
 937      esac
 938    fi])
 939
 940 dnl OVS_CHECK_LINUX_HOST.
 941 dnl
 942 dnl Checks whether we're building for a Linux host, based on the presence of
 943 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 944 dnl LINUX based on the result.
 945 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 946   [AC_CACHE_CHECK(
 947      [whether __linux__ is defined],
 948      [ovs_cv_linux],
 949      [AC_COMPILE_IFELSE(
 950         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 951         [ovs_cv_linux=true],
 952         [ovs_cv_linux=false])])
 953    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])