arch/arm64/kernel/head.S

   1 /*
   2  * Low-level CPU initialisation
   3  * Based on arch/arm/kernel/head.S
   4  *
   5  * Copyright (C) 1994-2002 Russell King
   6  * Copyright (C) 2003-2012 ARM Ltd.
   7  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   8  *              Will Deacon <will.deacon@arm.com>
   9  *
  10  * This program is free software; you can redistribute it and/or modify
  11  * it under the terms of the GNU General Public License version 2 as
  12  * published by the Free Software Foundation.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  21  */
  22
  23 #include <linux/linkage.h>
  24 #include <linux/init.h>
  25
  26 #include <asm/assembler.h>
  27 #include <asm/ptrace.h>
  28 #include <asm/asm-offsets.h>
  29 #include <asm/memory.h>
  30 #include <asm/thread_info.h>
  31 #include <asm/pgtable-hwdef.h>
  32 #include <asm/pgtable.h>
  33 #include <asm/page.h>
  34 #include <asm/virt.h>
  35
  36 /*
  37  * swapper_pg_dir is the virtual address of the initial page table. We place
  38  * the page tables 3 * PAGE_SIZE below KERNEL_RAM_VADDR. The idmap_pg_dir has
  39  * 2 pages and is placed below swapper_pg_dir.
  40  */
  41 #define KERNEL_RAM_VADDR        (PAGE_OFFSET + TEXT_OFFSET)
  42
  43 #if (KERNEL_RAM_VADDR & 0xfffff) != 0x80000
  44 #error KERNEL_RAM_VADDR must start at 0xXXX80000
  45 #endif
  46
  47 #define SWAPPER_DIR_SIZE        (3 * PAGE_SIZE)
  48 #define IDMAP_DIR_SIZE          (2 * PAGE_SIZE)
  49
  50         .globl  swapper_pg_dir
  51         .equ    swapper_pg_dir, KERNEL_RAM_VADDR - SWAPPER_DIR_SIZE
  52
  53         .globl  idmap_pg_dir
  54         .equ    idmap_pg_dir, swapper_pg_dir - IDMAP_DIR_SIZE
  55
  56         .macro  pgtbl, ttb0, ttb1, phys
  57         add     \ttb1, \phys, #TEXT_OFFSET - SWAPPER_DIR_SIZE
  58         sub     \ttb0, \ttb1, #IDMAP_DIR_SIZE
  59         .endm
  60
  61 #ifdef CONFIG_ARM64_64K_PAGES
  62 #define BLOCK_SHIFT     PAGE_SHIFT
  63 #define BLOCK_SIZE      PAGE_SIZE
  64 #else
  65 #define BLOCK_SHIFT     SECTION_SHIFT
  66 #define BLOCK_SIZE      SECTION_SIZE
  67 #endif
  68
  69 #define KERNEL_START    KERNEL_RAM_VADDR
  70 #define KERNEL_END      _end
  71
  72 /*
  73  * Initial memory map attributes.
  74  */
  75 #ifndef CONFIG_SMP
  76 #define PTE_FLAGS       PTE_TYPE_PAGE | PTE_AF
  77 #define PMD_FLAGS       PMD_TYPE_SECT | PMD_SECT_AF
  78 #else
  79 #define PTE_FLAGS       PTE_TYPE_PAGE | PTE_AF | PTE_SHARED
  80 #define PMD_FLAGS       PMD_TYPE_SECT | PMD_SECT_AF | PMD_SECT_S
  81 #endif
  82
  83 #ifdef CONFIG_ARM64_64K_PAGES
  84 #define MM_MMUFLAGS     PTE_ATTRINDX(MT_NORMAL) | PTE_FLAGS
  85 #define IO_MMUFLAGS     PTE_ATTRINDX(MT_DEVICE_nGnRE) | PTE_XN | PTE_FLAGS
  86 #else
  87 #define MM_MMUFLAGS     PMD_ATTRINDX(MT_NORMAL) | PMD_FLAGS
  88 #define IO_MMUFLAGS     PMD_ATTRINDX(MT_DEVICE_nGnRE) | PMD_SECT_XN | PMD_FLAGS
  89 #endif
  90
  91 /*
  92  * Kernel startup entry point.
  93  * ---------------------------
  94  *
  95  * The requirements are:
  96  *   MMU = off, D-cache = off, I-cache = on or off,
  97  *   x0 = physical address to the FDT blob.
  98  *
  99  * This code is mostly position independent so you call this at
 100  * __pa(PAGE_OFFSET + TEXT_OFFSET).
 101  *
 102  * Note that the callee-saved registers are used for storing variables
 103  * that are useful before the MMU is enabled. The allocations are described
 104  * in the entry routines.
 105  */
 106         __HEAD
 107
 108         /*
 109          * DO NOT MODIFY. Image header expected by Linux boot-loaders.
 110          */
 111         b       stext                           // branch to kernel start, magic
 112         .long   0                               // reserved
 113         .quad   TEXT_OFFSET                     // Image load offset from start of RAM
 114         .quad   0                               // reserved
 115         .quad   0                               // reserved
 116
 117 ENTRY(stext)
 118         mov     x21, x0                         // x21=FDT
 119         bl      __calc_phys_offset              // x24=PHYS_OFFSET, x28=PHYS_OFFSET-PAGE_OFFSET
 120         bl      el2_setup                       // Drop to EL1
 121         mrs     x22, midr_el1                   // x22=cpuid
 122         mov     x0, x22
 123         bl      lookup_processor_type
 124         mov     x23, x0                         // x23=current cpu_table
 125         cbz     x23, __error_p                  // invalid processor (x23=0)?
 126         bl      __vet_fdt
 127         bl      __create_page_tables            // x25=TTBR0, x26=TTBR1
 128         /*
 129          * The following calls CPU specific code in a position independent
 130          * manner. See arch/arm64/mm/proc.S for details. x23 = base of
 131          * cpu_info structure selected by lookup_processor_type above.
 132          * On return, the CPU will be ready for the MMU to be turned on and
 133          * the TCR will have been set.
 134          */
 135         ldr     x27, __switch_data              // address to jump to after
 136                                                 // MMU has been enabled
 137         adr     lr, __enable_mmu                // return (PIC) address
 138         ldr     x12, [x23, #CPU_INFO_SETUP]
 139         add     x12, x12, x28                   // __virt_to_phys
 140         br      x12                             // initialise processor
 141 ENDPROC(stext)
 142
 143 /*
 144  * If we're fortunate enough to boot at EL2, ensure that the world is
 145  * sane before dropping to EL1.
 146  */
 147 ENTRY(el2_setup)
 148         mrs     x0, CurrentEL
 149         cmp     x0, #PSR_MODE_EL2t
 150         ccmp    x0, #PSR_MODE_EL2h, #0x4, ne
 151         ldr     x0, =__boot_cpu_mode            // Compute __boot_cpu_mode
 152         add     x0, x0, x28
 153         b.eq    1f
 154         str     wzr, [x0]                       // Remember we don't have EL2...
 155         ret
 156
 157         /* Hyp configuration. */
 158 1:      ldr     w1, =BOOT_CPU_MODE_EL2
 159         str     w1, [x0, #4]                    // This CPU has EL2
 160         mov     x0, #(1 << 31)                  // 64-bit EL1
 161         msr     hcr_el2, x0
 162
 163         /* Generic timers. */
 164         mrs     x0, cnthctl_el2
 165         orr     x0, x0, #3                      // Enable EL1 physical timers
 166         msr     cnthctl_el2, x0
 167         msr     cntvoff_el2, xzr                // Clear virtual offset
 168
 169         /* Populate ID registers. */
 170         mrs     x0, midr_el1
 171         mrs     x1, mpidr_el1
 172         msr     vpidr_el2, x0
 173         msr     vmpidr_el2, x1
 174
 175         /* sctlr_el1 */
 176         mov     x0, #0x0800                     // Set/clear RES{1,0} bits
 177         movk    x0, #0x30d0, lsl #16
 178         msr     sctlr_el1, x0
 179
 180         /* Coprocessor traps. */
 181         mov     x0, #0x33ff
 182         msr     cptr_el2, x0                    // Disable copro. traps to EL2
 183
 184 #ifdef CONFIG_COMPAT
 185         msr     hstr_el2, xzr                   // Disable CP15 traps to EL2
 186 #endif
 187
 188         /* spsr */
 189         mov     x0, #(PSR_F_BIT | PSR_I_BIT | PSR_A_BIT | PSR_D_BIT |\
 190                       PSR_MODE_EL1h)
 191         msr     spsr_el2, x0
 192         msr     elr_el2, lr
 193         eret
 194 ENDPROC(el2_setup)
 195
 196 /*
 197  * We need to find out the CPU boot mode long after boot, so we need to
 198  * store it in a writable variable.
 199  *
 200  * This is not in .bss, because we set it sufficiently early that the boot-time
 201  * zeroing of .bss would clobber it.
 202  */
 203         .pushsection    .data
 204 ENTRY(__boot_cpu_mode)
 205         .long   BOOT_CPU_MODE_EL2
 206         .long   0
 207         .popsection
 208
 209         .align  3
 210 2:      .quad   .
 211         .quad   PAGE_OFFSET
 212
 213 #ifdef CONFIG_SMP
 214         .pushsection    .smp.pen.text, "ax"
 215         .align  3
 216 1:      .quad   .
 217         .quad   secondary_holding_pen_release
 218
 219         /*
 220          * This provides a "holding pen" for platforms to hold all secondary
 221          * cores are held until we're ready for them to initialise.
 222          */
 223 ENTRY(secondary_holding_pen)
 224         bl      __calc_phys_offset              // x24=phys offset
 225         bl      el2_setup                       // Drop to EL1
 226         mrs     x0, mpidr_el1
 227         and     x0, x0, #15                     // CPU number
 228         adr     x1, 1b
 229         ldp     x2, x3, [x1]
 230         sub     x1, x1, x2
 231         add     x3, x3, x1
 232 pen:    ldr     x4, [x3]
 233         cmp     x4, x0
 234         b.eq    secondary_startup
 235         wfe
 236         b       pen
 237 ENDPROC(secondary_holding_pen)
 238         .popsection
 239
 240 ENTRY(secondary_startup)
 241         /*
 242          * Common entry point for secondary CPUs.
 243          */
 244         mrs     x22, midr_el1                   // x22=cpuid
 245         mov     x0, x22
 246         bl      lookup_processor_type
 247         mov     x23, x0                         // x23=current cpu_table
 248         cbz     x23, __error_p                  // invalid processor (x23=0)?
 249
 250         pgtbl   x25, x26, x24                   // x25=TTBR0, x26=TTBR1
 251         ldr     x12, [x23, #CPU_INFO_SETUP]
 252         add     x12, x12, x28                   // __virt_to_phys
 253         blr     x12                             // initialise processor
 254
 255         ldr     x21, =secondary_data
 256         ldr     x27, =__secondary_switched      // address to jump to after enabling the MMU
 257         b       __enable_mmu
 258 ENDPROC(secondary_startup)
 259
 260 ENTRY(__secondary_switched)
 261         ldr     x0, [x21]                       // get secondary_data.stack
 262         mov     sp, x0
 263         mov     x29, #0
 264         b       secondary_start_kernel
 265 ENDPROC(__secondary_switched)
 266 #endif  /* CONFIG_SMP */
 267
 268 /*
 269  * Setup common bits before finally enabling the MMU. Essentially this is just
 270  * loading the page table pointer and vector base registers.
 271  *
 272  * On entry to this code, x0 must contain the SCTLR_EL1 value for turning on
 273  * the MMU.
 274  */
 275 __enable_mmu:
 276         ldr     x5, =vectors
 277         msr     vbar_el1, x5
 278         msr     ttbr0_el1, x25                  // load TTBR0
 279         msr     ttbr1_el1, x26                  // load TTBR1
 280         isb
 281         b       __turn_mmu_on
 282 ENDPROC(__enable_mmu)
 283
 284 /*
 285  * Enable the MMU. This completely changes the structure of the visible memory
 286  * space. You will not be able to trace execution through this.
 287  *
 288  *  x0  = system control register
 289  *  x27 = *virtual* address to jump to upon completion
 290  *
 291  * other registers depend on the function called upon completion
 292  */
 293         .align  6
 294 __turn_mmu_on:
 295         msr     sctlr_el1, x0
 296         isb
 297         br      x27
 298 ENDPROC(__turn_mmu_on)
 299
 300 /*
 301  * Calculate the start of physical memory.
 302  */
 303 __calc_phys_offset:
 304         adr     x0, 1f
 305         ldp     x1, x2, [x0]
 306         sub     x28, x0, x1                     // x28 = PHYS_OFFSET - PAGE_OFFSET
 307         add     x24, x2, x28                    // x24 = PHYS_OFFSET
 308         ret
 309 ENDPROC(__calc_phys_offset)
 310
 311         .align 3
 312 1:      .quad   .
 313         .quad   PAGE_OFFSET
 314
 315 /*
 316  * Macro to populate the PGD for the corresponding block entry in the next
 317  * level (tbl) for the given virtual address.
 318  *
 319  * Preserves:   pgd, tbl, virt
 320  * Corrupts:    tmp1, tmp2
 321  */
 322         .macro  create_pgd_entry, pgd, tbl, virt, tmp1, tmp2
 323         lsr     \tmp1, \virt, #PGDIR_SHIFT
 324         and     \tmp1, \tmp1, #PTRS_PER_PGD - 1 // PGD index
 325         orr     \tmp2, \tbl, #3                 // PGD entry table type
 326         str     \tmp2, [\pgd, \tmp1, lsl #3]
 327         .endm
 328
 329 /*
 330  * Macro to populate block entries in the page table for the start..end
 331  * virtual range (inclusive).
 332  *
 333  * Preserves:   tbl, flags
 334  * Corrupts:    phys, start, end, pstate
 335  */
 336         .macro  create_block_map, tbl, flags, phys, start, end, idmap=0
 337         lsr     \phys, \phys, #BLOCK_SHIFT
 338         .if     \idmap
 339         and     \start, \phys, #PTRS_PER_PTE - 1        // table index
 340         .else
 341         lsr     \start, \start, #BLOCK_SHIFT
 342         and     \start, \start, #PTRS_PER_PTE - 1       // table index
 343         .endif
 344         orr     \phys, \flags, \phys, lsl #BLOCK_SHIFT  // table entry
 345         .ifnc   \start,\end
 346         lsr     \end, \end, #BLOCK_SHIFT
 347         and     \end, \end, #PTRS_PER_PTE - 1           // table end index
 348         .endif
 349 9999:   str     \phys, [\tbl, \start, lsl #3]           // store the entry
 350         .ifnc   \start,\end
 351         add     \start, \start, #1                      // next entry
 352         add     \phys, \phys, #BLOCK_SIZE               // next block
 353         cmp     \start, \end
 354         b.ls    9999b
 355         .endif
 356         .endm
 357
 358 /*
 359  * Setup the initial page tables. We only setup the barest amount which is
 360  * required to get the kernel running. The following sections are required:
 361  *   - identity mapping to enable the MMU (low address, TTBR0)
 362  *   - first few MB of the kernel linear mapping to jump to once the MMU has
 363  *     been enabled, including the FDT blob (TTBR1)
 364  */
 365 __create_page_tables:
 366         pgtbl   x25, x26, x24                   // idmap_pg_dir and swapper_pg_dir addresses
 367
 368         /*
 369          * Clear the idmap and swapper page tables.
 370          */
 371         mov     x0, x25
 372         add     x6, x26, #SWAPPER_DIR_SIZE
 373 1:      stp     xzr, xzr, [x0], #16
 374         stp     xzr, xzr, [x0], #16
 375         stp     xzr, xzr, [x0], #16
 376         stp     xzr, xzr, [x0], #16
 377         cmp     x0, x6
 378         b.lo    1b
 379
 380         ldr     x7, =MM_MMUFLAGS
 381
 382         /*
 383          * Create the identity mapping.
 384          */
 385         add     x0, x25, #PAGE_SIZE             // section table address
 386         adr     x3, __turn_mmu_on               // virtual/physical address
 387         create_pgd_entry x25, x0, x3, x5, x6
 388         create_block_map x0, x7, x3, x5, x5, idmap=1
 389
 390         /*
 391          * Map the kernel image (starting with PHYS_OFFSET).
 392          */
 393         add     x0, x26, #PAGE_SIZE             // section table address
 394         mov     x5, #PAGE_OFFSET
 395         create_pgd_entry x26, x0, x5, x3, x6
 396         ldr     x6, =KERNEL_END - 1
 397         mov     x3, x24                         // phys offset
 398         create_block_map x0, x7, x3, x5, x6
 399
 400         /*
 401          * Map the FDT blob (maximum 2MB; must be within 512MB of
 402          * PHYS_OFFSET).
 403          */
 404         mov     x3, x21                         // FDT phys address
 405         and     x3, x3, #~((1 << 21) - 1)       // 2MB aligned
 406         mov     x6, #PAGE_OFFSET
 407         sub     x5, x3, x24                     // subtract PHYS_OFFSET
 408         tst     x5, #~((1 << 29) - 1)           // within 512MB?
 409         csel    x21, xzr, x21, ne               // zero the FDT pointer
 410         b.ne    1f
 411         add     x5, x5, x6                      // __va(FDT blob)
 412         add     x6, x5, #1 << 21                // 2MB for the FDT blob
 413         sub     x6, x6, #1                      // inclusive range
 414         create_block_map x0, x7, x3, x5, x6
 415 1:
 416         ret
 417 ENDPROC(__create_page_tables)
 418         .ltorg
 419
 420         .align  3
 421         .type   __switch_data, %object
 422 __switch_data:
 423         .quad   __mmap_switched
 424         .quad   __data_loc                      // x4
 425         .quad   _data                           // x5
 426         .quad   __bss_start                     // x6
 427         .quad   _end                            // x7
 428         .quad   processor_id                    // x4
 429         .quad   __fdt_pointer                   // x5
 430         .quad   memstart_addr                   // x6
 431         .quad   init_thread_union + THREAD_START_SP // sp
 432
 433 /*
 434  * The following fragment of code is executed with the MMU on in MMU mode, and
 435  * uses absolute addresses; this is not position independent.
 436  */
 437 __mmap_switched:
 438         adr     x3, __switch_data + 8
 439
 440         ldp     x4, x5, [x3], #16
 441         ldp     x6, x7, [x3], #16
 442         cmp     x4, x5                          // Copy data segment if needed
 443 1:      ccmp    x5, x6, #4, ne
 444         b.eq    2f
 445         ldr     x16, [x4], #8
 446         str     x16, [x5], #8
 447         b       1b
 448 2:
 449 1:      cmp     x6, x7
 450         b.hs    2f
 451         str     xzr, [x6], #8                   // Clear BSS
 452         b       1b
 453 2:
 454         ldp     x4, x5, [x3], #16
 455         ldr     x6, [x3], #8
 456         ldr     x16, [x3]
 457         mov     sp, x16
 458         str     x22, [x4]                       // Save processor ID
 459         str     x21, [x5]                       // Save FDT pointer
 460         str     x24, [x6]                       // Save PHYS_OFFSET
 461         mov     x29, #0
 462         b       start_kernel
 463 ENDPROC(__mmap_switched)
 464
 465 /*
 466  * Exception handling. Something went wrong and we can't proceed. We ought to
 467  * tell the user, but since we don't have any guarantee that we're even
 468  * running on the right architecture, we do virtually nothing.
 469  */
 470 __error_p:
 471 ENDPROC(__error_p)
 472
 473 __error:
 474 1:      nop
 475         b       1b
 476 ENDPROC(__error)
 477
 478 /*
 479  * This function gets the processor ID in w0 and searches the cpu_table[] for
 480  * a match. It returns a pointer to the struct cpu_info it found. The
 481  * cpu_table[] must end with an empty (all zeros) structure.
 482  *
 483  * This routine can be called via C code and it needs to work with the MMU
 484  * both disabled and enabled (the offset is calculated automatically).
 485  */
 486 ENTRY(lookup_processor_type)
 487         adr     x1, __lookup_processor_type_data
 488         ldp     x2, x3, [x1]
 489         sub     x1, x1, x2                      // get offset between VA and PA
 490         add     x3, x3, x1                      // convert VA to PA
 491 1:
 492         ldp     w5, w6, [x3]                    // load cpu_id_val and cpu_id_mask
 493         cbz     w5, 2f                          // end of list?
 494         and     w6, w6, w0
 495         cmp     w5, w6
 496         b.eq    3f
 497         add     x3, x3, #CPU_INFO_SZ
 498         b       1b
 499 2:
 500         mov     x3, #0                          // unknown processor
 501 3:
 502         mov     x0, x3
 503         ret
 504 ENDPROC(lookup_processor_type)
 505
 506         .align  3
 507         .type   __lookup_processor_type_data, %object
 508 __lookup_processor_type_data:
 509         .quad   .
 510         .quad   cpu_table
 511         .size   __lookup_processor_type_data, . - __lookup_processor_type_data
 512
 513 /*
 514  * Determine validity of the x21 FDT pointer.
 515  * The dtb must be 8-byte aligned and live in the first 512M of memory.
 516  */
 517 __vet_fdt:
 518         tst     x21, #0x7
 519         b.ne    1f
 520         cmp     x21, x24
 521         b.lt    1f
 522         mov     x0, #(1 << 29)
 523         add     x0, x0, x24
 524         cmp     x21, x0
 525         b.ge    1f
 526         ret
 527 1:
 528         mov     x21, #0
 529         ret
 530 ENDPROC(__vet_fdt)