arch/powerpc/kernel/head_8xx.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   5  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   6  *  Low-level exception handlers and MMU support
   7  *  rewritten by Paul Mackerras.
   8  *    Copyright (C) 1996 Paul Mackerras.
   9  *  MPC8xx modifications by Dan Malek
  10  *    Copyright (C) 1997 Dan Malek (dmalek@jlc.net).
  11  *
  12  *  This file contains low-level support and setup for PowerPC 8xx
  13  *  embedded processors, including trap and interrupt dispatch.
  14  *
  15  *  This program is free software; you can redistribute it and/or
  16  *  modify it under the terms of the GNU General Public License
  17  *  as published by the Free Software Foundation; either version
  18  *  2 of the License, or (at your option) any later version.
  19  *
  20  */
  21
  22 #include <linux/init.h>
  23 #include <asm/processor.h>
  24 #include <asm/page.h>
  25 #include <asm/mmu.h>
  26 #include <asm/cache.h>
  27 #include <asm/pgtable.h>
  28 #include <asm/cputable.h>
  29 #include <asm/thread_info.h>
  30 #include <asm/ppc_asm.h>
  31 #include <asm/asm-offsets.h>
  32 #include <asm/ptrace.h>
  33 #include <asm/fixmap.h>
  34
  35 /* Macro to make the code more readable. */
  36 #ifdef CONFIG_8xx_CPU6
  37 #define SPRN_MI_TWC_ADDR        0x2b80
  38 #define SPRN_MI_RPN_ADDR        0x2d80
  39 #define SPRN_MD_TWC_ADDR        0x3b80
  40 #define SPRN_MD_RPN_ADDR        0x3d80
  41
  42 #define MTSPR_CPU6(spr, reg, treg)      \
  43         li      treg, spr##_ADDR;       \
  44         stw     treg, 12(r0);           \
  45         lwz     treg, 12(r0);           \
  46         mtspr   spr, reg
  47 #else
  48 #define MTSPR_CPU6(spr, reg, treg)      \
  49         mtspr   spr, reg
  50 #endif
  51
  52 /* Macro to test if an address is a kernel address */
  53 #if CONFIG_TASK_SIZE <= 0x80000000 && CONFIG_PAGE_OFFSET >= 0x80000000
  54 #define IS_KERNEL(tmp, addr)            \
  55         andis.  tmp, addr, 0x8000       /* Address >= 0x80000000 */
  56 #define BRANCH_UNLESS_KERNEL(label)     beq     label
  57 #else
  58 #define IS_KERNEL(tmp, addr)            \
  59         rlwinm  tmp, addr, 16, 16, 31;  \
  60         cmpli   cr0, tmp, PAGE_OFFSET >> 16
  61 #define BRANCH_UNLESS_KERNEL(label)     blt     label
  62 #endif
  63
  64
  65 /*
  66  * Value for the bits that have fixed value in RPN entries.
  67  * Also used for tagging DAR for DTLBerror.
  68  */
  69 #ifdef CONFIG_PPC_16K_PAGES
  70 #define RPN_PATTERN     (0x00f0 | MD_SPS16K)
  71 #else
  72 #define RPN_PATTERN     0x00f0
  73 #endif
  74
  75         __HEAD
  76 _ENTRY(_stext);
  77 _ENTRY(_start);
  78
  79 /* MPC8xx
  80  * This port was done on an MBX board with an 860.  Right now I only
  81  * support an ELF compressed (zImage) boot from EPPC-Bug because the
  82  * code there loads up some registers before calling us:
  83  *   r3: ptr to board info data
  84  *   r4: initrd_start or if no initrd then 0
  85  *   r5: initrd_end - unused if r4 is 0
  86  *   r6: Start of command line string
  87  *   r7: End of command line string
  88  *
  89  * I decided to use conditional compilation instead of checking PVR and
  90  * adding more processor specific branches around code I don't need.
  91  * Since this is an embedded processor, I also appreciate any memory
  92  * savings I can get.
  93  *
  94  * The MPC8xx does not have any BATs, but it supports large page sizes.
  95  * We first initialize the MMU to support 8M byte pages, then load one
  96  * entry into each of the instruction and data TLBs to map the first
  97  * 8M 1:1.  I also mapped an additional I/O space 1:1 so we can get to
  98  * the "internal" processor registers before MMU_init is called.
  99  *
 100  *      -- Dan
 101  */
 102         .globl  __start
 103 __start:
 104         mr      r31,r3                  /* save device tree ptr */
 105
 106         /* We have to turn on the MMU right away so we get cache modes
 107          * set correctly.
 108          */
 109         bl      initial_mmu
 110
 111 /* We now have the lower 8 Meg mapped into TLB entries, and the caches
 112  * ready to work.
 113  */
 114
 115 turn_on_mmu:
 116         mfmsr   r0
 117         ori     r0,r0,MSR_DR|MSR_IR
 118         mtspr   SPRN_SRR1,r0
 119         lis     r0,start_here@h
 120         ori     r0,r0,start_here@l
 121         mtspr   SPRN_SRR0,r0
 122         SYNC
 123         rfi                             /* enables MMU */
 124
 125 /*
 126  * Exception entry code.  This code runs with address translation
 127  * turned off, i.e. using physical addresses.
 128  * We assume sprg3 has the physical address of the current
 129  * task's thread_struct.
 130  */
 131 #define EXCEPTION_PROLOG        \
 132         EXCEPTION_PROLOG_0;     \
 133         mfcr    r10;            \
 134         EXCEPTION_PROLOG_1;     \
 135         EXCEPTION_PROLOG_2
 136
 137 #define EXCEPTION_PROLOG_0      \
 138         mtspr   SPRN_SPRG_SCRATCH0,r10; \
 139         mtspr   SPRN_SPRG_SCRATCH1,r11
 140
 141 #define EXCEPTION_PROLOG_1      \
 142         mfspr   r11,SPRN_SRR1;          /* check whether user or kernel */ \
 143         andi.   r11,r11,MSR_PR; \
 144         tophys(r11,r1);                 /* use tophys(r1) if kernel */ \
 145         beq     1f;             \
 146         mfspr   r11,SPRN_SPRG_THREAD;   \
 147         lwz     r11,THREAD_INFO-THREAD(r11);    \
 148         addi    r11,r11,THREAD_SIZE;    \
 149         tophys(r11,r11);        \
 150 1:      subi    r11,r11,INT_FRAME_SIZE  /* alloc exc. frame */
 151
 152
 153 #define EXCEPTION_PROLOG_2      \
 154         CLR_TOP32(r11);         \
 155         stw     r10,_CCR(r11);          /* save registers */ \
 156         stw     r12,GPR12(r11); \
 157         stw     r9,GPR9(r11);   \
 158         mfspr   r10,SPRN_SPRG_SCRATCH0; \
 159         stw     r10,GPR10(r11); \
 160         mfspr   r12,SPRN_SPRG_SCRATCH1; \
 161         stw     r12,GPR11(r11); \
 162         mflr    r10;            \
 163         stw     r10,_LINK(r11); \
 164         mfspr   r12,SPRN_SRR0;  \
 165         mfspr   r9,SPRN_SRR1;   \
 166         stw     r1,GPR1(r11);   \
 167         stw     r1,0(r11);      \
 168         tovirt(r1,r11);                 /* set new kernel sp */ \
 169         li      r10,MSR_KERNEL & ~(MSR_IR|MSR_DR); /* can take exceptions */ \
 170         MTMSRD(r10);                    /* (except for mach check in rtas) */ \
 171         stw     r0,GPR0(r11);   \
 172         SAVE_4GPRS(3, r11);     \
 173         SAVE_2GPRS(7, r11)
 174
 175 /*
 176  * Exception exit code.
 177  */
 178 #define EXCEPTION_EPILOG_0      \
 179         mfspr   r10,SPRN_SPRG_SCRATCH0; \
 180         mfspr   r11,SPRN_SPRG_SCRATCH1
 181
 182 /*
 183  * Note: code which follows this uses cr0.eq (set if from kernel),
 184  * r11, r12 (SRR0), and r9 (SRR1).
 185  *
 186  * Note2: once we have set r1 we are in a position to take exceptions
 187  * again, and we could thus set MSR:RI at that point.
 188  */
 189
 190 /*
 191  * Exception vectors.
 192  */
 193 #define EXCEPTION(n, label, hdlr, xfer)         \
 194         . = n;                                  \
 195 label:                                          \
 196         EXCEPTION_PROLOG;                       \
 197         addi    r3,r1,STACK_FRAME_OVERHEAD;     \
 198         xfer(n, hdlr)
 199
 200 #define EXC_XFER_TEMPLATE(n, hdlr, trap, copyee, tfer, ret)     \
 201         li      r10,trap;                                       \
 202         stw     r10,_TRAP(r11);                                 \
 203         li      r10,MSR_KERNEL;                                 \
 204         copyee(r10, r9);                                        \
 205         bl      tfer;                                           \
 206 i##n:                                                           \
 207         .long   hdlr;                                           \
 208         .long   ret
 209
 210 #define COPY_EE(d, s)           rlwimi d,s,0,16,16
 211 #define NOCOPY(d, s)
 212
 213 #define EXC_XFER_STD(n, hdlr)           \
 214         EXC_XFER_TEMPLATE(n, hdlr, n, NOCOPY, transfer_to_handler_full, \
 215                           ret_from_except_full)
 216
 217 #define EXC_XFER_LITE(n, hdlr)          \
 218         EXC_XFER_TEMPLATE(n, hdlr, n+1, NOCOPY, transfer_to_handler, \
 219                           ret_from_except)
 220
 221 #define EXC_XFER_EE(n, hdlr)            \
 222         EXC_XFER_TEMPLATE(n, hdlr, n, COPY_EE, transfer_to_handler_full, \
 223                           ret_from_except_full)
 224
 225 #define EXC_XFER_EE_LITE(n, hdlr)       \
 226         EXC_XFER_TEMPLATE(n, hdlr, n+1, COPY_EE, transfer_to_handler, \
 227                           ret_from_except)
 228
 229 /* System reset */
 230         EXCEPTION(0x100, Reset, unknown_exception, EXC_XFER_STD)
 231
 232 /* Machine check */
 233         . = 0x200
 234 MachineCheck:
 235         EXCEPTION_PROLOG
 236         mfspr r4,SPRN_DAR
 237         stw r4,_DAR(r11)
 238         li r5,RPN_PATTERN
 239         mtspr SPRN_DAR,r5       /* Tag DAR, to be used in DTLB Error */
 240         mfspr r5,SPRN_DSISR
 241         stw r5,_DSISR(r11)
 242         addi r3,r1,STACK_FRAME_OVERHEAD
 243         EXC_XFER_STD(0x200, machine_check_exception)
 244
 245 /* Data access exception.
 246  * This is "never generated" by the MPC8xx.
 247  */
 248         . = 0x300
 249 DataAccess:
 250
 251 /* Instruction access exception.
 252  * This is "never generated" by the MPC8xx.
 253  */
 254         . = 0x400
 255 InstructionAccess:
 256
 257 /* External interrupt */
 258         EXCEPTION(0x500, HardwareInterrupt, do_IRQ, EXC_XFER_LITE)
 259
 260 /* Alignment exception */
 261         . = 0x600
 262 Alignment:
 263         EXCEPTION_PROLOG
 264         mfspr   r4,SPRN_DAR
 265         stw     r4,_DAR(r11)
 266         li      r5,RPN_PATTERN
 267         mtspr   SPRN_DAR,r5     /* Tag DAR, to be used in DTLB Error */
 268         mfspr   r5,SPRN_DSISR
 269         stw     r5,_DSISR(r11)
 270         addi    r3,r1,STACK_FRAME_OVERHEAD
 271         EXC_XFER_EE(0x600, alignment_exception)
 272
 273 /* Program check exception */
 274         EXCEPTION(0x700, ProgramCheck, program_check_exception, EXC_XFER_STD)
 275
 276 /* No FPU on MPC8xx.  This exception is not supposed to happen.
 277 */
 278         EXCEPTION(0x800, FPUnavailable, unknown_exception, EXC_XFER_STD)
 279
 280 /* Decrementer */
 281         EXCEPTION(0x900, Decrementer, timer_interrupt, EXC_XFER_LITE)
 282
 283         EXCEPTION(0xa00, Trap_0a, unknown_exception, EXC_XFER_EE)
 284         EXCEPTION(0xb00, Trap_0b, unknown_exception, EXC_XFER_EE)
 285
 286 /* System call */
 287         . = 0xc00
 288 SystemCall:
 289         EXCEPTION_PROLOG
 290         EXC_XFER_EE_LITE(0xc00, DoSyscall)
 291
 292 /* Single step - not used on 601 */
 293         EXCEPTION(0xd00, SingleStep, single_step_exception, EXC_XFER_STD)
 294         EXCEPTION(0xe00, Trap_0e, unknown_exception, EXC_XFER_EE)
 295         EXCEPTION(0xf00, Trap_0f, unknown_exception, EXC_XFER_EE)
 296
 297 /* On the MPC8xx, this is a software emulation interrupt.  It occurs
 298  * for all unimplemented and illegal instructions.
 299  */
 300         EXCEPTION(0x1000, SoftEmu, SoftwareEmulation, EXC_XFER_STD)
 301
 302         . = 0x1100
 303 /*
 304  * For the MPC8xx, this is a software tablewalk to load the instruction
 305  * TLB.  The task switch loads the M_TW register with the pointer to the first
 306  * level table.
 307  * If we discover there is no second level table (value is zero) or if there
 308  * is an invalid pte, we load that into the TLB, which causes another fault
 309  * into the TLB Error interrupt where we can handle such problems.
 310  * We have to use the MD_xxx registers for the tablewalk because the
 311  * equivalent MI_xxx registers only perform the attribute functions.
 312  */
 313
 314 #ifdef CONFIG_8xx_CPU15
 315 #define INVALIDATE_ADJACENT_PAGES_CPU15(tmp, addr)      \
 316         addi    tmp, addr, PAGE_SIZE;   \
 317         tlbie   tmp;                    \
 318         addi    tmp, addr, -PAGE_SIZE;  \
 319         tlbie   tmp
 320 #else
 321 #define INVALIDATE_ADJACENT_PAGES_CPU15(tmp, addr)
 322 #endif
 323
 324 InstructionTLBMiss:
 325 #ifdef CONFIG_8xx_CPU6
 326         mtspr   SPRN_SPRG_SCRATCH2, r3
 327 #endif
 328         EXCEPTION_PROLOG_0
 329
 330         /* If we are faulting a kernel address, we have to use the
 331          * kernel page tables.
 332          */
 333 #if defined(CONFIG_MODULES) || defined (CONFIG_DEBUG_PAGEALLOC)
 334         /* Only modules will cause ITLB Misses as we always
 335          * pin the first 8MB of kernel memory */
 336         mfspr   r11, SPRN_SRR0  /* Get effective address of fault */
 337         INVALIDATE_ADJACENT_PAGES_CPU15(r10, r11)
 338         mfcr    r10
 339         IS_KERNEL(r11, r11)
 340         mfspr   r11, SPRN_M_TW  /* Get level 1 table */
 341         BRANCH_UNLESS_KERNEL(3f)
 342         lis     r11, (swapper_pg_dir-PAGE_OFFSET)@ha
 343 3:
 344         mtcr    r10
 345         mfspr   r10, SPRN_SRR0  /* Get effective address of fault */
 346 #else
 347         mfspr   r10, SPRN_SRR0  /* Get effective address of fault */
 348         INVALIDATE_ADJACENT_PAGES_CPU15(r11, r10)
 349         mfspr   r11, SPRN_M_TW  /* Get level 1 table base address */
 350 #endif
 351         /* Insert level 1 index */
 352         rlwimi  r11, r10, 32 - ((PAGE_SHIFT - 2) << 1), (PAGE_SHIFT - 2) << 1, 29
 353         lwz     r11, (swapper_pg_dir-PAGE_OFFSET)@l(r11)        /* Get the level 1 entry */
 354
 355         /* Extract level 2 index */
 356         rlwinm  r10, r10, 32 - (PAGE_SHIFT - 2), 32 - PAGE_SHIFT, 29
 357         rlwimi  r10, r11, 0, 0, 32 - PAGE_SHIFT - 1     /* Add level 2 base */
 358         lwz     r10, 0(r10)     /* Get the pte */
 359
 360         /* Insert the APG into the TWC from the Linux PTE. */
 361         rlwimi  r11, r10, 0, 25, 26
 362         /* Load the MI_TWC with the attributes for this "segment." */
 363         MTSPR_CPU6(SPRN_MI_TWC, r11, r3)        /* Set segment attributes */
 364
 365 #ifdef CONFIG_SWAP
 366         rlwinm  r11, r10, 32-5, _PAGE_PRESENT
 367         and     r11, r11, r10
 368         rlwimi  r10, r11, 0, _PAGE_PRESENT
 369 #endif
 370         li      r11, RPN_PATTERN
 371         /* The Linux PTE won't go exactly into the MMU TLB.
 372          * Software indicator bits 20-23 and 28 must be clear.
 373          * Software indicator bits 24, 25, 26, and 27 must be
 374          * set.  All other Linux PTE bits control the behavior
 375          * of the MMU.
 376          */
 377         rlwimi  r10, r11, 0, 0x0ff8     /* Set 24-27, clear 20-23,28 */
 378         MTSPR_CPU6(SPRN_MI_RPN, r10, r3)        /* Update TLB entry */
 379
 380         /* Restore registers */
 381 #ifdef CONFIG_8xx_CPU6
 382         mfspr   r3, SPRN_SPRG_SCRATCH2
 383 #endif
 384         EXCEPTION_EPILOG_0
 385         rfi
 386
 387         . = 0x1200
 388 DataStoreTLBMiss:
 389         mtspr   SPRN_SPRG_SCRATCH2, r3
 390         EXCEPTION_PROLOG_0
 391         mfcr    r3
 392
 393         /* If we are faulting a kernel address, we have to use the
 394          * kernel page tables.
 395          */
 396         mfspr   r10, SPRN_MD_EPN
 397         IS_KERNEL(r11, r10)
 398         mfspr   r11, SPRN_M_TW  /* Get level 1 table */
 399         BRANCH_UNLESS_KERNEL(3f)
 400         lis     r11, (swapper_pg_dir-PAGE_OFFSET)@ha
 401 3:
 402
 403         /* Insert level 1 index */
 404         rlwimi  r11, r10, 32 - ((PAGE_SHIFT - 2) << 1), (PAGE_SHIFT - 2) << 1, 29
 405         lwz     r11, (swapper_pg_dir-PAGE_OFFSET)@l(r11)        /* Get the level 1 entry */
 406         mtcr    r11
 407         bt-     28,DTLBMiss8M           /* bit 28 = Large page (8M) */
 408         mtcr    r3
 409
 410         /* We have a pte table, so load fetch the pte from the table.
 411          */
 412         /* Extract level 2 index */
 413         rlwinm  r10, r10, 32 - (PAGE_SHIFT - 2), 32 - PAGE_SHIFT, 29
 414         rlwimi  r10, r11, 0, 0, 32 - PAGE_SHIFT - 1     /* Add level 2 base */
 415         lwz     r10, 0(r10)     /* Get the pte */
 416
 417         /* Insert the Guarded flag and APG into the TWC from the Linux PTE.
 418          * It is bit 26-27 of both the Linux PTE and the TWC (at least
 419          * I got that right :-).  It will be better when we can put
 420          * this into the Linux pgd/pmd and load it in the operation
 421          * above.
 422          */
 423         rlwimi  r11, r10, 0, 26, 27
 424         /* Insert the WriteThru flag into the TWC from the Linux PTE.
 425          * It is bit 25 in the Linux PTE and bit 30 in the TWC
 426          */
 427         rlwimi  r11, r10, 32-5, 30, 30
 428         MTSPR_CPU6(SPRN_MD_TWC, r11, r3)
 429
 430         /* Both _PAGE_ACCESSED and _PAGE_PRESENT has to be set.
 431          * We also need to know if the insn is a load/store, so:
 432          * Clear _PAGE_PRESENT and load that which will
 433          * trap into DTLB Error with store bit set accordinly.
 434          */
 435         /* PRESENT=0x1, ACCESSED=0x20
 436          * r11 = ((r10 & PRESENT) & ((r10 & ACCESSED) >> 5));
 437          * r10 = (r10 & ~PRESENT) | r11;
 438          */
 439 #ifdef CONFIG_SWAP
 440         rlwinm  r11, r10, 32-5, _PAGE_PRESENT
 441         and     r11, r11, r10
 442         rlwimi  r10, r11, 0, _PAGE_PRESENT
 443 #endif
 444         /* The Linux PTE won't go exactly into the MMU TLB.
 445          * Software indicator bits 22 and 28 must be clear.
 446          * Software indicator bits 24, 25, 26, and 27 must be
 447          * set.  All other Linux PTE bits control the behavior
 448          * of the MMU.
 449          */
 450         li      r11, RPN_PATTERN
 451         rlwimi  r10, r11, 0, 24, 28     /* Set 24-27, clear 28 */
 452         rlwimi  r10, r11, 0, 20, 20     /* clear 20 */
 453         MTSPR_CPU6(SPRN_MD_RPN, r10, r3)        /* Update TLB entry */
 454
 455         /* Restore registers */
 456         mfspr   r3, SPRN_SPRG_SCRATCH2
 457         mtspr   SPRN_DAR, r11   /* Tag DAR */
 458         EXCEPTION_EPILOG_0
 459         rfi
 460
 461 DTLBMiss8M:
 462         mtcr    r3
 463         ori     r11, r11, MD_SVALID
 464         MTSPR_CPU6(SPRN_MD_TWC, r11, r3)
 465 #ifdef CONFIG_PPC_16K_PAGES
 466         /*
 467          * In 16k pages mode, each PGD entry defines a 64M block.
 468          * Here we select the 8M page within the block.
 469          */
 470         rlwimi  r11, r10, 0, 0x03800000
 471 #endif
 472         rlwinm  r10, r11, 0, 0xff800000
 473         ori     r10, r10, 0xf0 | MD_SPS16K | _PAGE_SHARED | _PAGE_DIRTY | \
 474                           _PAGE_PRESENT
 475         MTSPR_CPU6(SPRN_MD_RPN, r10, r3)        /* Update TLB entry */
 476
 477         li      r11, RPN_PATTERN
 478         mfspr   r3, SPRN_SPRG_SCRATCH2
 479         mtspr   SPRN_DAR, r11   /* Tag DAR */
 480         EXCEPTION_EPILOG_0
 481         rfi
 482
 483
 484 /* This is an instruction TLB error on the MPC8xx.  This could be due
 485  * to many reasons, such as executing guarded memory or illegal instruction
 486  * addresses.  There is nothing to do but handle a big time error fault.
 487  */
 488         . = 0x1300
 489 InstructionTLBError:
 490         EXCEPTION_PROLOG
 491         mr      r4,r12
 492         mr      r5,r9
 493         andis.  r10,r5,0x4000
 494         beq+    1f
 495         tlbie   r4
 496         /* 0x400 is InstructionAccess exception, needed by bad_page_fault() */
 497 1:      EXC_XFER_LITE(0x400, handle_page_fault)
 498
 499 /* This is the data TLB error on the MPC8xx.  This could be due to
 500  * many reasons, including a dirty update to a pte.  We bail out to
 501  * a higher level function that can handle it.
 502  */
 503         . = 0x1400
 504 DataTLBError:
 505         EXCEPTION_PROLOG_0
 506         mfcr    r10
 507
 508         mfspr   r11, SPRN_DAR
 509         cmpwi   cr0, r11, RPN_PATTERN
 510         beq-    FixupDAR        /* must be a buggy dcbX, icbi insn. */
 511 DARFixed:/* Return from dcbx instruction bug workaround */
 512         EXCEPTION_PROLOG_1
 513         EXCEPTION_PROLOG_2
 514         mfspr   r5,SPRN_DSISR
 515         stw     r5,_DSISR(r11)
 516         mfspr   r4,SPRN_DAR
 517         andis.  r10,r5,0x4000
 518         beq+    1f
 519         tlbie   r4
 520 1:      li      r10,RPN_PATTERN
 521         mtspr   SPRN_DAR,r10    /* Tag DAR, to be used in DTLB Error */
 522         /* 0x300 is DataAccess exception, needed by bad_page_fault() */
 523         EXC_XFER_LITE(0x300, handle_page_fault)
 524
 525         EXCEPTION(0x1500, Trap_15, unknown_exception, EXC_XFER_EE)
 526         EXCEPTION(0x1600, Trap_16, unknown_exception, EXC_XFER_EE)
 527         EXCEPTION(0x1700, Trap_17, unknown_exception, EXC_XFER_EE)
 528         EXCEPTION(0x1800, Trap_18, unknown_exception, EXC_XFER_EE)
 529         EXCEPTION(0x1900, Trap_19, unknown_exception, EXC_XFER_EE)
 530         EXCEPTION(0x1a00, Trap_1a, unknown_exception, EXC_XFER_EE)
 531         EXCEPTION(0x1b00, Trap_1b, unknown_exception, EXC_XFER_EE)
 532
 533 /* On the MPC8xx, these next four traps are used for development
 534  * support of breakpoints and such.  Someday I will get around to
 535  * using them.
 536  */
 537         EXCEPTION(0x1c00, Trap_1c, unknown_exception, EXC_XFER_EE)
 538         EXCEPTION(0x1d00, Trap_1d, unknown_exception, EXC_XFER_EE)
 539         EXCEPTION(0x1e00, Trap_1e, unknown_exception, EXC_XFER_EE)
 540         EXCEPTION(0x1f00, Trap_1f, unknown_exception, EXC_XFER_EE)
 541
 542         . = 0x2000
 543
 544 /* This is the procedure to calculate the data EA for buggy dcbx,dcbi instructions
 545  * by decoding the registers used by the dcbx instruction and adding them.
 546  * DAR is set to the calculated address.
 547  */
 548  /* define if you don't want to use self modifying code */
 549 #define NO_SELF_MODIFYING_CODE
 550 FixupDAR:/* Entry point for dcbx workaround. */
 551         mtspr   SPRN_SPRG_SCRATCH2, r10
 552         /* fetch instruction from memory. */
 553         mfspr   r10, SPRN_SRR0
 554         IS_KERNEL(r11, r10)
 555         mfspr   r11, SPRN_M_TW  /* Get level 1 table */
 556         BRANCH_UNLESS_KERNEL(3f)
 557         lis     r11, (swapper_pg_dir-PAGE_OFFSET)@ha
 558         /* Insert level 1 index */
 559 3:      rlwimi  r11, r10, 32 - ((PAGE_SHIFT - 2) << 1), (PAGE_SHIFT - 2) << 1, 29
 560         lwz     r11, (swapper_pg_dir-PAGE_OFFSET)@l(r11)        /* Get the level 1 entry */
 561         mtcr    r11
 562         bt      28,200f         /* bit 28 = Large page (8M) */
 563         rlwinm  r11, r11,0,0,19 /* Extract page descriptor page address */
 564         /* Insert level 2 index */
 565         rlwimi  r11, r10, 32 - (PAGE_SHIFT - 2), 32 - PAGE_SHIFT, 29
 566         lwz     r11, 0(r11)     /* Get the pte */
 567         /* concat physical page address(r11) and page offset(r10) */
 568         rlwimi  r11, r10, 0, 32 - PAGE_SHIFT, 31
 569 201:    lwz     r11,0(r11)
 570 /* Check if it really is a dcbx instruction. */
 571 /* dcbt and dcbtst does not generate DTLB Misses/Errors,
 572  * no need to include them here */
 573         xoris   r10, r11, 0x7c00        /* check if major OP code is 31 */
 574         rlwinm  r10, r10, 0, 21, 5
 575         cmpwi   cr0, r10, 2028  /* Is dcbz? */
 576         beq+    142f
 577         cmpwi   cr0, r10, 940   /* Is dcbi? */
 578         beq+    142f
 579         cmpwi   cr0, r10, 108   /* Is dcbst? */
 580         beq+    144f            /* Fix up store bit! */
 581         cmpwi   cr0, r10, 172   /* Is dcbf? */
 582         beq+    142f
 583         cmpwi   cr0, r10, 1964  /* Is icbi? */
 584         beq+    142f
 585 141:    mfspr   r10,SPRN_SPRG_SCRATCH2
 586         b       DARFixed        /* Nope, go back to normal TLB processing */
 587
 588         /* concat physical page address(r11) and page offset(r10) */
 589 200:    rlwimi  r11, r10, 0, 32 - (PAGE_SHIFT << 1), 31
 590         b       201b
 591
 592 144:    mfspr   r10, SPRN_DSISR
 593         rlwinm  r10, r10,0,7,5  /* Clear store bit for buggy dcbst insn */
 594         mtspr   SPRN_DSISR, r10
 595 142:    /* continue, it was a dcbx, dcbi instruction. */
 596 #ifndef NO_SELF_MODIFYING_CODE
 597         andis.  r10,r11,0x1f    /* test if reg RA is r0 */
 598         li      r10,modified_instr@l
 599         dcbtst  r0,r10          /* touch for store */
 600         rlwinm  r11,r11,0,0,20  /* Zero lower 10 bits */
 601         oris    r11,r11,640     /* Transform instr. to a "add r10,RA,RB" */
 602         ori     r11,r11,532
 603         stw     r11,0(r10)      /* store add/and instruction */
 604         dcbf    0,r10           /* flush new instr. to memory. */
 605         icbi    0,r10           /* invalidate instr. cache line */
 606         mfspr   r11, SPRN_SPRG_SCRATCH1 /* restore r11 */
 607         mfspr   r10, SPRN_SPRG_SCRATCH0 /* restore r10 */
 608         isync                   /* Wait until new instr is loaded from memory */
 609 modified_instr:
 610         .space  4               /* this is where the add instr. is stored */
 611         bne+    143f
 612         subf    r10,r0,r10      /* r10=r10-r0, only if reg RA is r0 */
 613 143:    mtdar   r10             /* store faulting EA in DAR */
 614         mfspr   r10,SPRN_SPRG_SCRATCH2
 615         b       DARFixed        /* Go back to normal TLB handling */
 616 #else
 617         mfctr   r10
 618         mtdar   r10                     /* save ctr reg in DAR */
 619         rlwinm  r10, r11, 24, 24, 28    /* offset into jump table for reg RB */
 620         addi    r10, r10, 150f@l        /* add start of table */
 621         mtctr   r10                     /* load ctr with jump address */
 622         xor     r10, r10, r10           /* sum starts at zero */
 623         bctr                            /* jump into table */
 624 150:
 625         add     r10, r10, r0    ;b      151f
 626         add     r10, r10, r1    ;b      151f
 627         add     r10, r10, r2    ;b      151f
 628         add     r10, r10, r3    ;b      151f
 629         add     r10, r10, r4    ;b      151f
 630         add     r10, r10, r5    ;b      151f
 631         add     r10, r10, r6    ;b      151f
 632         add     r10, r10, r7    ;b      151f
 633         add     r10, r10, r8    ;b      151f
 634         add     r10, r10, r9    ;b      151f
 635         mtctr   r11     ;b      154f    /* r10 needs special handling */
 636         mtctr   r11     ;b      153f    /* r11 needs special handling */
 637         add     r10, r10, r12   ;b      151f
 638         add     r10, r10, r13   ;b      151f
 639         add     r10, r10, r14   ;b      151f
 640         add     r10, r10, r15   ;b      151f
 641         add     r10, r10, r16   ;b      151f
 642         add     r10, r10, r17   ;b      151f
 643         add     r10, r10, r18   ;b      151f
 644         add     r10, r10, r19   ;b      151f
 645         add     r10, r10, r20   ;b      151f
 646         add     r10, r10, r21   ;b      151f
 647         add     r10, r10, r22   ;b      151f
 648         add     r10, r10, r23   ;b      151f
 649         add     r10, r10, r24   ;b      151f
 650         add     r10, r10, r25   ;b      151f
 651         add     r10, r10, r26   ;b      151f
 652         add     r10, r10, r27   ;b      151f
 653         add     r10, r10, r28   ;b      151f
 654         add     r10, r10, r29   ;b      151f
 655         add     r10, r10, r30   ;b      151f
 656         add     r10, r10, r31
 657 151:
 658         rlwinm. r11,r11,19,24,28        /* offset into jump table for reg RA */
 659         beq     152f                    /* if reg RA is zero, don't add it */
 660         addi    r11, r11, 150b@l        /* add start of table */
 661         mtctr   r11                     /* load ctr with jump address */
 662         rlwinm  r11,r11,0,16,10         /* make sure we don't execute this more than once */
 663         bctr                            /* jump into table */
 664 152:
 665         mfdar   r11
 666         mtctr   r11                     /* restore ctr reg from DAR */
 667         mtdar   r10                     /* save fault EA to DAR */
 668         mfspr   r10,SPRN_SPRG_SCRATCH2
 669         b       DARFixed                /* Go back to normal TLB handling */
 670
 671         /* special handling for r10,r11 since these are modified already */
 672 153:    mfspr   r11, SPRN_SPRG_SCRATCH1 /* load r11 from SPRN_SPRG_SCRATCH1 */
 673         add     r10, r10, r11   /* add it */
 674         mfctr   r11             /* restore r11 */
 675         b       151b
 676 154:    mfspr   r11, SPRN_SPRG_SCRATCH0 /* load r10 from SPRN_SPRG_SCRATCH0 */
 677         add     r10, r10, r11   /* add it */
 678         mfctr   r11             /* restore r11 */
 679         b       151b
 680 #endif
 681
 682 /*
 683  * This is where the main kernel code starts.
 684  */
 685 start_here:
 686         /* ptr to current */
 687         lis     r2,init_task@h
 688         ori     r2,r2,init_task@l
 689
 690         /* ptr to phys current thread */
 691         tophys(r4,r2)
 692         addi    r4,r4,THREAD    /* init task's THREAD */
 693         mtspr   SPRN_SPRG_THREAD,r4
 694
 695         /* stack */
 696         lis     r1,init_thread_union@ha
 697         addi    r1,r1,init_thread_union@l
 698         li      r0,0
 699         stwu    r0,THREAD_SIZE-STACK_FRAME_OVERHEAD(r1)
 700
 701         bl      early_init      /* We have to do this with MMU on */
 702
 703 /*
 704  * Decide what sort of machine this is and initialize the MMU.
 705  */
 706         li      r3,0
 707         mr      r4,r31
 708         bl      machine_init
 709         bl      MMU_init
 710
 711 /*
 712  * Go back to running unmapped so we can load up new values
 713  * and change to using our exception vectors.
 714  * On the 8xx, all we have to do is invalidate the TLB to clear
 715  * the old 8M byte TLB mappings and load the page table base register.
 716  */
 717         /* The right way to do this would be to track it down through
 718          * init's THREAD like the context switch code does, but this is
 719          * easier......until someone changes init's static structures.
 720          */
 721         lis     r6, swapper_pg_dir@ha
 722         tophys(r6,r6)
 723 #ifdef CONFIG_8xx_CPU6
 724         lis     r4, cpu6_errata_word@h
 725         ori     r4, r4, cpu6_errata_word@l
 726         li      r3, 0x3f80
 727         stw     r3, 12(r4)
 728         lwz     r3, 12(r4)
 729 #endif
 730         mtspr   SPRN_M_TW, r6
 731         lis     r4,2f@h
 732         ori     r4,r4,2f@l
 733         tophys(r4,r4)
 734         li      r3,MSR_KERNEL & ~(MSR_IR|MSR_DR)
 735         mtspr   SPRN_SRR0,r4
 736         mtspr   SPRN_SRR1,r3
 737         rfi
 738 /* Load up the kernel context */
 739 2:
 740         SYNC                    /* Force all PTE updates to finish */
 741         tlbia                   /* Clear all TLB entries */
 742         sync                    /* wait for tlbia/tlbie to finish */
 743         TLBSYNC                 /* ... on all CPUs */
 744
 745         /* set up the PTE pointers for the Abatron bdiGDB.
 746         */
 747         tovirt(r6,r6)
 748         lis     r5, abatron_pteptrs@h
 749         ori     r5, r5, abatron_pteptrs@l
 750         stw     r5, 0xf0(r0)    /* Must match your Abatron config file */
 751         tophys(r5,r5)
 752         stw     r6, 0(r5)
 753
 754 /* Now turn on the MMU for real! */
 755         li      r4,MSR_KERNEL
 756         lis     r3,start_kernel@h
 757         ori     r3,r3,start_kernel@l
 758         mtspr   SPRN_SRR0,r3
 759         mtspr   SPRN_SRR1,r4
 760         rfi                     /* enable MMU and jump to start_kernel */
 761
 762 /* Set up the initial MMU state so we can do the first level of
 763  * kernel initialization.  This maps the first 8 MBytes of memory 1:1
 764  * virtual to physical.  Also, set the cache mode since that is defined
 765  * by TLB entries and perform any additional mapping (like of the IMMR).
 766  * If configured to pin some TLBs, we pin the first 8 Mbytes of kernel,
 767  * 24 Mbytes of data, and the 512k IMMR space.  Anything not covered by
 768  * these mappings is mapped by page tables.
 769  */
 770 initial_mmu:
 771         tlbia                   /* Invalidate all TLB entries */
 772 /* Always pin the first 8 MB ITLB to prevent ITLB
 773    misses while mucking around with SRR0/SRR1 in asm
 774 */
 775         lis     r8, MI_RSV4I@h
 776         ori     r8, r8, 0x1c00
 777
 778         mtspr   SPRN_MI_CTR, r8 /* Set instruction MMU control */
 779
 780 #ifdef CONFIG_PIN_TLB
 781         lis     r10, (MD_RSV4I | MD_RESETVAL)@h
 782         ori     r10, r10, 0x1c00
 783         mr      r8, r10
 784 #else
 785         lis     r10, MD_RESETVAL@h
 786 #endif
 787 #ifndef CONFIG_8xx_COPYBACK
 788         oris    r10, r10, MD_WTDEF@h
 789 #endif
 790         mtspr   SPRN_MD_CTR, r10        /* Set data TLB control */
 791
 792         /* Now map the lower 8 Meg into the TLBs.  For this quick hack,
 793          * we can load the instruction and data TLB registers with the
 794          * same values.
 795          */
 796         lis     r8, KERNELBASE@h        /* Create vaddr for TLB */
 797         ori     r8, r8, MI_EVALID       /* Mark it valid */
 798         mtspr   SPRN_MI_EPN, r8
 799         mtspr   SPRN_MD_EPN, r8
 800         li      r8, MI_PS8MEG | (2 << 5)        /* Set 8M byte page, APG 2 */
 801         ori     r8, r8, MI_SVALID       /* Make it valid */
 802         mtspr   SPRN_MI_TWC, r8
 803         li      r8, MI_PS8MEG           /* Set 8M byte page, APG 0 */
 804         ori     r8, r8, MI_SVALID       /* Make it valid */
 805         mtspr   SPRN_MD_TWC, r8
 806         li      r8, MI_BOOTINIT         /* Create RPN for address 0 */
 807         mtspr   SPRN_MI_RPN, r8         /* Store TLB entry */
 808         mtspr   SPRN_MD_RPN, r8
 809         lis     r8, MI_APG_INIT@h       /* Set protection modes */
 810         ori     r8, r8, MI_APG_INIT@l
 811         mtspr   SPRN_MI_AP, r8
 812         lis     r8, MD_APG_INIT@h
 813         ori     r8, r8, MD_APG_INIT@l
 814         mtspr   SPRN_MD_AP, r8
 815
 816         /* Map a 512k page for the IMMR to get the processor
 817          * internal registers (among other things).
 818          */
 819 #ifdef CONFIG_PIN_TLB
 820         addi    r10, r10, 0x0100
 821         mtspr   SPRN_MD_CTR, r10
 822 #endif
 823         mfspr   r9, 638                 /* Get current IMMR */
 824         andis.  r9, r9, 0xfff8          /* Get 512 kbytes boundary */
 825
 826         lis     r8, VIRT_IMMR_BASE@h    /* Create vaddr for TLB */
 827         ori     r8, r8, MD_EVALID       /* Mark it valid */
 828         mtspr   SPRN_MD_EPN, r8
 829         li      r8, MD_PS512K | MD_GUARDED      /* Set 512k byte page */
 830         ori     r8, r8, MD_SVALID       /* Make it valid */
 831         mtspr   SPRN_MD_TWC, r8
 832         mr      r8, r9                  /* Create paddr for TLB */
 833         ori     r8, r8, MI_BOOTINIT|0x2 /* Inhibit cache -- Cort */
 834         mtspr   SPRN_MD_RPN, r8
 835
 836 #ifdef CONFIG_PIN_TLB
 837         /* Map two more 8M kernel data pages.
 838         */
 839         addi    r10, r10, 0x0100
 840         mtspr   SPRN_MD_CTR, r10
 841
 842         lis     r8, KERNELBASE@h        /* Create vaddr for TLB */
 843         addis   r8, r8, 0x0080          /* Add 8M */
 844         ori     r8, r8, MI_EVALID       /* Mark it valid */
 845         mtspr   SPRN_MD_EPN, r8
 846         li      r9, MI_PS8MEG           /* Set 8M byte page */
 847         ori     r9, r9, MI_SVALID       /* Make it valid */
 848         mtspr   SPRN_MD_TWC, r9
 849         li      r11, MI_BOOTINIT        /* Create RPN for address 0 */
 850         addis   r11, r11, 0x0080        /* Add 8M */
 851         mtspr   SPRN_MD_RPN, r11
 852
 853         addi    r10, r10, 0x0100
 854         mtspr   SPRN_MD_CTR, r10
 855
 856         addis   r8, r8, 0x0080          /* Add 8M */
 857         mtspr   SPRN_MD_EPN, r8
 858         mtspr   SPRN_MD_TWC, r9
 859         addis   r11, r11, 0x0080        /* Add 8M */
 860         mtspr   SPRN_MD_RPN, r11
 861 #endif
 862
 863         /* Since the cache is enabled according to the information we
 864          * just loaded into the TLB, invalidate and enable the caches here.
 865          * We should probably check/set other modes....later.
 866          */
 867         lis     r8, IDC_INVALL@h
 868         mtspr   SPRN_IC_CST, r8
 869         mtspr   SPRN_DC_CST, r8
 870         lis     r8, IDC_ENABLE@h
 871         mtspr   SPRN_IC_CST, r8
 872 #ifdef CONFIG_8xx_COPYBACK
 873         mtspr   SPRN_DC_CST, r8
 874 #else
 875         /* For a debug option, I left this here to easily enable
 876          * the write through cache mode
 877          */
 878         lis     r8, DC_SFWT@h
 879         mtspr   SPRN_DC_CST, r8
 880         lis     r8, IDC_ENABLE@h
 881         mtspr   SPRN_DC_CST, r8
 882 #endif
 883         blr
 884
 885
 886 /*
 887  * We put a few things here that have to be page-aligned.
 888  * This stuff goes at the beginning of the data segment,
 889  * which is page-aligned.
 890  */
 891         .data
 892         .globl  sdata
 893 sdata:
 894         .globl  empty_zero_page
 895         .align  PAGE_SHIFT
 896 empty_zero_page:
 897         .space  PAGE_SIZE
 898
 899         .globl  swapper_pg_dir
 900 swapper_pg_dir:
 901         .space  PGD_TABLE_SIZE
 902
 903 /* Room for two PTE table poiners, usually the kernel and current user
 904  * pointer to their respective root page table (pgdir).
 905  */
 906 abatron_pteptrs:
 907         .space  8
 908
 909 #ifdef CONFIG_8xx_CPU6
 910         .globl  cpu6_errata_word
 911 cpu6_errata_word:
 912         .space  16
 913 #endif
 914