arch/powerpc/kernel/entry_64.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   5  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   6  *  Adapted for Power Macintosh by Paul Mackerras.
   7  *  Low-level exception handlers and MMU support
   8  *  rewritten by Paul Mackerras.
   9  *    Copyright (C) 1996 Paul Mackerras.
  10  *  MPC8xx modifications Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  11  *
  12  *  This file contains the system call entry code, context switch
  13  *  code, and exception/interrupt return code for PowerPC.
  14  *
  15  *  This program is free software; you can redistribute it and/or
  16  *  modify it under the terms of the GNU General Public License
  17  *  as published by the Free Software Foundation; either version
  18  *  2 of the License, or (at your option) any later version.
  19  */
  20
  21 #include <linux/errno.h>
  22 #include <asm/unistd.h>
  23 #include <asm/processor.h>
  24 #include <asm/page.h>
  25 #include <asm/mmu.h>
  26 #include <asm/thread_info.h>
  27 #include <asm/ppc_asm.h>
  28 #include <asm/asm-offsets.h>
  29 #include <asm/cputable.h>
  30 #include <asm/firmware.h>
  31 #include <asm/bug.h>
  32 #include <asm/ptrace.h>
  33 #include <asm/irqflags.h>
  34 #include <asm/ftrace.h>
  35 #include <asm/hw_irq.h>
  36 #include <asm/context_tracking.h>
  37
  38 /*
  39  * System calls.
  40  */
  41         .section        ".toc","aw"
  42 .SYS_CALL_TABLE:
  43         .tc .sys_call_table[TC],.sys_call_table
  44
  45 /* This value is used to mark exception frames on the stack. */
  46 exception_marker:
  47         .tc     ID_EXC_MARKER[TC],STACK_FRAME_REGS_MARKER
  48
  49         .section        ".text"
  50         .align 7
  51
  52 #undef SHOW_SYSCALLS
  53
  54         .globl system_call_common
  55 system_call_common:
  56         andi.   r10,r12,MSR_PR
  57         mr      r10,r1
  58         addi    r1,r1,-INT_FRAME_SIZE
  59         beq-    1f
  60         ld      r1,PACAKSAVE(r13)
  61 1:      std     r10,0(r1)
  62         std     r11,_NIP(r1)
  63         std     r12,_MSR(r1)
  64         std     r0,GPR0(r1)
  65         std     r10,GPR1(r1)
  66         beq     2f                      /* if from kernel mode */
  67         ACCOUNT_CPU_USER_ENTRY(r10, r11)
  68 2:      std     r2,GPR2(r1)
  69         std     r3,GPR3(r1)
  70         mfcr    r2
  71         std     r4,GPR4(r1)
  72         std     r5,GPR5(r1)
  73         std     r6,GPR6(r1)
  74         std     r7,GPR7(r1)
  75         std     r8,GPR8(r1)
  76         li      r11,0
  77         std     r11,GPR9(r1)
  78         std     r11,GPR10(r1)
  79         std     r11,GPR11(r1)
  80         std     r11,GPR12(r1)
  81         std     r11,_XER(r1)
  82         std     r11,_CTR(r1)
  83         std     r9,GPR13(r1)
  84         mflr    r10
  85         /*
  86          * This clears CR0.SO (bit 28), which is the error indication on
  87          * return from this system call.
  88          */
  89         rldimi  r2,r11,28,(63-28)
  90         li      r11,0xc01
  91         std     r10,_LINK(r1)
  92         std     r11,_TRAP(r1)
  93         std     r3,ORIG_GPR3(r1)
  94         std     r2,_CCR(r1)
  95         ld      r2,PACATOC(r13)
  96         addi    r9,r1,STACK_FRAME_OVERHEAD
  97         ld      r11,exception_marker@toc(r2)
  98         std     r11,-16(r9)             /* "regshere" marker */
  99 #if defined(CONFIG_VIRT_CPU_ACCOUNTING_NATIVE) && defined(CONFIG_PPC_SPLPAR)
 100 BEGIN_FW_FTR_SECTION
 101         beq     33f
 102         /* if from user, see if there are any DTL entries to process */
 103         ld      r10,PACALPPACAPTR(r13)  /* get ptr to VPA */
 104         ld      r11,PACA_DTL_RIDX(r13)  /* get log read index */
 105         ld      r10,LPPACA_DTLIDX(r10)  /* get log write index */
 106         cmpd    cr1,r11,r10
 107         beq+    cr1,33f
 108         bl      .accumulate_stolen_time
 109         REST_GPR(0,r1)
 110         REST_4GPRS(3,r1)
 111         REST_2GPRS(7,r1)
 112         addi    r9,r1,STACK_FRAME_OVERHEAD
 113 33:
 114 END_FW_FTR_SECTION_IFSET(FW_FEATURE_SPLPAR)
 115 #endif /* CONFIG_VIRT_CPU_ACCOUNTING_NATIVE && CONFIG_PPC_SPLPAR */
 116
 117         /*
 118          * A syscall should always be called with interrupts enabled
 119          * so we just unconditionally hard-enable here. When some kind
 120          * of irq tracing is used, we additionally check that condition
 121          * is correct
 122          */
 123 #if defined(CONFIG_TRACE_IRQFLAGS) && defined(CONFIG_BUG)
 124         lbz     r10,PACASOFTIRQEN(r13)
 125         xori    r10,r10,1
 126 1:      tdnei   r10,0
 127         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 128 #endif
 129
 130 #ifdef CONFIG_PPC_BOOK3E
 131         wrteei  1
 132 #else
 133         ld      r11,PACAKMSR(r13)
 134         ori     r11,r11,MSR_EE
 135         mtmsrd  r11,1
 136 #endif /* CONFIG_PPC_BOOK3E */
 137
 138         /* We do need to set SOFTE in the stack frame or the return
 139          * from interrupt will be painful
 140          */
 141         li      r10,1
 142         std     r10,SOFTE(r1)
 143
 144 #ifdef SHOW_SYSCALLS
 145         bl      .do_show_syscall
 146         REST_GPR(0,r1)
 147         REST_4GPRS(3,r1)
 148         REST_2GPRS(7,r1)
 149         addi    r9,r1,STACK_FRAME_OVERHEAD
 150 #endif
 151         CURRENT_THREAD_INFO(r11, r1)
 152         ld      r10,TI_FLAGS(r11)
 153         andi.   r11,r10,_TIF_SYSCALL_T_OR_A
 154         bne     syscall_dotrace
 155 .Lsyscall_dotrace_cont:
 156         cmpldi  0,r0,NR_syscalls
 157         bge-    syscall_enosys
 158
 159 system_call:                    /* label this so stack traces look sane */
 160 /*
 161  * Need to vector to 32 Bit or default sys_call_table here,
 162  * based on caller's run-mode / personality.
 163  */
 164         ld      r11,.SYS_CALL_TABLE@toc(2)
 165         andi.   r10,r10,_TIF_32BIT
 166         beq     15f
 167         addi    r11,r11,8       /* use 32-bit syscall entries */
 168         clrldi  r3,r3,32
 169         clrldi  r4,r4,32
 170         clrldi  r5,r5,32
 171         clrldi  r6,r6,32
 172         clrldi  r7,r7,32
 173         clrldi  r8,r8,32
 174 15:
 175         slwi    r0,r0,4
 176         ldx     r10,r11,r0      /* Fetch system call handler [ptr] */
 177         mtctr   r10
 178         bctrl                   /* Call handler */
 179
 180 syscall_exit:
 181         std     r3,RESULT(r1)
 182 #ifdef SHOW_SYSCALLS
 183         bl      .do_show_syscall_exit
 184         ld      r3,RESULT(r1)
 185 #endif
 186         CURRENT_THREAD_INFO(r12, r1)
 187
 188         ld      r8,_MSR(r1)
 189 #ifdef CONFIG_PPC_BOOK3S
 190         /* No MSR:RI on BookE */
 191         andi.   r10,r8,MSR_RI
 192         beq-    unrecov_restore
 193 #endif
 194         /*
 195          * Disable interrupts so current_thread_info()->flags can't change,
 196          * and so that we don't get interrupted after loading SRR0/1.
 197          */
 198 #ifdef CONFIG_PPC_BOOK3E
 199         wrteei  0
 200 #else
 201         ld      r10,PACAKMSR(r13)
 202         /*
 203          * For performance reasons we clear RI the same time that we
 204          * clear EE. We only need to clear RI just before we restore r13
 205          * below, but batching it with EE saves us one expensive mtmsrd call.
 206          * We have to be careful to restore RI if we branch anywhere from
 207          * here (eg syscall_exit_work).
 208          */
 209         li      r9,MSR_RI
 210         andc    r11,r10,r9
 211         mtmsrd  r11,1
 212 #endif /* CONFIG_PPC_BOOK3E */
 213
 214         ld      r9,TI_FLAGS(r12)
 215         li      r11,-_LAST_ERRNO
 216         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP|_TIF_USER_WORK_MASK|_TIF_PERSYSCALL_MASK)
 217         bne-    syscall_exit_work
 218         cmpld   r3,r11
 219         ld      r5,_CCR(r1)
 220         bge-    syscall_error
 221 .Lsyscall_error_cont:
 222         ld      r7,_NIP(r1)
 223 BEGIN_FTR_SECTION
 224         stdcx.  r0,0,r1                 /* to clear the reservation */
 225 END_FTR_SECTION_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 226         andi.   r6,r8,MSR_PR
 227         ld      r4,_LINK(r1)
 228
 229         beq-    1f
 230         ACCOUNT_CPU_USER_EXIT(r11, r12)
 231         HMT_MEDIUM_LOW_HAS_PPR
 232         ld      r13,GPR13(r1)   /* only restore r13 if returning to usermode */
 233 1:      ld      r2,GPR2(r1)
 234         ld      r1,GPR1(r1)
 235         mtlr    r4
 236         mtcr    r5
 237         mtspr   SPRN_SRR0,r7
 238         mtspr   SPRN_SRR1,r8
 239         RFI
 240         b       .       /* prevent speculative execution */
 241
 242 syscall_error:
 243         oris    r5,r5,0x1000    /* Set SO bit in CR */
 244         neg     r3,r3
 245         std     r5,_CCR(r1)
 246         b       .Lsyscall_error_cont
 247
 248 /* Traced system call support */
 249 syscall_dotrace:
 250         bl      .save_nvgprs
 251         addi    r3,r1,STACK_FRAME_OVERHEAD
 252         bl      .do_syscall_trace_enter
 253         /*
 254          * Restore argument registers possibly just changed.
 255          * We use the return value of do_syscall_trace_enter
 256          * for the call number to look up in the table (r0).
 257          */
 258         mr      r0,r3
 259         ld      r3,GPR3(r1)
 260         ld      r4,GPR4(r1)
 261         ld      r5,GPR5(r1)
 262         ld      r6,GPR6(r1)
 263         ld      r7,GPR7(r1)
 264         ld      r8,GPR8(r1)
 265         addi    r9,r1,STACK_FRAME_OVERHEAD
 266         CURRENT_THREAD_INFO(r10, r1)
 267         ld      r10,TI_FLAGS(r10)
 268         b       .Lsyscall_dotrace_cont
 269
 270 syscall_enosys:
 271         li      r3,-ENOSYS
 272         b       syscall_exit
 273
 274 syscall_exit_work:
 275 #ifdef CONFIG_PPC_BOOK3S
 276         mtmsrd  r10,1           /* Restore RI */
 277 #endif
 278         /* If TIF_RESTOREALL is set, don't scribble on either r3 or ccr.
 279          If TIF_NOERROR is set, just save r3 as it is. */
 280
 281         andi.   r0,r9,_TIF_RESTOREALL
 282         beq+    0f
 283         REST_NVGPRS(r1)
 284         b       2f
 285 0:      cmpld   r3,r11          /* r10 is -LAST_ERRNO */
 286         blt+    1f
 287         andi.   r0,r9,_TIF_NOERROR
 288         bne-    1f
 289         ld      r5,_CCR(r1)
 290         neg     r3,r3
 291         oris    r5,r5,0x1000    /* Set SO bit in CR */
 292         std     r5,_CCR(r1)
 293 1:      std     r3,GPR3(r1)
 294 2:      andi.   r0,r9,(_TIF_PERSYSCALL_MASK)
 295         beq     4f
 296
 297         /* Clear per-syscall TIF flags if any are set.  */
 298
 299         li      r11,_TIF_PERSYSCALL_MASK
 300         addi    r12,r12,TI_FLAGS
 301 3:      ldarx   r10,0,r12
 302         andc    r10,r10,r11
 303         stdcx.  r10,0,r12
 304         bne-    3b
 305         subi    r12,r12,TI_FLAGS
 306
 307 4:      /* Anything else left to do? */
 308         SET_DEFAULT_THREAD_PPR(r3, r10)         /* Set thread.ppr = 3 */
 309         andi.   r0,r9,(_TIF_SYSCALL_T_OR_A|_TIF_SINGLESTEP)
 310         beq     .ret_from_except_lite
 311
 312         /* Re-enable interrupts */
 313 #ifdef CONFIG_PPC_BOOK3E
 314         wrteei  1
 315 #else
 316         ld      r10,PACAKMSR(r13)
 317         ori     r10,r10,MSR_EE
 318         mtmsrd  r10,1
 319 #endif /* CONFIG_PPC_BOOK3E */
 320
 321         bl      .save_nvgprs
 322         addi    r3,r1,STACK_FRAME_OVERHEAD
 323         bl      .do_syscall_trace_leave
 324         b       .ret_from_except
 325
 326 /* Save non-volatile GPRs, if not already saved. */
 327 _GLOBAL(save_nvgprs)
 328         ld      r11,_TRAP(r1)
 329         andi.   r0,r11,1
 330         beqlr-
 331         SAVE_NVGPRS(r1)
 332         clrrdi  r0,r11,1
 333         std     r0,_TRAP(r1)
 334         blr
 335
 336
 337 /*
 338  * The sigsuspend and rt_sigsuspend system calls can call do_signal
 339  * and thus put the process into the stopped state where we might
 340  * want to examine its user state with ptrace.  Therefore we need
 341  * to save all the nonvolatile registers (r14 - r31) before calling
 342  * the C code.  Similarly, fork, vfork and clone need the full
 343  * register state on the stack so that it can be copied to the child.
 344  */
 345
 346 _GLOBAL(ppc_fork)
 347         bl      .save_nvgprs
 348         bl      .sys_fork
 349         b       syscall_exit
 350
 351 _GLOBAL(ppc_vfork)
 352         bl      .save_nvgprs
 353         bl      .sys_vfork
 354         b       syscall_exit
 355
 356 _GLOBAL(ppc_clone)
 357         bl      .save_nvgprs
 358         bl      .sys_clone
 359         b       syscall_exit
 360
 361 _GLOBAL(ppc32_swapcontext)
 362         bl      .save_nvgprs
 363         bl      .compat_sys_swapcontext
 364         b       syscall_exit
 365
 366 _GLOBAL(ppc64_swapcontext)
 367         bl      .save_nvgprs
 368         bl      .sys_swapcontext
 369         b       syscall_exit
 370
 371 _GLOBAL(ret_from_fork)
 372         bl      .schedule_tail
 373         REST_NVGPRS(r1)
 374         li      r3,0
 375         b       syscall_exit
 376
 377 _GLOBAL(ret_from_kernel_thread)
 378         bl      .schedule_tail
 379         REST_NVGPRS(r1)
 380         ld      r14, 0(r14)
 381         mtlr    r14
 382         mr      r3,r15
 383         blrl
 384         li      r3,0
 385         b       syscall_exit
 386
 387         .section        ".toc","aw"
 388 DSCR_DEFAULT:
 389         .tc dscr_default[TC],dscr_default
 390
 391         .section        ".text"
 392
 393 /*
 394  * This routine switches between two different tasks.  The process
 395  * state of one is saved on its kernel stack.  Then the state
 396  * of the other is restored from its kernel stack.  The memory
 397  * management hardware is updated to the second process's state.
 398  * Finally, we can return to the second process, via ret_from_except.
 399  * On entry, r3 points to the THREAD for the current task, r4
 400  * points to the THREAD for the new task.
 401  *
 402  * Note: there are two ways to get to the "going out" portion
 403  * of this code; either by coming in via the entry (_switch)
 404  * or via "fork" which must set up an environment equivalent
 405  * to the "_switch" path.  If you change this you'll have to change
 406  * the fork code also.
 407  *
 408  * The code which creates the new task context is in 'copy_thread'
 409  * in arch/powerpc/kernel/process.c
 410  */
 411         .align  7
 412 _GLOBAL(_switch)
 413         mflr    r0
 414         std     r0,16(r1)
 415         stdu    r1,-SWITCH_FRAME_SIZE(r1)
 416         /* r3-r13 are caller saved -- Cort */
 417         SAVE_8GPRS(14, r1)
 418         SAVE_10GPRS(22, r1)
 419         mflr    r20             /* Return to switch caller */
 420         mfmsr   r22
 421         li      r0, MSR_FP
 422 #ifdef CONFIG_VSX
 423 BEGIN_FTR_SECTION
 424         oris    r0,r0,MSR_VSX@h /* Disable VSX */
 425 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
 426 #endif /* CONFIG_VSX */
 427 #ifdef CONFIG_ALTIVEC
 428 BEGIN_FTR_SECTION
 429         oris    r0,r0,MSR_VEC@h /* Disable altivec */
 430         mfspr   r24,SPRN_VRSAVE /* save vrsave register value */
 431         std     r24,THREAD_VRSAVE(r3)
 432 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 433 #endif /* CONFIG_ALTIVEC */
 434 #ifdef CONFIG_PPC64
 435 BEGIN_FTR_SECTION
 436         mfspr   r25,SPRN_DSCR
 437         std     r25,THREAD_DSCR(r3)
 438 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 439 #endif
 440         and.    r0,r0,r22
 441         beq+    1f
 442         andc    r22,r22,r0
 443         MTMSRD(r22)
 444         isync
 445 1:      std     r20,_NIP(r1)
 446         mfcr    r23
 447         std     r23,_CCR(r1)
 448         std     r1,KSP(r3)      /* Set old stack pointer */
 449
 450 #ifdef CONFIG_PPC_BOOK3S_64
 451 BEGIN_FTR_SECTION
 452         /*
 453          * Back up the TAR across context switches.  Note that the TAR is not
 454          * available for use in the kernel.  (To provide this, the TAR should
 455          * be backed up/restored on exception entry/exit instead, and be in
 456          * pt_regs.  FIXME, this should be in pt_regs anyway (for debug).)
 457          */
 458         mfspr   r0,SPRN_TAR
 459         std     r0,THREAD_TAR(r3)
 460
 461         /* Event based branch registers */
 462         mfspr   r0, SPRN_BESCR
 463         std     r0, THREAD_BESCR(r3)
 464         mfspr   r0, SPRN_EBBHR
 465         std     r0, THREAD_EBBHR(r3)
 466         mfspr   r0, SPRN_EBBRR
 467         std     r0, THREAD_EBBRR(r3)
 468 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 469 #endif
 470
 471 #ifdef CONFIG_SMP
 472         /* We need a sync somewhere here to make sure that if the
 473          * previous task gets rescheduled on another CPU, it sees all
 474          * stores it has performed on this one.
 475          */
 476         sync
 477 #endif /* CONFIG_SMP */
 478
 479         /*
 480          * If we optimise away the clear of the reservation in system
 481          * calls because we know the CPU tracks the address of the
 482          * reservation, then we need to clear it here to cover the
 483          * case that the kernel context switch path has no larx
 484          * instructions.
 485          */
 486 BEGIN_FTR_SECTION
 487         ldarx   r6,0,r1
 488 END_FTR_SECTION_IFSET(CPU_FTR_STCX_CHECKS_ADDRESS)
 489
 490         addi    r6,r4,-THREAD   /* Convert THREAD to 'current' */
 491         std     r6,PACACURRENT(r13)     /* Set new 'current' */
 492
 493         ld      r8,KSP(r4)      /* new stack pointer */
 494 #ifdef CONFIG_PPC_BOOK3S
 495 BEGIN_FTR_SECTION
 496   BEGIN_FTR_SECTION_NESTED(95)
 497         clrrdi  r6,r8,28        /* get its ESID */
 498         clrrdi  r9,r1,28        /* get current sp ESID */
 499   FTR_SECTION_ELSE_NESTED(95)
 500         clrrdi  r6,r8,40        /* get its 1T ESID */
 501         clrrdi  r9,r1,40        /* get current sp 1T ESID */
 502   ALT_MMU_FTR_SECTION_END_NESTED_IFCLR(MMU_FTR_1T_SEGMENT, 95)
 503 FTR_SECTION_ELSE
 504         b       2f
 505 ALT_MMU_FTR_SECTION_END_IFSET(MMU_FTR_SLB)
 506         clrldi. r0,r6,2         /* is new ESID c00000000? */
 507         cmpd    cr1,r6,r9       /* or is new ESID the same as current ESID? */
 508         cror    eq,4*cr1+eq,eq
 509         beq     2f              /* if yes, don't slbie it */
 510
 511         /* Bolt in the new stack SLB entry */
 512         ld      r7,KSP_VSID(r4) /* Get new stack's VSID */
 513         oris    r0,r6,(SLB_ESID_V)@h
 514         ori     r0,r0,(SLB_NUM_BOLTED-1)@l
 515 BEGIN_FTR_SECTION
 516         li      r9,MMU_SEGSIZE_1T       /* insert B field */
 517         oris    r6,r6,(MMU_SEGSIZE_1T << SLBIE_SSIZE_SHIFT)@h
 518         rldimi  r7,r9,SLB_VSID_SSIZE_SHIFT,0
 519 END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
 520
 521         /* Update the last bolted SLB.  No write barriers are needed
 522          * here, provided we only update the current CPU's SLB shadow
 523          * buffer.
 524          */
 525         ld      r9,PACA_SLBSHADOWPTR(r13)
 526         li      r12,0
 527         std     r12,SLBSHADOW_STACKESID(r9) /* Clear ESID */
 528         std     r7,SLBSHADOW_STACKVSID(r9)  /* Save VSID */
 529         std     r0,SLBSHADOW_STACKESID(r9)  /* Save ESID */
 530
 531         /* No need to check for MMU_FTR_NO_SLBIE_B here, since when
 532          * we have 1TB segments, the only CPUs known to have the errata
 533          * only support less than 1TB of system memory and we'll never
 534          * actually hit this code path.
 535          */
 536
 537         slbie   r6
 538         slbie   r6              /* Workaround POWER5 < DD2.1 issue */
 539         slbmte  r7,r0
 540         isync
 541 2:
 542 #endif /* !CONFIG_PPC_BOOK3S */
 543
 544         CURRENT_THREAD_INFO(r7, r8)  /* base of new stack */
 545         /* Note: this uses SWITCH_FRAME_SIZE rather than INT_FRAME_SIZE
 546            because we don't need to leave the 288-byte ABI gap at the
 547            top of the kernel stack. */
 548         addi    r7,r7,THREAD_SIZE-SWITCH_FRAME_SIZE
 549
 550         mr      r1,r8           /* start using new stack pointer */
 551         std     r7,PACAKSAVE(r13)
 552
 553 #ifdef CONFIG_PPC_BOOK3S_64
 554 BEGIN_FTR_SECTION
 555         /* Event based branch registers */
 556         ld      r0, THREAD_BESCR(r4)
 557         mtspr   SPRN_BESCR, r0
 558         ld      r0, THREAD_EBBHR(r4)
 559         mtspr   SPRN_EBBHR, r0
 560         ld      r0, THREAD_EBBRR(r4)
 561         mtspr   SPRN_EBBRR, r0
 562
 563         ld      r0,THREAD_TAR(r4)
 564         mtspr   SPRN_TAR,r0
 565 END_FTR_SECTION_IFSET(CPU_FTR_ARCH_207S)
 566 #endif
 567
 568 #ifdef CONFIG_ALTIVEC
 569 BEGIN_FTR_SECTION
 570         ld      r0,THREAD_VRSAVE(r4)
 571         mtspr   SPRN_VRSAVE,r0          /* if G4, restore VRSAVE reg */
 572 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
 573 #endif /* CONFIG_ALTIVEC */
 574 #ifdef CONFIG_PPC64
 575 BEGIN_FTR_SECTION
 576         lwz     r6,THREAD_DSCR_INHERIT(r4)
 577         ld      r7,DSCR_DEFAULT@toc(2)
 578         ld      r0,THREAD_DSCR(r4)
 579         cmpwi   r6,0
 580         bne     1f
 581         ld      r0,0(r7)
 582 1:      cmpd    r0,r25
 583         beq     2f
 584         mtspr   SPRN_DSCR,r0
 585 2:
 586 END_FTR_SECTION_IFSET(CPU_FTR_DSCR)
 587 #endif
 588
 589         ld      r6,_CCR(r1)
 590         mtcrf   0xFF,r6
 591
 592         /* r3-r13 are destroyed -- Cort */
 593         REST_8GPRS(14, r1)
 594         REST_10GPRS(22, r1)
 595
 596         /* convert old thread to its task_struct for return value */
 597         addi    r3,r3,-THREAD
 598         ld      r7,_NIP(r1)     /* Return to _switch caller in new task */
 599         mtlr    r7
 600         addi    r1,r1,SWITCH_FRAME_SIZE
 601         blr
 602
 603         .align  7
 604 _GLOBAL(ret_from_except)
 605         ld      r11,_TRAP(r1)
 606         andi.   r0,r11,1
 607         bne     .ret_from_except_lite
 608         REST_NVGPRS(r1)
 609
 610 _GLOBAL(ret_from_except_lite)
 611         /*
 612          * Disable interrupts so that current_thread_info()->flags
 613          * can't change between when we test it and when we return
 614          * from the interrupt.
 615          */
 616 #ifdef CONFIG_PPC_BOOK3E
 617         wrteei  0
 618 #else
 619         ld      r10,PACAKMSR(r13) /* Get kernel MSR without EE */
 620         mtmsrd  r10,1             /* Update machine state */
 621 #endif /* CONFIG_PPC_BOOK3E */
 622
 623         CURRENT_THREAD_INFO(r9, r1)
 624         ld      r3,_MSR(r1)
 625         ld      r4,TI_FLAGS(r9)
 626         andi.   r3,r3,MSR_PR
 627         beq     resume_kernel
 628
 629         /* Check current_thread_info()->flags */
 630         andi.   r0,r4,_TIF_USER_WORK_MASK
 631         beq     restore
 632
 633         andi.   r0,r4,_TIF_NEED_RESCHED
 634         beq     1f
 635         bl      .restore_interrupts
 636         SCHEDULE_USER
 637         b       .ret_from_except_lite
 638
 639 1:      bl      .save_nvgprs
 640         bl      .restore_interrupts
 641         addi    r3,r1,STACK_FRAME_OVERHEAD
 642         bl      .do_notify_resume
 643         b       .ret_from_except
 644
 645 resume_kernel:
 646         /* check current_thread_info, _TIF_EMULATE_STACK_STORE */
 647         CURRENT_THREAD_INFO(r9, r1)
 648         ld      r8,TI_FLAGS(r9)
 649         andis.  r8,r8,_TIF_EMULATE_STACK_STORE@h
 650         beq+    1f
 651
 652         addi    r8,r1,INT_FRAME_SIZE    /* Get the kprobed function entry */
 653
 654         lwz     r3,GPR1(r1)
 655         subi    r3,r3,INT_FRAME_SIZE    /* dst: Allocate a trampoline exception frame */
 656         mr      r4,r1                   /* src:  current exception frame */
 657         mr      r1,r3                   /* Reroute the trampoline frame to r1 */
 658
 659         /* Copy from the original to the trampoline. */
 660         li      r5,INT_FRAME_SIZE/8     /* size: INT_FRAME_SIZE */
 661         li      r6,0                    /* start offset: 0 */
 662         mtctr   r5
 663 2:      ldx     r0,r6,r4
 664         stdx    r0,r6,r3
 665         addi    r6,r6,8
 666         bdnz    2b
 667
 668         /* Do real store operation to complete stwu */
 669         lwz     r5,GPR1(r1)
 670         std     r8,0(r5)
 671
 672         /* Clear _TIF_EMULATE_STACK_STORE flag */
 673         lis     r11,_TIF_EMULATE_STACK_STORE@h
 674         addi    r5,r9,TI_FLAGS
 675 0:      ldarx   r4,0,r5
 676         andc    r4,r4,r11
 677         stdcx.  r4,0,r5
 678         bne-    0b
 679 1:
 680
 681 #ifdef CONFIG_PREEMPT
 682         /* Check if we need to preempt */
 683         andi.   r0,r4,_TIF_NEED_RESCHED
 684         beq+    restore
 685         /* Check that preempt_count() == 0 and interrupts are enabled */
 686         lwz     r8,TI_PREEMPT(r9)
 687         cmpwi   cr1,r8,0
 688         ld      r0,SOFTE(r1)
 689         cmpdi   r0,0
 690         crandc  eq,cr1*4+eq,eq
 691         bne     restore
 692
 693         /*
 694          * Here we are preempting the current task. We want to make
 695          * sure we are soft-disabled first
 696          */
 697         SOFT_DISABLE_INTS(r3,r4)
 698 1:      bl      .preempt_schedule_irq
 699
 700         /* Re-test flags and eventually loop */
 701         CURRENT_THREAD_INFO(r9, r1)
 702         ld      r4,TI_FLAGS(r9)
 703         andi.   r0,r4,_TIF_NEED_RESCHED
 704         bne     1b
 705
 706         /*
 707          * arch_local_irq_restore() from preempt_schedule_irq above may
 708          * enable hard interrupt but we really should disable interrupts
 709          * when we return from the interrupt, and so that we don't get
 710          * interrupted after loading SRR0/1.
 711          */
 712 #ifdef CONFIG_PPC_BOOK3E
 713         wrteei  0
 714 #else
 715         ld      r10,PACAKMSR(r13) /* Get kernel MSR without EE */
 716         mtmsrd  r10,1             /* Update machine state */
 717 #endif /* CONFIG_PPC_BOOK3E */
 718 #endif /* CONFIG_PREEMPT */
 719
 720         .globl  fast_exc_return_irq
 721 fast_exc_return_irq:
 722 restore:
 723         /*
 724          * This is the main kernel exit path. First we check if we
 725          * are about to re-enable interrupts
 726          */
 727         ld      r5,SOFTE(r1)
 728         lbz     r6,PACASOFTIRQEN(r13)
 729         cmpwi   cr0,r5,0
 730         beq     restore_irq_off
 731
 732         /* We are enabling, were we already enabled ? Yes, just return */
 733         cmpwi   cr0,r6,1
 734         beq     cr0,do_restore
 735
 736         /*
 737          * We are about to soft-enable interrupts (we are hard disabled
 738          * at this point). We check if there's anything that needs to
 739          * be replayed first.
 740          */
 741         lbz     r0,PACAIRQHAPPENED(r13)
 742         cmpwi   cr0,r0,0
 743         bne-    restore_check_irq_replay
 744
 745         /*
 746          * Get here when nothing happened while soft-disabled, just
 747          * soft-enable and move-on. We will hard-enable as a side
 748          * effect of rfi
 749          */
 750 restore_no_replay:
 751         TRACE_ENABLE_INTS
 752         li      r0,1
 753         stb     r0,PACASOFTIRQEN(r13);
 754
 755         /*
 756          * Final return path. BookE is handled in a different file
 757          */
 758 do_restore:
 759 #ifdef CONFIG_PPC_BOOK3E
 760         b       .exception_return_book3e
 761 #else
 762         /*
 763          * Clear the reservation. If we know the CPU tracks the address of
 764          * the reservation then we can potentially save some cycles and use
 765          * a larx. On POWER6 and POWER7 this is significantly faster.
 766          */
 767 BEGIN_FTR_SECTION
 768         stdcx.  r0,0,r1         /* to clear the reservation */
 769 FTR_SECTION_ELSE
 770         ldarx   r4,0,r1
 771 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_STCX_CHECKS_ADDRESS)
 772
 773         /*
 774          * Some code path such as load_up_fpu or altivec return directly
 775          * here. They run entirely hard disabled and do not alter the
 776          * interrupt state. They also don't use lwarx/stwcx. and thus
 777          * are known not to leave dangling reservations.
 778          */
 779         .globl  fast_exception_return
 780 fast_exception_return:
 781         ld      r3,_MSR(r1)
 782         ld      r4,_CTR(r1)
 783         ld      r0,_LINK(r1)
 784         mtctr   r4
 785         mtlr    r0
 786         ld      r4,_XER(r1)
 787         mtspr   SPRN_XER,r4
 788
 789         REST_8GPRS(5, r1)
 790
 791         andi.   r0,r3,MSR_RI
 792         beq-    unrecov_restore
 793
 794         /*
 795          * Clear RI before restoring r13.  If we are returning to
 796          * userspace and we take an exception after restoring r13,
 797          * we end up corrupting the userspace r13 value.
 798          */
 799         ld      r4,PACAKMSR(r13) /* Get kernel MSR without EE */
 800         andc    r4,r4,r0         /* r0 contains MSR_RI here */
 801         mtmsrd  r4,1
 802
 803 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
 804         /* TM debug */
 805         std     r3, PACATMSCRATCH(r13) /* Stash returned-to MSR */
 806 #endif
 807         /*
 808          * r13 is our per cpu area, only restore it if we are returning to
 809          * userspace the value stored in the stack frame may belong to
 810          * another CPU.
 811          */
 812         andi.   r0,r3,MSR_PR
 813         beq     1f
 814         ACCOUNT_CPU_USER_EXIT(r2, r4)
 815         RESTORE_PPR(r2, r4)
 816         REST_GPR(13, r1)
 817 1:
 818         mtspr   SPRN_SRR1,r3
 819
 820         ld      r2,_CCR(r1)
 821         mtcrf   0xFF,r2
 822         ld      r2,_NIP(r1)
 823         mtspr   SPRN_SRR0,r2
 824
 825         ld      r0,GPR0(r1)
 826         ld      r2,GPR2(r1)
 827         ld      r3,GPR3(r1)
 828         ld      r4,GPR4(r1)
 829         ld      r1,GPR1(r1)
 830
 831         rfid
 832         b       .       /* prevent speculative execution */
 833
 834 #endif /* CONFIG_PPC_BOOK3E */
 835
 836         /*
 837          * We are returning to a context with interrupts soft disabled.
 838          *
 839          * However, we may also about to hard enable, so we need to
 840          * make sure that in this case, we also clear PACA_IRQ_HARD_DIS
 841          * or that bit can get out of sync and bad things will happen
 842          */
 843 restore_irq_off:
 844         ld      r3,_MSR(r1)
 845         lbz     r7,PACAIRQHAPPENED(r13)
 846         andi.   r0,r3,MSR_EE
 847         beq     1f
 848         rlwinm  r7,r7,0,~PACA_IRQ_HARD_DIS
 849         stb     r7,PACAIRQHAPPENED(r13)
 850 1:      li      r0,0
 851         stb     r0,PACASOFTIRQEN(r13);
 852         TRACE_DISABLE_INTS
 853         b       do_restore
 854
 855         /*
 856          * Something did happen, check if a re-emit is needed
 857          * (this also clears paca->irq_happened)
 858          */
 859 restore_check_irq_replay:
 860         /* XXX: We could implement a fast path here where we check
 861          * for irq_happened being just 0x01, in which case we can
 862          * clear it and return. That means that we would potentially
 863          * miss a decrementer having wrapped all the way around.
 864          *
 865          * Still, this might be useful for things like hash_page
 866          */
 867         bl      .__check_irq_replay
 868         cmpwi   cr0,r3,0
 869         beq     restore_no_replay
 870
 871         /*
 872          * We need to re-emit an interrupt. We do so by re-using our
 873          * existing exception frame. We first change the trap value,
 874          * but we need to ensure we preserve the low nibble of it
 875          */
 876         ld      r4,_TRAP(r1)
 877         clrldi  r4,r4,60
 878         or      r4,r4,r3
 879         std     r4,_TRAP(r1)
 880
 881         /*
 882          * Then find the right handler and call it. Interrupts are
 883          * still soft-disabled and we keep them that way.
 884         */
 885         cmpwi   cr0,r3,0x500
 886         bne     1f
 887         addi    r3,r1,STACK_FRAME_OVERHEAD;
 888         bl      .do_IRQ
 889         b       .ret_from_except
 890 1:      cmpwi   cr0,r3,0x900
 891         bne     1f
 892         addi    r3,r1,STACK_FRAME_OVERHEAD;
 893         bl      .timer_interrupt
 894         b       .ret_from_except
 895 #ifdef CONFIG_PPC_DOORBELL
 896 1:
 897 #ifdef CONFIG_PPC_BOOK3E
 898         cmpwi   cr0,r3,0x280
 899 #else
 900         BEGIN_FTR_SECTION
 901                 cmpwi   cr0,r3,0xe80
 902         FTR_SECTION_ELSE
 903                 cmpwi   cr0,r3,0xa00
 904         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE)
 905 #endif /* CONFIG_PPC_BOOK3E */
 906         bne     1f
 907         addi    r3,r1,STACK_FRAME_OVERHEAD;
 908         bl      .doorbell_exception
 909         b       .ret_from_except
 910 #endif /* CONFIG_PPC_DOORBELL */
 911 1:      b       .ret_from_except /* What else to do here ? */
 912
 913 unrecov_restore:
 914         addi    r3,r1,STACK_FRAME_OVERHEAD
 915         bl      .unrecoverable_exception
 916         b       unrecov_restore
 917
 918 #ifdef CONFIG_PPC_RTAS
 919 /*
 920  * On CHRP, the Run-Time Abstraction Services (RTAS) have to be
 921  * called with the MMU off.
 922  *
 923  * In addition, we need to be in 32b mode, at least for now.
 924  *
 925  * Note: r3 is an input parameter to rtas, so don't trash it...
 926  */
 927 _GLOBAL(enter_rtas)
 928         mflr    r0
 929         std     r0,16(r1)
 930         stdu    r1,-RTAS_FRAME_SIZE(r1) /* Save SP and create stack space. */
 931
 932         /* Because RTAS is running in 32b mode, it clobbers the high order half
 933          * of all registers that it saves.  We therefore save those registers
 934          * RTAS might touch to the stack.  (r0, r3-r13 are caller saved)
 935          */
 936         SAVE_GPR(2, r1)                 /* Save the TOC */
 937         SAVE_GPR(13, r1)                /* Save paca */
 938         SAVE_8GPRS(14, r1)              /* Save the non-volatiles */
 939         SAVE_10GPRS(22, r1)             /* ditto */
 940
 941         mfcr    r4
 942         std     r4,_CCR(r1)
 943         mfctr   r5
 944         std     r5,_CTR(r1)
 945         mfspr   r6,SPRN_XER
 946         std     r6,_XER(r1)
 947         mfdar   r7
 948         std     r7,_DAR(r1)
 949         mfdsisr r8
 950         std     r8,_DSISR(r1)
 951
 952         /* Temporary workaround to clear CR until RTAS can be modified to
 953          * ignore all bits.
 954          */
 955         li      r0,0
 956         mtcr    r0
 957
 958 #ifdef CONFIG_BUG
 959         /* There is no way it is acceptable to get here with interrupts enabled,
 960          * check it with the asm equivalent of WARN_ON
 961          */
 962         lbz     r0,PACASOFTIRQEN(r13)
 963 1:      tdnei   r0,0
 964         EMIT_BUG_ENTRY 1b,__FILE__,__LINE__,BUGFLAG_WARNING
 965 #endif
 966
 967         /* Hard-disable interrupts */
 968         mfmsr   r6
 969         rldicl  r7,r6,48,1
 970         rotldi  r7,r7,16
 971         mtmsrd  r7,1
 972
 973         /* Unfortunately, the stack pointer and the MSR are also clobbered,
 974          * so they are saved in the PACA which allows us to restore
 975          * our original state after RTAS returns.
 976          */
 977         std     r1,PACAR1(r13)
 978         std     r6,PACASAVEDMSR(r13)
 979
 980         /* Setup our real return addr */
 981         LOAD_REG_ADDR(r4,.rtas_return_loc)
 982         clrldi  r4,r4,2                 /* convert to realmode address */
 983         mtlr    r4
 984
 985         li      r0,0
 986         ori     r0,r0,MSR_EE|MSR_SE|MSR_BE|MSR_RI
 987         andc    r0,r6,r0
 988
 989         li      r9,1
 990         rldicr  r9,r9,MSR_SF_LG,(63-MSR_SF_LG)
 991         ori     r9,r9,MSR_IR|MSR_DR|MSR_FE0|MSR_FE1|MSR_FP|MSR_RI
 992         andc    r6,r0,r9
 993         sync                            /* disable interrupts so SRR0/1 */
 994         mtmsrd  r0                      /* don't get trashed */
 995
 996         LOAD_REG_ADDR(r4, rtas)
 997         ld      r5,RTASENTRY(r4)        /* get the rtas->entry value */
 998         ld      r4,RTASBASE(r4)         /* get the rtas->base value */
 999
