arch/arc/kernel/entry.S

   1 /*
   2  * Low Level Interrupts/Traps/Exceptions(non-TLB) Handling for ARC
   3  *
   4  * Copyright (C) 2004, 2007-2010, 2011-2012 Synopsys, Inc. (www.synopsys.com)
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  * vineetg: May 2011
  11  *  -Userspace unaligned access emulation
  12  *
  13  * vineetg: Feb 2011 (ptrace low level code fixes)
  14  *  -traced syscall return code (r0) was not saved into pt_regs for restoring
  15  *   into user reg-file when traded task rets to user space.
  16  *  -syscalls needing arch-wrappers (mainly for passing sp as pt_regs)
  17  *   were not invoking post-syscall trace hook (jumping directly into
  18  *   ret_from_system_call)
  19  *
  20  * vineetg: Nov 2010:
  21  *  -Vector table jumps (@8 bytes) converted into branches (@4 bytes)
  22  *  -To maintain the slot size of 8 bytes/vector, added nop, which is
  23  *   not executed at runtime.
  24  *
  25  * vineetg: Nov 2009 (Everything needed for TIF_RESTORE_SIGMASK)
  26  *  -do_signal()invoked upon TIF_RESTORE_SIGMASK as well
  27  *  -Wrappers for sys_{,rt_}sigsuspend() nolonger needed as they don't
  28  *   need ptregs anymore
  29  *
  30  * Vineetg: Oct 2009
  31  *  -In a rare scenario, Process gets a Priv-V exception and gets scheduled
  32  *   out. Since we don't do FAKE RTIE for Priv-V, CPU excpetion state remains
  33  *   active (AE bit enabled).  This causes a double fault for a subseq valid
  34  *   exception. Thus FAKE RTIE needed in low level Priv-Violation handler.
  35  *   Instr Error could also cause similar scenario, so same there as well.
  36  *
  37  * Vineetg: March 2009 (Supporting 2 levels of Interrupts)
  38  *
  39  * Vineetg: Aug 28th 2008: Bug #94984
  40  *  -Zero Overhead Loop Context shd be cleared when entering IRQ/EXcp/Trap
  41  *   Normally CPU does this automatically, however when doing FAKE rtie,
  42  *   we need to explicitly do this. The problem in macros
  43  *   FAKE_RET_FROM_EXCPN and FAKE_RET_FROM_EXCPN_LOCK_IRQ was that this bit
  44  *   was being "CLEARED" rather then "SET". Since it is Loop INHIBIT Bit,
  45  *   setting it and not clearing it clears ZOL context
  46  *
  47  * Vineetg: May 16th, 2008
  48  *  - r25 now contains the Current Task when in kernel
  49  *
  50  * Vineetg: Dec 22, 2007
  51  *    Minor Surgery of Low Level ISR to make it SMP safe
  52  *    - MMU_SCRATCH0 Reg used for freeing up r9 in Level 1 ISR
  53  *    - _current_task is made an array of NR_CPUS
  54  *    - Access of _current_task wrapped inside a macro so that if hardware
  55  *       team agrees for a dedicated reg, no other code is touched
  56  *
  57  * Amit Bhor, Rahul Trivedi, Kanika Nema, Sameer Dhavale : Codito Tech 2004
  58  */
  59
  60 /*------------------------------------------------------------------
  61  *    Function                            ABI
  62  *------------------------------------------------------------------
  63  *
  64  *  Arguments                           r0 - r7
  65  *  Caller Saved Registers              r0 - r12
  66  *  Callee Saved Registers              r13- r25
  67  *  Global Pointer (gp)                 r26
  68  *  Frame Pointer (fp)                  r27
  69  *  Stack Pointer (sp)                  r28
  70  *  Interrupt link register (ilink1)    r29
  71  *  Interrupt link register (ilink2)    r30
  72  *  Branch link register (blink)        r31
  73  *------------------------------------------------------------------
  74  */
  75
  76         .cpu A7
  77
  78 ;############################ Vector Table #################################
  79
  80 .macro VECTOR  lbl
  81 #if 1   /* Just in case, build breaks */
  82         j   \lbl
  83 #else
  84         b   \lbl
  85         nop
  86 #endif
  87 .endm
  88
  89         .section .vector, "ax",@progbits
  90         .align 4
  91
  92 /* Each entry in the vector table must occupy 2 words. Since it is a jump
  93  * across sections (.vector to .text) we are gauranteed that 'j somewhere'
  94  * will use the 'j limm' form of the intrsuction as long as somewhere is in
  95  * a section other than .vector.
  96  */
  97
  98 ; ********* Critical System Events **********************
  99 VECTOR   res_service             ; 0x0, Restart Vector  (0x0)
 100 VECTOR   mem_service             ; 0x8, Mem exception   (0x1)
 101 VECTOR   instr_service           ; 0x10, Instrn Error   (0x2)
 102
 103 ; ******************** Device ISRs **********************
 104 #ifdef CONFIG_ARC_IRQ3_LV2
 105 VECTOR   handle_interrupt_level2
 106 #else
 107 VECTOR   handle_interrupt_level1
 108 #endif
 109
 110 VECTOR   handle_interrupt_level1
 111
 112 #ifdef CONFIG_ARC_IRQ5_LV2
 113 VECTOR   handle_interrupt_level2
 114 #else
 115 VECTOR   handle_interrupt_level1
 116 #endif
 117
 118 #ifdef CONFIG_ARC_IRQ6_LV2
 119 VECTOR   handle_interrupt_level2
 120 #else
 121 VECTOR   handle_interrupt_level1
 122 #endif
 123
 124 .rept   25
 125 VECTOR   handle_interrupt_level1 ; Other devices
 126 .endr
 127
 128 /* FOR ARC600: timer = 0x3, uart = 0x8, emac = 0x10 */
 129
 130 ; ******************** Exceptions **********************
 131 VECTOR   EV_MachineCheck         ; 0x100, Fatal Machine check   (0x20)
 132 VECTOR   EV_TLBMissI             ; 0x108, Intruction TLB miss   (0x21)
 133 VECTOR   EV_TLBMissD             ; 0x110, Data TLB miss         (0x22)
 134 VECTOR   EV_TLBProtV             ; 0x118, Protection Violation  (0x23)
 135                                  ;         or Misaligned Access
 136 VECTOR   EV_PrivilegeV           ; 0x120, Privilege Violation   (0x24)
 137 VECTOR   EV_Trap                 ; 0x128, Trap exception        (0x25)
 138 VECTOR   EV_Extension            ; 0x130, Extn Intruction Excp  (0x26)
 139
 140 .rept   24
 141 VECTOR   reserved                ; Reserved Exceptions
 142 .endr
 143
 144 #include <linux/linkage.h>   /* ARC_{EXTRY,EXIT} */
 145 #include <asm/entry.h>       /* SAVE_ALL_{INT1,INT2,SYS...} */
 146 #include <asm/errno.h>
 147 #include <asm/arcregs.h>
 148 #include <asm/irqflags.h>
 149
 150 ;##################### Scratch Mem for IRQ stack switching #############
 151
 152 ARCFP_DATA int1_saved_reg
 153         .align 32
 154         .type   int1_saved_reg, @object
 155         .size   int1_saved_reg, 4
 156 int1_saved_reg:
 157         .zero 4
 158
 159 /* Each Interrupt level needs it's own scratch */
 160 #ifdef CONFIG_ARC_COMPACT_IRQ_LEVELS
 161
 162 ARCFP_DATA int2_saved_reg
 163         .type   int2_saved_reg, @object
 164         .size   int2_saved_reg, 4
 165 int2_saved_reg:
 166         .zero 4
 167
 168 #endif
 169
 170 ; ---------------------------------------------
 171         .section .text, "ax",@progbits
 172
 173 res_service:            ; processor restart
 174         flag    0x1     ; not implemented
 175         nop
 176         nop
 177
 178 reserved:               ; processor restart
 179         rtie            ; jump to processor initializations
 180
 181 ;##################### Interrupt Handling ##############################
 182
 183 #ifdef CONFIG_ARC_COMPACT_IRQ_LEVELS
 184 ; ---------------------------------------------
 185 ;  Level 2 ISR: Can interrupt a Level 1 ISR
 186 ; ---------------------------------------------
 187 ARC_ENTRY handle_interrupt_level2
 188
 189         ; TODO-vineetg for SMP this wont work
 190         ; free up r9 as scratchpad
 191         st  r9, [@int2_saved_reg]
 192
 193         ;Which mode (user/kernel) was the system in when intr occured
 194         lr  r9, [status32_l2]
 195
 196         SWITCH_TO_KERNEL_STK
 197         SAVE_ALL_INT2
 198
 199         ;------------------------------------------------------
 200         ; if L2 IRQ interrupted a L1 ISR, disable preemption
 201         ;------------------------------------------------------
 202
 203         ld r9, [sp, PT_status32]        ; get statu32_l2 (saved in pt_regs)
 204         bbit0 r9, STATUS_A1_BIT, 1f     ; L1 not active when L2 IRQ, so normal
 205
 206         ; A1 is set in status32_l2
 207         ; bump thread_info->preempt_count (Disable preemption)
 208         GET_CURR_THR_INFO_FROM_SP   r10
 209         ld      r9, [r10, THREAD_INFO_PREEMPT_COUNT]
 210         add     r9, r9, 1
 211         st      r9, [r10, THREAD_INFO_PREEMPT_COUNT]
 212
 213 1:
 214         ;------------------------------------------------------
 215         ; setup params for Linux common ISR and invoke it
 216         ;------------------------------------------------------
 217         lr  r0, [icause2]
 218         and r0, r0, 0x1f
 219
 220         bl.d  @arch_do_IRQ
 221         mov r1, sp
 222
 223         mov r8,0x2
 224         sr r8, [AUX_IRQ_LV12]       ; clear bit in Sticky Status Reg
 225
 226         b   ret_from_exception
 227
 228 ARC_EXIT handle_interrupt_level2
 229
 230 #endif
 231
 232 ; ---------------------------------------------
 233 ;  Level 1 ISR
 234 ; ---------------------------------------------
 235 ARC_ENTRY handle_interrupt_level1
 236
 237         /* free up r9 as scratchpad */
 238 #ifdef CONFIG_SMP
 239         sr  r9, [ARC_REG_SCRATCH_DATA0]
 240 #else
 241         st   r9, [@int1_saved_reg]
 242 #endif
 243
 244         ;Which mode (user/kernel) was the system in when intr occured
 245         lr  r9, [status32_l1]
 246
 247         SWITCH_TO_KERNEL_STK
 248         SAVE_ALL_INT1
 249
 250         lr  r0, [icause1]
 251         and r0, r0, 0x1f
 252
 253         bl.d  @arch_do_IRQ
 254         mov r1, sp
 255
 256         mov r8,0x1
 257         sr r8, [AUX_IRQ_LV12]       ; clear bit in Sticky Status Reg
 258
 259         b   ret_from_exception
 260 ARC_EXIT handle_interrupt_level1
 261
 262 ;################### Non TLB Exception Handling #############################
 263
 264 ; ---------------------------------------------
 265 ; Instruction Error Exception Handler
 266 ; ---------------------------------------------
 267
 268 ARC_ENTRY instr_service
 269
 270         EXCPN_PROLOG_FREEUP_REG r9
 271
 272         lr  r9, [erstatus]
 273
 274         SWITCH_TO_KERNEL_STK
 275         SAVE_ALL_SYS
 276
 277         lr  r0, [efa]
 278         mov r1, sp
 279
 280         FAKE_RET_FROM_EXCPN r9
 281
 282         bl  do_insterror_or_kprobe
 283         b   ret_from_exception
 284 ARC_EXIT instr_service
 285
 286 ; ---------------------------------------------
 287 ; Memory Error Exception Handler
 288 ; ---------------------------------------------
 289
 290 ARC_ENTRY mem_service
 291
 292         EXCPN_PROLOG_FREEUP_REG r9
 293
 294         lr  r9, [erstatus]
 295
 296         SWITCH_TO_KERNEL_STK
 297         SAVE_ALL_SYS
 298
 299         lr  r0, [efa]
 300         mov r1, sp
 301         bl  do_memory_error
 302         b   ret_from_exception
 303 ARC_EXIT mem_service
 304
 305 ; ---------------------------------------------
 306 ; Machine Check Exception Handler
 307 ; ---------------------------------------------
 308
 309 ARC_ENTRY EV_MachineCheck
 310
 311         EXCPN_PROLOG_FREEUP_REG r9
 312         lr  r9, [erstatus]
 313
 314         SWITCH_TO_KERNEL_STK
 315         SAVE_ALL_SYS
 316
 317         lr  r2, [ecr]
 318         lr  r0, [efa]
 319         mov r1, sp
 320
 321         lsr     r3, r2, 8
 322         bmsk    r3, r3, 7
 323         brne    r3, ECR_C_MCHK_DUP_TLB, 1f
 324
 325         bl      do_tlb_overlap_fault
 326         b       ret_from_exception
 327
 328 1:
 329         ; DEAD END: can't do much, display Regs and HALT
 330         SAVE_CALLEE_SAVED_USER
 331
 332         GET_CURR_TASK_FIELD_PTR   TASK_THREAD, r10
 333         st  sp, [r10, THREAD_CALLEE_REG]
 334
 335         j  do_machine_check_fault
 336
 337 ARC_EXIT EV_MachineCheck
 338
 339 ; ---------------------------------------------
 340 ; Protection Violation Exception Handler
 341 ; ---------------------------------------------
 342
 343 ARC_ENTRY EV_TLBProtV
 344
 345         EXCPN_PROLOG_FREEUP_REG r9
 346
 347         ;Which mode (user/kernel) was the system in when Exception occured
 348         lr  r9, [erstatus]
 349
 350         SWITCH_TO_KERNEL_STK
 351         SAVE_ALL_SYS
 352
 353         ;---------(3) Save some more regs-----------------
 354         ;  vineetg: Mar 6th: Random Seg Fault issue #1
 355         ;  ecr and efa were not saved in case an Intr sneaks in
 356         ;  after fake rtie
 357         ;
 358         lr  r2, [ecr]
 359         lr  r1, [efa]   ; Faulting Data address
 360
 361         ; --------(4) Return from CPU Exception Mode ---------
 362         ;  Fake a rtie, but rtie to next label
 363         ;  That way, subsequently, do_page_fault ( ) executes in pure kernel
 364         ;  mode with further Exceptions enabled
 365
 366         FAKE_RET_FROM_EXCPN r9
 367
 368         ;------ (5) Type of Protection Violation? ----------
 369         ;
 370         ; ProtV Hardware Exception is triggered for Access Faults of 2 types
 371         ;   -Access Violaton    : 00_23_(00|01|02|03)_00
 372         ;                                x  r  w  r+w
 373         ;   -Unaligned Access   : 00_23_04_00
 374         ;
 375         bbit1 r2, ECR_C_BIT_PROTV_MISALIG_DATA, 4f
 376
 377         ;========= (6a) Access Violation Processing ========
 378         mov r0, sp              ; pt_regs
 379         bl  do_page_fault
 380         b   ret_from_exception
 381
 382         ;========== (6b) Non aligned access ============
 383 4:
 384         mov r0, r1
 385         mov r1, sp              ; pt_regs
 386
 387 #ifdef  CONFIG_ARC_MISALIGN_ACCESS
 388         SAVE_CALLEE_SAVED_USER
 389         mov r2, sp              ; callee_regs
 390
 391         bl  do_misaligned_access
 392
 393         ; TBD: optimize - do this only if a callee reg was involved
 394         ; either a dst of emulated LD/ST or src with address-writeback
 395         RESTORE_CALLEE_SAVED_USER
 396 #else
 397         bl  do_misaligned_error
 398 #endif
 399
 400         b   ret_from_exception
 401
 402 ARC_EXIT EV_TLBProtV
 403
 404 ; ---------------------------------------------
 405 ; Privilege Violation Exception Handler
 406 ; ---------------------------------------------
 407 ARC_ENTRY EV_PrivilegeV
 408
 409         EXCPN_PROLOG_FREEUP_REG r9
 410
 411         lr  r9, [erstatus]
 412
 413         SWITCH_TO_KERNEL_STK
 414         SAVE_ALL_SYS
 415
 416         lr  r0, [efa]
 417         mov r1, sp
 418
 419         FAKE_RET_FROM_EXCPN r9
 420
 421         bl  do_privilege_fault
 422         b   ret_from_exception
 423 ARC_EXIT EV_PrivilegeV
 424
 425 ; ---------------------------------------------
 426 ; Extension Instruction Exception Handler
 427 ; ---------------------------------------------
 428 ARC_ENTRY EV_Extension
 429
 430         EXCPN_PROLOG_FREEUP_REG r9
 431         lr  r9, [erstatus]
 432
 433         SWITCH_TO_KERNEL_STK
 434         SAVE_ALL_SYS
 435
 436         lr  r0, [efa]
 437         mov r1, sp
 438         bl  do_extension_fault
 439         b   ret_from_exception
 440 ARC_EXIT EV_Extension
 441
 442 ;######################### System Call Tracing #########################
 443
 444 tracesys:
 445         ; save EFA in case tracer wants the PC of traced task
 446         ; using ERET won't work since next-PC has already committed
 447         lr  r12, [efa]
 448         GET_CURR_TASK_FIELD_PTR   TASK_THREAD, r11
 449         st  r12, [r11, THREAD_FAULT_ADDR]       ; thread.fault_address
 450
 451         ; PRE Sys Call Ptrace hook
 452         mov r0, sp                      ; pt_regs needed
 453         bl  @syscall_trace_entry
 454
 455         ; Tracing code now returns the syscall num (orig or modif)
 456         mov r8, r0
 457
 458         ; Do the Sys Call as we normally would.
 459         ; Validate the Sys Call number
 460         cmp     r8,  NR_syscalls
 461         mov.hi  r0, -ENOSYS
 462         bhi     tracesys_exit
 463
 464         ; Restore the sys-call args. Mere invocation of the hook abv could have
 465         ; clobbered them (since they are in scratch regs). The tracer could also
 466         ; have deliberately changed the syscall args: r0-r7
 467         ld  r0, [sp, PT_r0]
 468         ld  r1, [sp, PT_r1]
 469         ld  r2, [sp, PT_r2]
 470         ld  r3, [sp, PT_r3]
 471         ld  r4, [sp, PT_r4]
 472         ld  r5, [sp, PT_r5]
 473         ld  r6, [sp, PT_r6]
 474         ld  r7, [sp, PT_r7]
 475         ld.as   r9, [sys_call_table, r8]
 476         jl      [r9]        ; Entry into Sys Call Handler
 477
 478 tracesys_exit:
 479         st  r0, [sp, PT_r0]     ; sys call return value in pt_regs
 480
 481         ;POST Sys Call Ptrace Hook
 482         bl  @syscall_trace_exit
 483         b   ret_from_exception ; NOT ret_from_system_call at is saves r0 which
 484         ; we'd done before calling post hook above
 485
 486 ;################### Break Point TRAP ##########################
 487
 488         ; ======= (5b) Trap is due to Break-Point =========
 489
 490 trap_with_param:
 491
 492         ; stop_pc info by gdb needs this info
 493         lr  r0, [efa]
 494         mov r1, sp
 495
 496         ; Now that we have read EFA, its safe to do "fake" rtie
 497         ;   and get out of CPU exception mode
 498         FAKE_RET_FROM_EXCPN r11
 499
 500         ; Save callee regs in case gdb wants to have a look
 501         ; SP will grow up by size of CALLEE Reg-File
 502         ; NOTE: clobbers r12
 503         SAVE_CALLEE_SAVED_USER
 504
 505         ; save location of saved Callee Regs @ thread_struct->pc
 506         GET_CURR_TASK_FIELD_PTR   TASK_THREAD, r10
 507         st  sp, [r10, THREAD_CALLEE_REG]
 508
 509         ; Call the trap handler
 510         bl  do_non_swi_trap
 511
 512         ; unwind stack to discard Callee saved Regs
 513         DISCARD_CALLEE_SAVED_USER
 514
 515         b   ret_from_exception
 516
 517 ;##################### Trap Handling ##############################
 518 ;
 519 ; EV_Trap caused by TRAP_S and TRAP0 instructions.
 520 ;------------------------------------------------------------------
 521 ;   (1) System Calls
 522 ;       :parameters in r0-r7.
 523 ;       :r8 has the system call number
 524 ;   (2) Break Points
 525 ;------------------------------------------------------------------
 526
 527 ARC_ENTRY EV_Trap
 528
 529         ; Need at least 1 reg to code the early exception prolog
 530         EXCPN_PROLOG_FREEUP_REG r9
 531
 532         ;Which mode (user/kernel) was the system in when intr occured
 533         lr  r9, [erstatus]
 534
 535         SWITCH_TO_KERNEL_STK
 536         SAVE_ALL_SYS
 537
 538         ;------- (4) What caused the Trap --------------
 539         lr     r12, [ecr]
 540         bmsk.f 0, r12, 7
 541         bnz    trap_with_param
 542
 543         ; ======= (5a) Trap is due to System Call ========
 544
 545         ; Before doing anything, return from CPU Exception Mode
 546         FAKE_RET_FROM_EXCPN r11
 547
 548         ; If syscall tracing ongoing, invoke pre-pos-hooks
 549         GET_CURR_THR_INFO_FLAGS   r10
 550         btst r10, TIF_SYSCALL_TRACE
 551         bnz tracesys  ; this never comes back
 552
 553         ;============ This is normal System Call case ==========
 554         ; Sys-call num shd not exceed the total system calls avail
 555         cmp     r8,  NR_syscalls
 556         mov.hi  r0, -ENOSYS
 557         bhi     ret_from_system_call
 558
 559         ; Offset into the syscall_table and call handler
 560         ld.as   r9,[sys_call_table, r8]
 561         jl      [r9]        ; Entry into Sys Call Handler
 562
 563         ; fall through to ret_from_system_call
 564 ARC_EXIT EV_Trap
 565
 566 ARC_ENTRY ret_from_system_call
 567
 568         st  r0, [sp, PT_r0]     ; sys call return value in pt_regs
 569
 570         ; fall through yet again to ret_from_exception
 571
 572 ;############# Return from Intr/Excp/Trap (Linux Specifics) ##############
 573 ;
 574 ; If ret to user mode do we need to handle signals, schedule() et al.
 575
 576 ARC_ENTRY ret_from_exception
 577
 578         ; Pre-{IRQ,Trap,Exception} K/U mode from pt_regs->status32
 579         ld  r8, [sp, PT_status32]   ; returning to User/Kernel Mode
 580
 581         bbit0  r8, STATUS_U_BIT, resume_kernel_mode
 582
 583         ; Before returning to User mode check-for-and-complete any pending work
 584         ; such as rescheduling/signal-delivery etc.
 585 resume_user_mode_begin:
 586
 587         ; Disable IRQs to ensures that chk for pending work itself is atomic
 588         ; (and we don't end up missing a NEED_RESCHED/SIGPENDING due to an
 589         ; interim IRQ).
 590         IRQ_DISABLE     r10
 591
 592         ; Fast Path return to user mode if no pending work
 593         GET_CURR_THR_INFO_FLAGS   r9
 594         and.f  0,  r9, _TIF_WORK_MASK
 595         bz     restore_regs
 596
 597         ; --- (Slow Path #1) task preemption ---
 598         bbit0  r9, TIF_NEED_RESCHED, .Lchk_pend_signals
 599         mov    blink, resume_user_mode_begin  ; tail-call to U mode ret chks
 600         b      @schedule        ; BTST+Bnz causes relo error in link
 601
 602 .Lchk_pend_signals:
 603         IRQ_ENABLE      r10
 604
 605         ; --- (Slow Path #2) pending signal  ---
 606         mov r0, sp      ; pt_regs for arg to do_signal()/do_notify_resume()
 607
 608         bbit0  r9, TIF_SIGPENDING, .Lchk_notify_resume
 609
 610         ; Normal Trap/IRQ entry only saves Scratch (caller-saved) regs
 611         ; in pt_reg since the "C" ABI (kernel code) will automatically
 612         ; save/restore callee-saved regs.
 613         ;
 614         ; However, here we need to explicitly save callee regs because
 615         ; (i)  If this signal causes coredump - full regfile needed
 616         ; (ii) If signal is SIGTRAP/SIGSTOP, task is being traced thus
 617         ;      tracer might call PEEKUSR(CALLEE reg)
 618         ;
 619         ; NOTE: SP will grow up by size of CALLEE Reg-File
 620         SAVE_CALLEE_SAVED_USER          ; clobbers r12
 621
 622         ; save location of saved Callee Regs @ thread_struct->callee
 623         GET_CURR_TASK_FIELD_PTR   TASK_THREAD, r10
 624         st  sp, [r10, THREAD_CALLEE_REG]
 625
 626         bl  @do_signal
 627
 628         ; Ideally we want to discard the Callee reg above, however if this was
 629         ; a tracing signal, tracer could have done a POKEUSR(CALLEE reg)
 630         RESTORE_CALLEE_SAVED_USER
 631
 632         b      resume_user_mode_begin   ; loop back to start of U mode ret
 633
 634         ; --- (Slow Path #3) notify_resume ---
 635 .Lchk_notify_resume:
 636         btst   r9, TIF_NOTIFY_RESUME
 637         blnz   @do_notify_resume
 638         b      resume_user_mode_begin   ; unconditionally back to U mode ret chks
 639                                         ; for single exit point from this block
 640
 641 resume_kernel_mode:
 642
 643 #ifdef CONFIG_PREEMPT
 644
 645         ; Can't preempt if preemption disabled
 646         GET_CURR_THR_INFO_FROM_SP   r10
 647         ld  r8, [r10, THREAD_INFO_PREEMPT_COUNT]
 648         brne  r8, 0, restore_regs
 649
 650         ; check if this task's NEED_RESCHED flag set
 651         ld  r9, [r10, THREAD_INFO_FLAGS]
 652         bbit0  r9, TIF_NEED_RESCHED, restore_regs
 653
 654         IRQ_DISABLE     r9
 655
 656         ; Invoke PREEMPTION
 657         bl      preempt_schedule_irq
 658
 659         ; preempt_schedule_irq() always returns with IRQ disabled
 660 #endif
 661
 662         ; fall through
 663
 664 ;############# Return from Intr/Excp/Trap (ARC Specifics) ##############
 665 ;
 666 ; Restore the saved sys context (common exit-path for EXCPN/IRQ/Trap)
 667 ; IRQ shd definitely not happen between now and rtie
 668
 669 restore_regs :
 670
 671         ; Disable Interrupts while restoring reg-file back
 672         ; XXX can this be optimised out
 673         IRQ_DISABLE_SAVE    r9, r10     ;@r10 has prisitine (pre-disable) copy
 674
 675         ; Restore REG File. In case multiple Events outstanding,
 676         ; use the same priorty as rtie: EXCPN, L2 IRQ, L1 IRQ, None
 677         ; Note that we use realtime STATUS32 (not pt_regs->status32) to
 678         ; decide that.
 679
 680         ; if Returning from Exception
 681         bbit0  r10, STATUS_AE_BIT, not_exception
 682         RESTORE_ALL_SYS
 683         rtie
 684
 685         ; Not Exception so maybe Interrupts (Level 1 or 2)
 686
 687 not_exception:
 688
 689 #ifdef CONFIG_ARC_COMPACT_IRQ_LEVELS
 690
 691         ; Level 2 interrupt return Path - from hardware standpoint
 692         bbit0  r10, STATUS_A2_BIT, not_level2_interrupt
 693
 694         ;------------------------------------------------------------------
 695         ; However the context returning might not have taken L2 intr itself
 696         ; e.g. Task'A' user-code -> L2 intr -> schedule -> 'B' user-code ret
 697         ; Special considerations needed for the context which took L2 intr
 698
 699         ld   r9, [sp, PT_event]        ; Ensure this is L2 intr context
 700         brne r9, event_IRQ2, 149f
 701
 702         ;------------------------------------------------------------------
 703         ; if L2 IRQ interrupted a L1 ISR,  we'd disbaled preemption earlier
 704         ; so that sched doesnt move to new task, causing L1 to be delayed
 705         ; undeterministically. Now that we've achieved that, lets reset
 706         ; things to what they were, before returning from L2 context
 707         ;----------------------------------------------------------------
 708
 709         ld r9, [sp, PT_status32]       ; get statu32_l2 (saved in pt_regs)
 710         bbit0 r9, STATUS_A1_BIT, 149f  ; L1 not active when L2 IRQ, so normal
 711
 712         ; decrement thread_info->preempt_count (re-enable preemption)
 713         GET_CURR_THR_INFO_FROM_SP   r10
 714         ld      r9, [r10, THREAD_INFO_PREEMPT_COUNT]
 715
 716         ; paranoid check, given A1 was active when A2 happened, preempt count
 717         ; must not be 0 because we would have incremented it.
 718         ; If this does happen we simply HALT as it means a BUG !!!
 719         cmp     r9, 0
 720         bnz     2f
 721         flag 1
 722
 723 2:
 724         sub     r9, r9, 1
 725         st      r9, [r10, THREAD_INFO_PREEMPT_COUNT]
 726
 727 149:
 728         ;return from level 2
 729         RESTORE_ALL_INT2
 730 debug_marker_l2:
 731         rtie
 732
 733 not_level2_interrupt:
 734
 735 #endif
 736
 737         bbit0  r10, STATUS_A1_BIT, not_level1_interrupt
 738
 739         ;return from level 1
 740
 741         RESTORE_ALL_INT1
 742 debug_marker_l1:
 743         rtie
 744
 745 not_level1_interrupt:
 746
 747         ;this case is for syscalls or Exceptions (with fake rtie)
 748
 749         RESTORE_ALL_SYS
 750 debug_marker_syscall:
 751         rtie
 752
 753 ARC_EXIT ret_from_exception
 754
 755 ARC_ENTRY ret_from_fork
 756         ; when the forked child comes here from the __switch_to function
 757         ; r0 has the last task pointer.
 758         ; put last task in scheduler queue
 759         bl   @schedule_tail
 760
 761         ; If kernel thread, jump to it's entry-point
 762         ld   r9, [sp, PT_status32]
 763         brne r9, 0, 1f
 764
 765         jl.d [r14]
 766         mov  r0, r13            ; arg to payload
 767
 768 1:
 769         ; special case of kernel_thread entry point returning back due to
 770         ; kernel_execve() - pretend return from syscall to ret to userland
 771         b    ret_from_exception
 772 ARC_EXIT ret_from_fork
 773
 774 ;################### Special Sys Call Wrappers ##########################
 775
 776 ARC_ENTRY sys_clone_wrapper
 777         SAVE_CALLEE_SAVED_USER
 778         bl  @sys_clone
 779         DISCARD_CALLEE_SAVED_USER
 780
 781         GET_CURR_THR_INFO_FLAGS   r10
 782         btst r10, TIF_SYSCALL_TRACE
 783         bnz  tracesys_exit
 784
 785         b ret_from_system_call
 786 ARC_EXIT sys_clone_wrapper
 787
 788 #ifdef CONFIG_ARC_DW2_UNWIND
 789 ; Workaround for bug 94179 (STAR ):
 790 ; Despite -fasynchronous-unwind-tables, linker is not making dwarf2 unwinder
 791 ; section (.debug_frame) as loadable. So we force it here.
 792 ; This also fixes STAR 9000487933 where the prev-workaround (objcopy --setflag)
 793 ; would not work after a clean build due to kernel build system dependencies.
 794 .section .debug_frame, "wa",@progbits
 795 #endif