acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        if test "$version" = 3 && test "$patchlevel" -le 11; then
 138           : # Linux 3.x
 139        else
 140          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 3.11.x is not supported])
 141        fi
 142     else
 143        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 144          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 145        else
 146          : # Linux 2.6.x
 147        fi
 148     fi
 149     if (test ! -e "$KBUILD"/include/linux/version.h && \
 150         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 151        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 152         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 153         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 154     fi
 155     OVS_CHECK_LINUX_COMPAT
 156   fi
 157   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 158 ])
 159
 160 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 161 dnl
 162 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 163 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 164 dnl <REGEX> translated to uppercase.
 165 AC_DEFUN([OVS_GREP_IFELSE], [
 166   AC_MSG_CHECKING([whether $2 matches in $1])
 167   if test -f $1; then
 168     grep '$2' $1 >/dev/null 2>&1
 169     status=$?
 170     case $status in
 171       0)
 172         AC_MSG_RESULT([yes])
 173         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 174         ;;
 175       1)
 176         AC_MSG_RESULT([no])
 177         $4
 178         ;;
 179       *)
 180         AC_MSG_ERROR([grep exited with status $status])
 181         ;;
 182     esac
 183   else
 184     AC_MSG_RESULT([file not found])
 185     $4
 186   fi
 187 ])
 188
 189 dnl OVS_DEFINE(NAME)
 190 dnl
 191 dnl Defines NAME to 1 in kcompat.h.
 192 AC_DEFUN([OVS_DEFINE], [
 193   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 194 ])
 195
 196 AC_DEFUN([OVS_CHECK_LOG2_H], [
 197   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 198   if test -e $KSRC/include/linux/log2.h; then
 199     AC_MSG_RESULT([yes])
 200     OVS_DEFINE([HAVE_LOG2_H])
 201   else
 202     AC_MSG_RESULT([no])
 203   fi
 204 ])
 205
 206 dnl OVS_CHECK_LINUX_COMPAT
 207 dnl
 208 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 209 dnl the directory in $KBUILD.
 210 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 211   rm -f datapath/linux/kcompat.h.new
 212   mkdir -p datapath/linux
 213   : > datapath/linux/kcompat.h.new
 214
 215   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 216                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 217
 218   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 219
 220   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 221
 222   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 223
 224   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 225
 226   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 227   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 228   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 229   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 230   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 231   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 232
 233   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 234                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 235                                    [rcu_read_lock_held])])
 236   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 237
 238   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 239   # is necessary because some versions of this header remove the
 240   # member but retain the kerneldoc comment that describes it (which
 241   # starts with @).  The brackets must be doubled because of m4
 242   # quoting rules.
 243   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 244                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 245   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 246   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 247                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 248   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 249                   [skb_copy_from_linear_data_offset])
 250   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 251                   [skb_reset_tail_pointer])
 252   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 253   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 254                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 255   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 256                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 257   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 258                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 259   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 260   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 261   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 262   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 263   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 264   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 265   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 266   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [l4_rxhash])
 267
 268   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 269                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 270   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 271                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 272   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 273                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 274
 275   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 276   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 277
 278   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 279   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 280   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 281   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 282   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 283   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 284   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 285
 286   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 287
 288   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 289                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 290
 291   OVS_GREP_IFELSE([$KSRC/include/linux/percpu.h], [this_cpu_ptr])
 292
 293   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 294                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 295
 296   OVS_CHECK_LOG2_H
 297
 298   if cmp -s datapath/linux/kcompat.h.new \
 299             datapath/linux/kcompat.h >/dev/null 2>&1; then
 300     rm datapath/linux/kcompat.h.new
 301   else
 302     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 303   fi
 304 ])
 305
 306 dnl Checks for net/if_packet.h.
 307 AC_DEFUN([OVS_CHECK_IF_PACKET],
 308   [AC_CHECK_HEADER([net/if_packet.h],
 309                    [HAVE_IF_PACKET=yes],
 310                    [HAVE_IF_PACKET=no])
 311    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 312    if test "$HAVE_IF_PACKET" = yes; then
 313       AC_DEFINE([HAVE_IF_PACKET], [1],
 314                 [Define to 1 if net/if_packet.h is available.])
 315    fi])
 316
 317 dnl Checks for net/if_dl.h.
 318 dnl
 319 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 320 dnl or NetBSD.)
 321 AC_DEFUN([OVS_CHECK_IF_DL],
 322   [AC_CHECK_HEADER([net/if_dl.h],
 323                    [HAVE_IF_DL=yes],
 324                    [HAVE_IF_DL=no])
 325    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 326    if test "$HAVE_IF_DL" = yes; then
 327       AC_DEFINE([HAVE_IF_DL], [1],
 328                 [Define to 1 if net/if_dl.h is available.])
 329
 330       # On these platforms we use libpcap to access network devices.
 331       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 332    fi])
 333
 334 dnl Checks for buggy strtok_r.
 335 dnl
 336 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 337 dnl with optimization that can cause segfaults:
 338 dnl
 339 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 340 AC_DEFUN([OVS_CHECK_STRTOK_R],
 341   [AC_CACHE_CHECK(
 342      [whether strtok_r macro segfaults on some inputs],
 343      [ovs_cv_strtok_r_bug],
 344      [AC_RUN_IFELSE(
 345         [AC_LANG_PROGRAM([#include <stdio.h>
 346                           #include <string.h>
 347                          ],
 348                          [[char string[] = ":::";
 349                            char *save_ptr = (char *) 0xc0ffee;
 350                            char *token1, *token2;
 351                            token1 = strtok_r(string, ":", &save_ptr);
 352                            token2 = strtok_r(NULL, ":", &save_ptr);
 353                            freopen ("/dev/null", "w", stdout);
 354                            printf ("%s %s\n", token1, token2);
 355                            return 0;
 356                           ]])],
 357         [ovs_cv_strtok_r_bug=no],
 358         [ovs_cv_strtok_r_bug=yes],
 359         [ovs_cv_strtok_r_bug=yes])])
 360    if test $ovs_cv_strtok_r_bug = yes; then
 361      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 362                [Define if strtok_r macro segfaults on some inputs])
 363    fi
 364 ])
 365
 366 dnl ----------------------------------------------------------------------
 367 dnl These macros are from GNU PSPP, with the following original license:
 368 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 369 dnl This file is free software; the Free Software Foundation
 370 dnl gives unlimited permission to copy and/or distribute it,
 371 dnl with or without modifications, as long as this notice is preserved.
 372
 373 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 374   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 375   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 376     [ovs_save_CFLAGS="$CFLAGS"
 377      dnl Include -Werror in the compiler options, because without -Werror
 378      dnl clang's GCC-compatible compiler driver does not return a failure
 379      dnl exit status even though it complains about options it does not
 380      dnl understand.
 381      CFLAGS="$CFLAGS $WERROR $1"
 382      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 383      CFLAGS="$ovs_save_CFLAGS"])
 384   if test $ovs_cv_name = yes; then
 385     m4_if([$2], [], [:], [$2])
 386   else
 387     m4_if([$3], [], [:], [$3])
 388   fi
 389 ])
 390
 391 dnl OVS_CHECK_WERROR
 392 dnl
 393 dnl Check whether the C compiler accepts -Werror.
 394 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 395 AC_DEFUN([OVS_CHECK_WERROR],
 396   [WERROR=
 397    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 398
 399 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 400 dnl Check whether the given C compiler OPTION is accepted.
 401 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 402 AC_DEFUN([OVS_CHECK_CC_OPTION],
 403   [AC_REQUIRE([OVS_CHECK_WERROR])
 404    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 405
 406 dnl OVS_ENABLE_OPTION([OPTION])
 407 dnl Check whether the given C compiler OPTION is accepted.
 408 dnl If so, add it to WARNING_FLAGS.
 409 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 410 AC_DEFUN([OVS_ENABLE_OPTION],
 411   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 412    AC_SUBST([WARNING_FLAGS])])
 413
 414 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 415 dnl Check whether the given C compiler OPTION is accepted.
 416 dnl If so, enable the given Automake CONDITIONAL.
 417
 418 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 419 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 420   [OVS_CHECK_CC_OPTION(
 421     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 422    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 423 dnl ----------------------------------------------------------------------
 424
 425 dnl Check for too-old XenServer.
 426 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 427   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 428     [if test -e /etc/redhat-release; then
 429        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 430      fi
 431      if test -z "$ovs_cv_xsversion"; then
 432        ovs_cv_xsversion=none
 433      fi])
 434   case $ovs_cv_xsversion in
 435     none)
 436       ;;
 437
 438     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 439     [[6-9]]* |                           dnl XenServer 6 or later
 440     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 441     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 442     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 443     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 444       ;;
 445
 446     *)
 447       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 448       ;;
 449   esac])
 450
 451 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 452 dnl
 453 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 454 dnl Runs 'if-true' if so, 'if-false' otherwise.
 455 AC_DEFUN([OVS_CHECK_MAKE_IF],
 456   [AC_CACHE_CHECK(
 457      [whether ${MAKE-make} has GNU make \$(if) extension],
 458      [ovs_cv_gnu_make_if],
 459      [cat <<'EOF' > conftest.mk
 460 conftest.out:
 461         echo $(if x,y,z) > conftest.out
 462 .PHONY: all
 463 EOF
 464       rm -f conftest.out
 465       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 466       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 467       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 468       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 469       result=`cat conftest.out`
 470       rm -f conftest.mk conftest.out
 471       if test "X$result" = "Xy"; then
 472         ovs_cv_gnu_make_if=yes
 473       else
 474         ovs_cv_gnu_make_if=no
 475       fi])])
 476
 477 dnl OVS_CHECK_GNU_MAKE
 478 dnl
 479 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 480 dnl only work with GNU make).
 481 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 482   [AC_CACHE_CHECK(
 483      [whether ${MAKE-make} is GNU make],
 484      [ovs_cv_gnu_make],
 485      [rm -f conftest.out
 486       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 487       ${MAKE-make} --version >conftest.out 2>&1
 488       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 489       result=`cat conftest.out`
 490       rm -f conftest.mk conftest.out
 491
 492       case $result in # (
 493         GNU*) ovs_cv_gnu_make=yes ;; # (
 494         *) ovs_cv_gnu_make=no ;;
 495       esac])
 496    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 497
 498 dnl OVS_CHECK_SPARSE_TARGET
 499 dnl
 500 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 501 dnl target for which the code is being built.  This helps it out.
 502 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 503   [AC_CACHE_CHECK(
 504     [target hint for cgcc],
 505     [ac_cv_sparse_target],
 506     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 507        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 508        [x86_64-*], [ac_cv_sparse_target=x86_64],
 509        [ac_cv_sparse_target=other])])
 510    AS_CASE([$ac_cv_sparse_target],
 511      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 512      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 513      [SPARSEFLAGS= CGCCFLAGS=])
 514    AC_SUBST([SPARSEFLAGS])
 515    AC_SUBST([CGCCFLAGS])])
 516
 517 dnl OVS_SPARSE_EXTRA_INCLUDES
 518 dnl
 519 dnl The cgcc script from "sparse" does not search gcc's default
 520 dnl search path. Get the default search path from GCC and pass
 521 dnl them to sparse.
 522 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 523     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 524            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 525
 526 dnl OVS_ENABLE_SPARSE
 527 AC_DEFUN([OVS_ENABLE_SPARSE],
 528   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 529    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 530    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 531    : ${SPARSE=sparse}
 532    AC_SUBST([SPARSE])
 533    AC_CONFIG_COMMANDS_PRE(
 534      [if test $ovs_cv_gnu_make_if = yes; then
 535         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 536       fi])])
 537
 538 dnl OVS_PTHREAD_SET_NAME
 539 dnl
 540 dnl This checks for three known variants of pthreads functions for setting
 541 dnl the name of the current thread:
 542 dnl
 543 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 544 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 545 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 546 dnl
 547 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 548 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 549 dnl provide to it.
 550 dnl
 551 dnl This macro defines:
 552 dnl
 553 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 554 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 555 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 556 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 557   [AC_CHECK_FUNCS([pthread_set_name_np])
 558    if test $ac_cv_func_pthread_set_name_np != yes; then
 559      AC_CACHE_CHECK(
 560        [for pthread_setname_np() variant],
 561        [ovs_cv_pthread_setname_np],
 562        [AC_LINK_IFELSE(
 563          [AC_LANG_PROGRAM([#include <pthread.h>
 564   ], [pthread_setname_np(pthread_self(), "name");])],
 565          [ovs_cv_pthread_setname_np=glibc],
 566          [AC_LINK_IFELSE(
 567            [AC_LANG_PROGRAM([#include <pthread.h>
 568 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 569            [ovs_cv_pthread_setname_np=netbsd],
 570            [ovs_cv_pthread_setname_np=none])])])
 571      case $ovs_cv_pthread_setname_np in # (
 572        glibc)
 573           AC_DEFINE(
 574             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 575             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 576           ;; # (
 577        netbsd)
 578           AC_DEFINE(
 579             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 580             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 581           ;;
 582      esac
 583    fi])