1000         mtspr   SPRN_SRR0,r5
1001         mtspr   SPRN_SRR1,r6
1002         rfid
1003         b       .       /* prevent speculative execution */
1004
1005 _STATIC(rtas_return_loc)
1006         /* relocation is off at this point */
1007         GET_PACA(r4)
1008         clrldi  r4,r4,2                 /* convert to realmode address */
1009
1010         bcl     20,31,$+4
1011 0:      mflr    r3
1012         ld      r3,(1f-0b)(r3)          /* get &.rtas_restore_regs */
1013
1014         mfmsr   r6
1015         li      r0,MSR_RI
1016         andc    r6,r6,r0
1017         sync
1018         mtmsrd  r6
1019
1020         ld      r1,PACAR1(r4)           /* Restore our SP */
1021         ld      r4,PACASAVEDMSR(r4)     /* Restore our MSR */
1022
1023         mtspr   SPRN_SRR0,r3
1024         mtspr   SPRN_SRR1,r4
1025         rfid
1026         b       .       /* prevent speculative execution */
1027
1028         .align  3
1029 1:      .llong  .rtas_restore_regs
1030
1031 _STATIC(rtas_restore_regs)
1032         /* relocation is on at this point */
1033         REST_GPR(2, r1)                 /* Restore the TOC */
1034         REST_GPR(13, r1)                /* Restore paca */
1035         REST_8GPRS(14, r1)              /* Restore the non-volatiles */
1036         REST_10GPRS(22, r1)             /* ditto */
1037
1038         GET_PACA(r13)
1039
1040         ld      r4,_CCR(r1)
1041         mtcr    r4
1042         ld      r5,_CTR(r1)
1043         mtctr   r5
1044         ld      r6,_XER(r1)
1045         mtspr   SPRN_XER,r6
1046         ld      r7,_DAR(r1)
1047         mtdar   r7
1048         ld      r8,_DSISR(r1)
1049         mtdsisr r8
1050
1051         addi    r1,r1,RTAS_FRAME_SIZE   /* Unstack our frame */
1052         ld      r0,16(r1)               /* get return address */
1053
1054         mtlr    r0
1055         blr                             /* return to caller */
1056
1057 #endif /* CONFIG_PPC_RTAS */
1058
1059 _GLOBAL(enter_prom)
1060         mflr    r0
1061         std     r0,16(r1)
1062         stdu    r1,-PROM_FRAME_SIZE(r1) /* Save SP and create stack space */
1063
1064         /* Because PROM is running in 32b mode, it clobbers the high order half
1065          * of all registers that it saves.  We therefore save those registers
1066          * PROM might touch to the stack.  (r0, r3-r13 are caller saved)
1067          */
1068         SAVE_GPR(2, r1)
1069         SAVE_GPR(13, r1)
1070         SAVE_8GPRS(14, r1)
1071         SAVE_10GPRS(22, r1)
1072         mfcr    r10
1073         mfmsr   r11
1074         std     r10,_CCR(r1)
1075         std     r11,_MSR(r1)
1076
1077         /* Get the PROM entrypoint */
1078         mtlr    r4
1079
1080         /* Switch MSR to 32 bits mode
1081          */
1082 #ifdef CONFIG_PPC_BOOK3E
1083         rlwinm  r11,r11,0,1,31
1084         mtmsr   r11
1085 #else /* CONFIG_PPC_BOOK3E */
1086         mfmsr   r11
1087         li      r12,1
1088         rldicr  r12,r12,MSR_SF_LG,(63-MSR_SF_LG)
1089         andc    r11,r11,r12
1090         li      r12,1
1091         rldicr  r12,r12,MSR_ISF_LG,(63-MSR_ISF_LG)
1092         andc    r11,r11,r12
1093         mtmsrd  r11
1094 #endif /* CONFIG_PPC_BOOK3E */
1095         isync
1096
1097         /* Enter PROM here... */
1098         blrl
1099
1100         /* Just make sure that r1 top 32 bits didn't get
1101          * corrupt by OF
1102          */
1103         rldicl  r1,r1,0,32
1104
1105         /* Restore the MSR (back to 64 bits) */
1106         ld      r0,_MSR(r1)
1107         MTMSRD(r0)
1108         isync
1109
1110         /* Restore other registers */
1111         REST_GPR(2, r1)
1112         REST_GPR(13, r1)
1113         REST_8GPRS(14, r1)
1114         REST_10GPRS(22, r1)
1115         ld      r4,_CCR(r1)
1116         mtcr    r4
1117
1118         addi    r1,r1,PROM_FRAME_SIZE
1119         ld      r0,16(r1)
1120         mtlr    r0
1121         blr
1122
1123 #ifdef CONFIG_FUNCTION_TRACER
1124 #ifdef CONFIG_DYNAMIC_FTRACE
1125 _GLOBAL(mcount)
1126 _GLOBAL(_mcount)
1127         blr
1128
1129 _GLOBAL(ftrace_caller)
1130         /* Taken from output of objdump from lib64/glibc */
1131         mflr    r3
1132         ld      r11, 0(r1)
1133         stdu    r1, -112(r1)
1134         std     r3, 128(r1)
1135         ld      r4, 16(r11)
1136         subi    r3, r3, MCOUNT_INSN_SIZE
1137 .globl ftrace_call
1138 ftrace_call:
1139         bl      ftrace_stub
1140         nop
1141 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1142 .globl ftrace_graph_call
1143 ftrace_graph_call:
1144         b       ftrace_graph_stub
1145 _GLOBAL(ftrace_graph_stub)
1146 #endif
1147         ld      r0, 128(r1)
1148         mtlr    r0
1149         addi    r1, r1, 112
1150 _GLOBAL(ftrace_stub)
1151         blr
1152 #else
1153 _GLOBAL(mcount)
1154         blr
1155
1156 _GLOBAL(_mcount)
1157         /* Taken from output of objdump from lib64/glibc */
1158         mflr    r3
1159         ld      r11, 0(r1)
1160         stdu    r1, -112(r1)
1161         std     r3, 128(r1)
1162         ld      r4, 16(r11)
1163
1164         subi    r3, r3, MCOUNT_INSN_SIZE
1165         LOAD_REG_ADDR(r5,ftrace_trace_function)
1166         ld      r5,0(r5)
1167         ld      r5,0(r5)
1168         mtctr   r5
1169         bctrl
1170         nop
1171
1172
1173 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1174         b       ftrace_graph_caller
1175 #endif
1176         ld      r0, 128(r1)
1177         mtlr    r0
1178         addi    r1, r1, 112
1179 _GLOBAL(ftrace_stub)
1180         blr
1181
1182 #endif /* CONFIG_DYNAMIC_FTRACE */
1183
1184 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1185 _GLOBAL(ftrace_graph_caller)
1186         /* load r4 with local address */
1187         ld      r4, 128(r1)
1188         subi    r4, r4, MCOUNT_INSN_SIZE
1189
1190         /* get the parent address */
1191         ld      r11, 112(r1)
1192         addi    r3, r11, 16
1193
1194         bl      .prepare_ftrace_return
1195         nop
1196
1197         ld      r0, 128(r1)
1198         mtlr    r0
1199         addi    r1, r1, 112
1200         blr
1201
1202 _GLOBAL(return_to_handler)
1203         /* need to save return values */
1204         std     r4,  -24(r1)
1205         std     r3,  -16(r1)
1206         std     r31, -8(r1)
1207         mr      r31, r1
1208         stdu    r1, -112(r1)
1209
1210         bl      .ftrace_return_to_handler
1211         nop
1212
1213         /* return value has real return address */
1214         mtlr    r3
1215
1216         ld      r1, 0(r1)
1217         ld      r4,  -24(r1)
1218         ld      r3,  -16(r1)
1219         ld      r31, -8(r1)
1220
1221         /* Jump back to real return address */
1222         blr
1223
1224 _GLOBAL(mod_return_to_handler)
1225         /* need to save return values */
1226         std     r4,  -32(r1)
1227         std     r3,  -24(r1)
1228         /* save TOC */
1229         std     r2,  -16(r1)
1230         std     r31, -8(r1)
1231         mr      r31, r1
1232         stdu    r1, -112(r1)
1233
1234         /*
1235          * We are in a module using the module's TOC.
1236          * Switch to our TOC to run inside the core kernel.
1237          */
1238         ld      r2, PACATOC(r13)
1239
1240         bl      .ftrace_return_to_handler
1241         nop
1242
1243         /* return value has real return address */
1244         mtlr    r3
1245
1246         ld      r1, 0(r1)
1247         ld      r4,  -32(r1)
1248         ld      r3,  -24(r1)
1249         ld      r2,  -16(r1)
1250         ld      r31, -8(r1)
1251
1252         /* Jump back to real return address */
1253         blr
1254 #endif /* CONFIG_FUNCTION_GRAPH_TRACER */
1255 #endif /* CONFIG_FUNCTION_TRACER */