arch/blackfin/mach-common/dpmc_modes.S

   1 /*
   2  * Copyright 2004-2008 Analog Devices Inc.
   3  *
   4  * Licensed under the GPL-2 or later.
   5  */
   6
   7 #include <linux/linkage.h>
   8 #include <asm/blackfin.h>
   9 #include <mach/irq.h>
  10 #include <asm/dpmc.h>
  11
  12 .section .l1.text
  13
  14 ENTRY(_sleep_mode)
  15         [--SP] = ( R7:0, P5:0 );
  16         [--SP] =  RETS;
  17
  18         call _set_sic_iwr;
  19
  20         P0.H = hi(PLL_CTL);
  21         P0.L = lo(PLL_CTL);
  22         R1 = W[P0](z);
  23         BITSET (R1, 3);
  24         W[P0] = R1.L;
  25
  26         CLI R2;
  27         SSYNC;
  28         IDLE;
  29         STI R2;
  30
  31         call _test_pll_locked;
  32
  33         R0 = IWR_ENABLE(0);
  34         R1 = IWR_DISABLE_ALL;
  35         R2 = IWR_DISABLE_ALL;
  36
  37         call _set_sic_iwr;
  38
  39         P0.H = hi(PLL_CTL);
  40         P0.L = lo(PLL_CTL);
  41         R7 = w[p0](z);
  42         BITCLR (R7, 3);
  43         BITCLR (R7, 5);
  44         w[p0] = R7.L;
  45         IDLE;
  46         call _test_pll_locked;
  47
  48         RETS = [SP++];
  49         ( R7:0, P5:0 ) = [SP++];
  50         RTS;
  51 ENDPROC(_sleep_mode)
  52
  53 ENTRY(_hibernate_mode)
  54         [--SP] = ( R7:0, P5:0 );
  55         [--SP] =  RETS;
  56
  57         R3 = R0;
  58         R0 = IWR_DISABLE_ALL;
  59         R1 = IWR_DISABLE_ALL;
  60         R2 = IWR_DISABLE_ALL;
  61         call _set_sic_iwr;
  62         call _set_dram_srfs;
  63         SSYNC;
  64
  65         P0.H = hi(VR_CTL);
  66         P0.L = lo(VR_CTL);
  67
  68         W[P0] = R3.L;
  69         CLI R2;
  70         IDLE;
  71 .Lforever:
  72         jump .Lforever;
  73 ENDPROC(_hibernate_mode)
  74
  75 ENTRY(_sleep_deeper)
  76         [--SP] = ( R7:0, P5:0 );
  77         [--SP] =  RETS;
  78
  79         CLI R4;
  80
  81         P3 = R0;
  82         P4 = R1;
  83         P5 = R2;
  84
  85         R0 = IWR_ENABLE(0);
  86         R1 = IWR_DISABLE_ALL;
  87         R2 = IWR_DISABLE_ALL;
  88
  89         call _set_sic_iwr;
  90         call _set_dram_srfs;    /* Set SDRAM Self Refresh */
  91
  92         P0.H = hi(PLL_DIV);
  93         P0.L = lo(PLL_DIV);
  94         R6 = W[P0](z);
  95         R0.L = 0xF;
  96         W[P0] = R0.l;           /* Set Max VCO to SCLK divider */
  97
  98         P0.H = hi(PLL_CTL);
  99         P0.L = lo(PLL_CTL);
 100         R5 = W[P0](z);
 101         R0.L = (CONFIG_MIN_VCO_HZ/CONFIG_CLKIN_HZ) << 9;
 102         W[P0] = R0.l;           /* Set Min CLKIN to VCO multiplier */
 103
 104         SSYNC;
 105         IDLE;
 106
 107         call _test_pll_locked;
 108
 109         P0.H = hi(VR_CTL);
 110         P0.L = lo(VR_CTL);
 111         R7 = W[P0](z);
 112         R1 = 0x6;
 113         R1 <<= 16;
 114         R2 = 0x0404(Z);
 115         R1 = R1|R2;
 116
 117         R2 = DEPOSIT(R7, R1);
 118         W[P0] = R2;             /* Set Min Core Voltage */
 119
 120         SSYNC;
 121         IDLE;
 122
 123         call _test_pll_locked;
 124
 125         R0 = P3;
 126         R1 = P4;
 127         R3 = P5;
 128         call _set_sic_iwr;      /* Set Awake from IDLE */
 129
 130         P0.H = hi(PLL_CTL);
 131         P0.L = lo(PLL_CTL);
 132         R0 = W[P0](z);
 133         BITSET (R0, 3);
 134         W[P0] = R0.L;           /* Turn CCLK OFF */
 135         SSYNC;
 136         IDLE;
 137
 138         call _test_pll_locked;
 139
 140         R0 = IWR_ENABLE(0);
 141         R1 = IWR_DISABLE_ALL;
 142         R2 = IWR_DISABLE_ALL;
 143
 144         call _set_sic_iwr;      /* Set Awake from IDLE PLL */
 145
 146         P0.H = hi(VR_CTL);
 147         P0.L = lo(VR_CTL);
 148         W[P0]= R7;
 149
 150         SSYNC;
 151         IDLE;
 152
 153         call _test_pll_locked;
 154
 155         P0.H = hi(PLL_DIV);
 156         P0.L = lo(PLL_DIV);
 157         W[P0]= R6;              /* Restore CCLK and SCLK divider */
 158
 159         P0.H = hi(PLL_CTL);
 160         P0.L = lo(PLL_CTL);
 161         w[p0] = R5;             /* Restore VCO multiplier */
 162         IDLE;
 163         call _test_pll_locked;
 164
 165         call _unset_dram_srfs;  /* SDRAM Self Refresh Off */
 166
 167         STI R4;
 168
 169         RETS = [SP++];
 170         ( R7:0, P5:0 ) = [SP++];
 171         RTS;
 172 ENDPROC(_sleep_deeper)
 173
 174 ENTRY(_set_dram_srfs)
 175         /*  set the dram to self refresh mode */
 176         SSYNC;
 177 #if defined(EBIU_RSTCTL)        /* DDR */
 178         P0.H = hi(EBIU_RSTCTL);
 179         P0.L = lo(EBIU_RSTCTL);
 180         R2 = [P0];
 181         BITSET(R2, 3); /* SRREQ enter self-refresh mode */
 182         [P0] = R2;
 183         SSYNC;
 184 1:
 185         R2 = [P0];
 186         CC = BITTST(R2, 4);
 187         if !CC JUMP 1b;
 188 #else                           /* SDRAM */
 189         P0.L = lo(EBIU_SDGCTL);
 190         P0.H = hi(EBIU_SDGCTL);
 191         R2 = [P0];
 192         BITSET(R2, 24); /* SRFS enter self-refresh mode */
 193         [P0] = R2;
 194         SSYNC;
 195
 196         P0.L = lo(EBIU_SDSTAT);
 197         P0.H = hi(EBIU_SDSTAT);
 198 1:
 199         R2 = w[P0];
 200         SSYNC;
 201         cc = BITTST(R2, 1); /* SDSRA poll self-refresh status */
 202         if !cc jump 1b;
 203
 204         P0.L = lo(EBIU_SDGCTL);
 205         P0.H = hi(EBIU_SDGCTL);
 206         R2 = [P0];
 207         BITCLR(R2, 0); /* SCTLE disable CLKOUT */
 208         [P0] = R2;
 209 #endif
 210         RTS;
 211 ENDPROC(_set_dram_srfs)
 212
 213 ENTRY(_unset_dram_srfs)
 214         /*  set the dram out of self refresh mode */
 215 #if defined(EBIU_RSTCTL)        /* DDR */
 216         P0.H = hi(EBIU_RSTCTL);
 217         P0.L = lo(EBIU_RSTCTL);
 218         R2 = [P0];
 219         BITCLR(R2, 3); /* clear SRREQ bit */
 220         [P0] = R2;
 221 #elif defined(EBIU_SDGCTL)      /* SDRAM */
 222
 223         P0.L = lo(EBIU_SDGCTL); /* release CLKOUT from self-refresh */
 224         P0.H = hi(EBIU_SDGCTL);
 225         R2 = [P0];
 226         BITSET(R2, 0); /* SCTLE enable CLKOUT */
 227         [P0] = R2
 228         SSYNC;
 229
 230         P0.L = lo(EBIU_SDGCTL); /* release SDRAM from self-refresh */
 231         P0.H = hi(EBIU_SDGCTL);
 232         R2 = [P0];
 233         BITCLR(R2, 24); /* clear SRFS bit */
 234         [P0] = R2
 235 #endif
 236         SSYNC;
 237         RTS;
 238 ENDPROC(_unset_dram_srfs)
 239
 240 ENTRY(_set_sic_iwr)
 241 #ifdef SIC_IWR0
 242         P0.H = hi(SYSMMR_BASE);
 243         P0.L = lo(SYSMMR_BASE);
 244         [P0 + (SIC_IWR0 - SYSMMR_BASE)] = R0;
 245         [P0 + (SIC_IWR1 - SYSMMR_BASE)] = R1;
 246 # ifdef SIC_IWR2
 247         [P0 + (SIC_IWR2 - SYSMMR_BASE)] = R2;
 248 # endif
 249 #else
 250         P0.H = hi(SIC_IWR);
 251         P0.L = lo(SIC_IWR);
 252         [P0] = R0;
 253 #endif
 254
 255         SSYNC;
 256         RTS;
 257 ENDPROC(_set_sic_iwr)
 258
 259 ENTRY(_test_pll_locked)
 260         P0.H = hi(PLL_STAT);
 261         P0.L = lo(PLL_STAT);
 262 1:
 263         R0 = W[P0] (Z);
 264         CC = BITTST(R0,5);
 265         IF !CC JUMP 1b;
 266         RTS;
 267 ENDPROC(_test_pll_locked)
 268
 269 .section .text
 270
 271 #define PM_PUSH(x) \
 272         R0 = [P0 + (x - SRAM_BASE_ADDRESS)];\
 273         [--SP] =  R0;\
 274
 275 #define PM_POP(x) \
 276         R0 = [SP++];\
 277         [P0 + (x - SRAM_BASE_ADDRESS)] = R0;\
 278
 279 #define PM_SYS_PUSH(x) \
 280         R0 = [P0 + (x - PLL_CTL)];\
 281         [--SP] =  R0;\
 282
 283 #define PM_SYS_POP(x) \
 284         R0 = [SP++];\
 285         [P0 + (x - PLL_CTL)] = R0;\
 286
 287 #define PM_SYS_PUSH16(x) \
 288         R0 = w[P0 + (x - PLL_CTL)];\
 289         [--SP] =  R0;\
 290
 291 #define PM_SYS_POP16(x) \
 292         R0 = [SP++];\
 293         w[P0 + (x - PLL_CTL)] = R0;\
 294
 295 ENTRY(_do_hibernate)
 296         [--SP] = ( R7:0, P5:0 );
 297         [--SP] =  RETS;
 298         /* Save System MMRs */
 299         R2 = R0;
 300         P0.H = hi(PLL_CTL);
 301         P0.L = lo(PLL_CTL);
 302
 303 #ifdef SIC_IMASK0
 304         PM_SYS_PUSH(SIC_IMASK0)
 305 #endif
 306 #ifdef SIC_IMASK1
 307         PM_SYS_PUSH(SIC_IMASK1)
 308 #endif
 309 #ifdef SIC_IMASK2
 310         PM_SYS_PUSH(SIC_IMASK2)
 311 #endif
 312 #ifdef SIC_IMASK
 313         PM_SYS_PUSH(SIC_IMASK)
 314 #endif
 315 #ifdef SIC_IAR0
 316         PM_SYS_PUSH(SIC_IAR0)
 317         PM_SYS_PUSH(SIC_IAR1)
 318         PM_SYS_PUSH(SIC_IAR2)
 319 #endif
 320 #ifdef SIC_IAR3
 321         PM_SYS_PUSH(SIC_IAR3)
 322 #endif
 323 #ifdef SIC_IAR4
 324         PM_SYS_PUSH(SIC_IAR4)
 325         PM_SYS_PUSH(SIC_IAR5)
 326         PM_SYS_PUSH(SIC_IAR6)
 327 #endif
 328 #ifdef SIC_IAR7
 329         PM_SYS_PUSH(SIC_IAR7)
 330 #endif
 331 #ifdef SIC_IAR8
 332         PM_SYS_PUSH(SIC_IAR8)
 333         PM_SYS_PUSH(SIC_IAR9)
 334         PM_SYS_PUSH(SIC_IAR10)
 335         PM_SYS_PUSH(SIC_IAR11)
 336 #endif
 337
 338 #ifdef SIC_IWR
 339         PM_SYS_PUSH(SIC_IWR)
 340 #endif
 341 #ifdef SIC_IWR0
 342         PM_SYS_PUSH(SIC_IWR0)
 343 #endif
 344 #ifdef SIC_IWR1
 345         PM_SYS_PUSH(SIC_IWR1)
 346 #endif
 347 #ifdef SIC_IWR2
 348         PM_SYS_PUSH(SIC_IWR2)
 349 #endif
 350
 351 #ifdef PINT0_ASSIGN
 352         PM_SYS_PUSH(PINT0_MASK_SET)
 353         PM_SYS_PUSH(PINT1_MASK_SET)
 354         PM_SYS_PUSH(PINT2_MASK_SET)
 355         PM_SYS_PUSH(PINT3_MASK_SET)
 356         PM_SYS_PUSH(PINT0_ASSIGN)
 357         PM_SYS_PUSH(PINT1_ASSIGN)
 358         PM_SYS_PUSH(PINT2_ASSIGN)
 359         PM_SYS_PUSH(PINT3_ASSIGN)
 360         PM_SYS_PUSH(PINT0_INVERT_SET)
 361         PM_SYS_PUSH(PINT1_INVERT_SET)
 362         PM_SYS_PUSH(PINT2_INVERT_SET)
 363         PM_SYS_PUSH(PINT3_INVERT_SET)
 364         PM_SYS_PUSH(PINT0_EDGE_SET)
 365         PM_SYS_PUSH(PINT1_EDGE_SET)
 366         PM_SYS_PUSH(PINT2_EDGE_SET)
 367         PM_SYS_PUSH(PINT3_EDGE_SET)
 368 #endif
 369
 370         PM_SYS_PUSH(EBIU_AMBCTL0)
 371         PM_SYS_PUSH(EBIU_AMBCTL1)
 372         PM_SYS_PUSH16(EBIU_AMGCTL)
 373
 374 #ifdef EBIU_FCTL
 375         PM_SYS_PUSH(EBIU_MBSCTL)
 376         PM_SYS_PUSH(EBIU_MODE)
 377         PM_SYS_PUSH(EBIU_FCTL)
 378 #endif
 379
 380 #ifdef PORTCIO_FER
 381         PM_SYS_PUSH16(PORTCIO_DIR)
 382         PM_SYS_PUSH16(PORTCIO_INEN)
 383         PM_SYS_PUSH16(PORTCIO)
 384         PM_SYS_PUSH16(PORTCIO_FER)
 385         PM_SYS_PUSH16(PORTDIO_DIR)
 386         PM_SYS_PUSH16(PORTDIO_INEN)
 387         PM_SYS_PUSH16(PORTDIO)
 388         PM_SYS_PUSH16(PORTDIO_FER)
 389         PM_SYS_PUSH16(PORTEIO_DIR)
 390         PM_SYS_PUSH16(PORTEIO_INEN)
 391         PM_SYS_PUSH16(PORTEIO)
 392         PM_SYS_PUSH16(PORTEIO_FER)
 393 #endif
 394
 395         PM_SYS_PUSH16(SYSCR)
 396
 397         /* Save Core MMRs */
 398         P0.H = hi(SRAM_BASE_ADDRESS);
 399         P0.L = lo(SRAM_BASE_ADDRESS);
 400
 401         PM_PUSH(DMEM_CONTROL)
 402         PM_PUSH(DCPLB_ADDR0)
 403         PM_PUSH(DCPLB_ADDR1)
 404         PM_PUSH(DCPLB_ADDR2)
 405         PM_PUSH(DCPLB_ADDR3)
 406         PM_PUSH(DCPLB_ADDR4)
 407         PM_PUSH(DCPLB_ADDR5)
 408         PM_PUSH(DCPLB_ADDR6)
 409         PM_PUSH(DCPLB_ADDR7)
 410         PM_PUSH(DCPLB_ADDR8)
 411         PM_PUSH(DCPLB_ADDR9)
 412         PM_PUSH(DCPLB_ADDR10)
 413         PM_PUSH(DCPLB_ADDR11)
 414         PM_PUSH(DCPLB_ADDR12)
 415         PM_PUSH(DCPLB_ADDR13)
 416         PM_PUSH(DCPLB_ADDR14)
 417         PM_PUSH(DCPLB_ADDR15)
 418         PM_PUSH(DCPLB_DATA0)
 419         PM_PUSH(DCPLB_DATA1)
 420         PM_PUSH(DCPLB_DATA2)
 421         PM_PUSH(DCPLB_DATA3)
 422         PM_PUSH(DCPLB_DATA4)
 423         PM_PUSH(DCPLB_DATA5)
 424         PM_PUSH(DCPLB_DATA6)
 425         PM_PUSH(DCPLB_DATA7)
 426         PM_PUSH(DCPLB_DATA8)
 427         PM_PUSH(DCPLB_DATA9)
 428         PM_PUSH(DCPLB_DATA10)
 429         PM_PUSH(DCPLB_DATA11)
 430         PM_PUSH(DCPLB_DATA12)
 431         PM_PUSH(DCPLB_DATA13)
 432         PM_PUSH(DCPLB_DATA14)
 433         PM_PUSH(DCPLB_DATA15)
 434         PM_PUSH(IMEM_CONTROL)
 435         PM_PUSH(ICPLB_ADDR0)
 436         PM_PUSH(ICPLB_ADDR1)
 437         PM_PUSH(ICPLB_ADDR2)
 438         PM_PUSH(ICPLB_ADDR3)
 439         PM_PUSH(ICPLB_ADDR4)
 440         PM_PUSH(ICPLB_ADDR5)
 441         PM_PUSH(ICPLB_ADDR6)
 442         PM_PUSH(ICPLB_ADDR7)
 443         PM_PUSH(ICPLB_ADDR8)
 444         PM_PUSH(ICPLB_ADDR9)
 445         PM_PUSH(ICPLB_ADDR10)
 446         PM_PUSH(ICPLB_ADDR11)
 447         PM_PUSH(ICPLB_ADDR12)
 448         PM_PUSH(ICPLB_ADDR13)
 449         PM_PUSH(ICPLB_ADDR14)
 450         PM_PUSH(ICPLB_ADDR15)
 451         PM_PUSH(ICPLB_DATA0)
 452         PM_PUSH(ICPLB_DATA1)
 453         PM_PUSH(ICPLB_DATA2)
 454         PM_PUSH(ICPLB_DATA3)
 455         PM_PUSH(ICPLB_DATA4)
 456         PM_PUSH(ICPLB_DATA5)
 457         PM_PUSH(ICPLB_DATA6)
 458         PM_PUSH(ICPLB_DATA7)
 459         PM_PUSH(ICPLB_DATA8)
 460         PM_PUSH(ICPLB_DATA9)
 461         PM_PUSH(ICPLB_DATA10)
 462         PM_PUSH(ICPLB_DATA11)
 463         PM_PUSH(ICPLB_DATA12)
 464         PM_PUSH(ICPLB_DATA13)
 465         PM_PUSH(ICPLB_DATA14)
 466         PM_PUSH(ICPLB_DATA15)
 467         PM_PUSH(EVT2)
 468         PM_PUSH(EVT3)
 469         PM_PUSH(EVT5)
 470         PM_PUSH(EVT6)
 471         PM_PUSH(EVT7)
 472         PM_PUSH(EVT8)
 473         PM_PUSH(EVT9)
 474         PM_PUSH(EVT10)
 475         PM_PUSH(EVT11)
 476         PM_PUSH(EVT12)
 477         PM_PUSH(EVT13)
 478         PM_PUSH(EVT14)
 479         PM_PUSH(EVT15)
 480         PM_PUSH(IMASK)
 481         PM_PUSH(ILAT)
 482         PM_PUSH(IPRIO)
 483         PM_PUSH(TCNTL)
 484         PM_PUSH(TPERIOD)
 485         PM_PUSH(TSCALE)
 486         PM_PUSH(TCOUNT)
 487         PM_PUSH(TBUFCTL)
 488
 489         /* Save Core Registers */
 490         [--sp] = SYSCFG;
 491         [--sp] = ( R7:0, P5:0 );
 492         [--sp] = fp;
 493         [--sp] = usp;
 494
 495         [--sp] = i0;
 496         [--sp] = i1;
 497         [--sp] = i2;
 498         [--sp] = i3;
 499
 500         [--sp] = m0;
 501         [--sp] = m1;
 502         [--sp] = m2;
 503         [--sp] = m3;
 504
 505         [--sp] = l0;
 506         [--sp] = l1;
 507         [--sp] = l2;
 508         [--sp] = l3;
 509
 510         [--sp] = b0;
 511         [--sp] = b1;
 512         [--sp] = b2;
 513         [--sp] = b3;
 514         [--sp] = a0.x;
 515         [--sp] = a0.w;
 516         [--sp] = a1.x;
 517         [--sp] = a1.w;
 518
 519         [--sp] = LC0;
 520         [--sp] = LC1;
 521         [--sp] = LT0;
 522         [--sp] = LT1;
 523         [--sp] = LB0;
 524         [--sp] = LB1;
 525
 526         [--sp] = ASTAT;
 527         [--sp] = CYCLES;
 528         [--sp] = CYCLES2;
 529
 530         [--sp] = RETS;
 531         r0 = RETI;
 532         [--sp] = r0;
 533         [--sp] = RETX;
 534         [--sp] = SEQSTAT;
 535
 536         /* Save Magic, return address and Stack Pointer */
 537         P0.H = 0;
 538         P0.L = 0;
 539         R0.H = 0xDEAD;  /* Hibernate Magic */
 540         R0.L = 0xBEEF;
 541         [P0++] = R0;    /* Store Hibernate Magic */
 542         R0.H = .Lpm_resume_here;
 543         R0.L = .Lpm_resume_here;
 544         [P0++] = R0;    /* Save Return Address */
 545         [P0++] = SP;    /* Save Stack Pointer */
 546         P0.H = _hibernate_mode;
 547         P0.L = _hibernate_mode;
 548         R0 = R2;
 549         call (P0); /* Goodbye */
 550
 551 .Lpm_resume_here:
 552
 553         /* Restore Core Registers */
 554         SEQSTAT = [sp++];
 555         RETX = [sp++];
 556         r0 = [sp++];
 557         RETI = r0;
 558         RETS = [sp++];
 559
 560         CYCLES2 = [sp++];
 561         CYCLES = [sp++];
 562         ASTAT = [sp++];
 563
 564         LB1 = [sp++];
 565         LB0 = [sp++];
 566         LT1 = [sp++];
 567         LT0 = [sp++];
 568         LC1 = [sp++];
 569         LC0 = [sp++];
 570
 571         a1.w = [sp++];
 572         a1.x = [sp++];
 573         a0.w = [sp++];
 574         a0.x = [sp++];
 575         b3 = [sp++];
 576         b2 = [sp++];
 577         b1 = [sp++];
 578         b0 = [sp++];
 579
 580         l3 = [sp++];
 581         l2 = [sp++];
 582         l1 = [sp++];
 583         l0 = [sp++];
 584
 585         m3 = [sp++];
 586         m2 = [sp++];
 587         m1 = [sp++];
 588         m0 = [sp++];
 589
 590         i3 = [sp++];
 591         i2 = [sp++];
 592         i1 = [sp++];
 593         i0 = [sp++];
 594
 595         usp = [sp++];
 596         fp = [sp++];
 597
 598         ( R7 : 0, P5 : 0) = [ SP ++ ];
 599         SYSCFG = [sp++];
 600
 601         /* Restore Core MMRs */
 602
 603         PM_POP(TBUFCTL)
 604         PM_POP(TCOUNT)
 605         PM_POP(TSCALE)
 606         PM_POP(TPERIOD)
 607         PM_POP(TCNTL)
 608         PM_POP(IPRIO)
 609         PM_POP(ILAT)
 610         PM_POP(IMASK)
 611         PM_POP(EVT15)
 612         PM_POP(EVT14)
 613         PM_POP(EVT13)
 614         PM_POP(EVT12)
 615         PM_POP(EVT11)
 616         PM_POP(EVT10)
 617         PM_POP(EVT9)
 618         PM_POP(EVT8)
 619         PM_POP(EVT7)
 620         PM_POP(EVT6)
 621         PM_POP(EVT5)
 622         PM_POP(EVT3)
 623         PM_POP(EVT2)
 624         PM_POP(ICPLB_DATA15)
 625         PM_POP(ICPLB_DATA14)
 626         PM_POP(ICPLB_DATA13)
 627         PM_POP(ICPLB_DATA12)
 628         PM_POP(ICPLB_DATA11)
 629         PM_POP(ICPLB_DATA10)
 630         PM_POP(ICPLB_DATA9)
 631         PM_POP(ICPLB_DATA8)
 632         PM_POP(ICPLB_DATA7)
 633         PM_POP(ICPLB_DATA6)
 634         PM_POP(ICPLB_DATA5)
 635         PM_POP(ICPLB_DATA4)
 636         PM_POP(ICPLB_DATA3)
 637         PM_POP(ICPLB_DATA2)
 638         PM_POP(ICPLB_DATA1)
 639         PM_POP(ICPLB_DATA0)
 640         PM_POP(ICPLB_ADDR15)
 641         PM_POP(ICPLB_ADDR14)
 642         PM_POP(ICPLB_ADDR13)
 643         PM_POP(ICPLB_ADDR12)
 644         PM_POP(ICPLB_ADDR11)
 645         PM_POP(ICPLB_ADDR10)
 646         PM_POP(ICPLB_ADDR9)
 647         PM_POP(ICPLB_ADDR8)
 648         PM_POP(ICPLB_ADDR7)
 649         PM_POP(ICPLB_ADDR6)
 650         PM_POP(ICPLB_ADDR5)
 651         PM_POP(ICPLB_ADDR4)
 652         PM_POP(ICPLB_ADDR3)
 653         PM_POP(ICPLB_ADDR2)
 654         PM_POP(ICPLB_ADDR1)
 655         PM_POP(ICPLB_ADDR0)
 656         PM_POP(IMEM_CONTROL)
 657         PM_POP(DCPLB_DATA15)
 658         PM_POP(DCPLB_DATA14)
 659         PM_POP(DCPLB_DATA13)
 660         PM_POP(DCPLB_DATA12)
 661         PM_POP(DCPLB_DATA11)
 662         PM_POP(DCPLB_DATA10)
 663         PM_POP(DCPLB_DATA9)
 664         PM_POP(DCPLB_DATA8)
 665         PM_POP(DCPLB_DATA7)
 666         PM_POP(DCPLB_DATA6)
 667         PM_POP(DCPLB_DATA5)
 668         PM_POP(DCPLB_DATA4)
 669         PM_POP(DCPLB_DATA3)
 670         PM_POP(DCPLB_DATA2)
 671         PM_POP(DCPLB_DATA1)
 672         PM_POP(DCPLB_DATA0)
 673         PM_POP(DCPLB_ADDR15)
 674         PM_POP(DCPLB_ADDR14)
 675         PM_POP(DCPLB_ADDR13)
 676         PM_POP(DCPLB_ADDR12)
 677         PM_POP(DCPLB_ADDR11)
 678         PM_POP(DCPLB_ADDR10)
 679         PM_POP(DCPLB_ADDR9)
 680         PM_POP(DCPLB_ADDR8)
 681         PM_POP(DCPLB_ADDR7)
 682         PM_POP(DCPLB_ADDR6)
 683         PM_POP(DCPLB_ADDR5)
 684         PM_POP(DCPLB_ADDR4)
 685         PM_POP(DCPLB_ADDR3)
 686         PM_POP(DCPLB_ADDR2)
 687         PM_POP(DCPLB_ADDR1)
 688         PM_POP(DCPLB_ADDR0)
 689         PM_POP(DMEM_CONTROL)
 690
 691         /* Restore System MMRs */
 692
 693         P0.H = hi(PLL_CTL);
 694         P0.L = lo(PLL_CTL);
 695         PM_SYS_POP16(SYSCR)
 696
 697 #ifdef PORTCIO_FER
 698         PM_SYS_POP16(PORTEIO_FER)
 699         PM_SYS_POP16(PORTEIO)
 700         PM_SYS_POP16(PORTEIO_INEN)
 701         PM_SYS_POP16(PORTEIO_DIR)
 702         PM_SYS_POP16(PORTDIO_FER)
 703         PM_SYS_POP16(PORTDIO)
 704         PM_SYS_POP16(PORTDIO_INEN)
 705         PM_SYS_POP16(PORTDIO_DIR)
 706         PM_SYS_POP16(PORTCIO_FER)
 707         PM_SYS_POP16(PORTCIO)
 708         PM_SYS_POP16(PORTCIO_INEN)
 709         PM_SYS_POP16(PORTCIO_DIR)
 710 #endif
 711
 712 #ifdef EBIU_FCTL
 713         PM_SYS_POP(EBIU_FCTL)
 714         PM_SYS_POP(EBIU_MODE)
 715         PM_SYS_POP(EBIU_MBSCTL)
 716 #endif
 717         PM_SYS_POP16(EBIU_AMGCTL)
 718         PM_SYS_POP(EBIU_AMBCTL1)
 719         PM_SYS_POP(EBIU_AMBCTL0)
 720
 721 #ifdef PINT0_ASSIGN
 722         PM_SYS_POP(PINT3_EDGE_SET)
 723         PM_SYS_POP(PINT2_EDGE_SET)
 724         PM_SYS_POP(PINT1_EDGE_SET)
 725         PM_SYS_POP(PINT0_EDGE_SET)
 726         PM_SYS_POP(PINT3_INVERT_SET)
 727         PM_SYS_POP(PINT2_INVERT_SET)
 728         PM_SYS_POP(PINT1_INVERT_SET)
 729         PM_SYS_POP(PINT0_INVERT_SET)
 730         PM_SYS_POP(PINT3_ASSIGN)
 731         PM_SYS_POP(PINT2_ASSIGN)
 732         PM_SYS_POP(PINT1_ASSIGN)
 733         PM_SYS_POP(PINT0_ASSIGN)
 734         PM_SYS_POP(PINT3_MASK_SET)
 735         PM_SYS_POP(PINT2_MASK_SET)
 736         PM_SYS_POP(PINT1_MASK_SET)
 737         PM_SYS_POP(PINT0_MASK_SET)
 738 #endif
 739
 740 #ifdef SIC_IWR2
 741         PM_SYS_POP(SIC_IWR2)
 742 #endif
 743 #ifdef SIC_IWR1
 744         PM_SYS_POP(SIC_IWR1)
 745 #endif
 746 #ifdef SIC_IWR0
 747         PM_SYS_POP(SIC_IWR0)
 748 #endif
 749 #ifdef SIC_IWR
 750         PM_SYS_POP(SIC_IWR)
 751 #endif
 752
 753 #ifdef SIC_IAR8
 754         PM_SYS_POP(SIC_IAR11)
 755         PM_SYS_POP(SIC_IAR10)
 756         PM_SYS_POP(SIC_IAR9)
 757         PM_SYS_POP(SIC_IAR8)
 758 #endif
 759 #ifdef SIC_IAR7
 760         PM_SYS_POP(SIC_IAR7)
 761 #endif
 762 #ifdef SIC_IAR6
 763         PM_SYS_POP(SIC_IAR6)
 764         PM_SYS_POP(SIC_IAR5)
 765         PM_SYS_POP(SIC_IAR4)
 766 #endif
 767 #ifdef SIC_IAR3
 768         PM_SYS_POP(SIC_IAR3)
 769 #endif
 770 #ifdef SIC_IAR0
 771         PM_SYS_POP(SIC_IAR2)
 772         PM_SYS_POP(SIC_IAR1)
 773         PM_SYS_POP(SIC_IAR0)
 774 #endif
 775 #ifdef SIC_IMASK
 776         PM_SYS_POP(SIC_IMASK)
 777 #endif
 778 #ifdef SIC_IMASK2
 779         PM_SYS_POP(SIC_IMASK2)
 780 #endif
 781 #ifdef SIC_IMASK1
 782         PM_SYS_POP(SIC_IMASK1)
 783 #endif
 784 #ifdef SIC_IMASK0
 785         PM_SYS_POP(SIC_IMASK0)
 786 #endif
 787
 788         [--sp] = RETI;  /* Clear Global Interrupt Disable */
 789         SP += 4;
 790
 791         RETS = [SP++];
 792         ( R7:0, P5:0 ) = [SP++];
 793         RTS;
 794 ENDPROC(_do_hibernate)