arch/powerpc/mm/slb_low.S

   1 /*
   2  * Low-level SLB routines
   3  *
   4  * Copyright (C) 2004 David Gibson <dwg@au.ibm.com>, IBM
   5  *
   6  * Based on earlier C version:
   7  * Dave Engebretsen and Mike Corrigan {engebret|mikejc}@us.ibm.com
   8  *    Copyright (c) 2001 Dave Engebretsen
   9  * Copyright (C) 2002 Anton Blanchard <anton@au.ibm.com>, IBM
  10  *
  11  *  This program is free software; you can redistribute it and/or
  12  *  modify it under the terms of the GNU General Public License
  13  *  as published by the Free Software Foundation; either version
  14  *  2 of the License, or (at your option) any later version.
  15  */
  16
  17 #include <asm/processor.h>
  18 #include <asm/ppc_asm.h>
  19 #include <asm/asm-offsets.h>
  20 #include <asm/cputable.h>
  21 #include <asm/page.h>
  22 #include <asm/mmu.h>
  23 #include <asm/pgtable.h>
  24 #include <asm/firmware.h>
  25
  26 /* void slb_allocate_realmode(unsigned long ea);
  27  *
  28  * Create an SLB entry for the given EA (user or kernel).
  29  *      r3 = faulting address, r13 = PACA
  30  *      r9, r10, r11 are clobbered by this function
  31  * No other registers are examined or changed.
  32  */
  33 _GLOBAL(slb_allocate_realmode)
  34         /* r3 = faulting address */
  35
  36         srdi    r9,r3,60                /* get region */
  37         srdi    r10,r3,28               /* get esid */
  38         cmpldi  cr7,r9,0xc              /* cmp PAGE_OFFSET for later use */
  39
  40         /* r3 = address, r10 = esid, cr7 = <> PAGE_OFFSET */
  41         blt     cr7,0f                  /* user or kernel? */
  42
  43         /* kernel address: proto-VSID = ESID */
  44         /* WARNING - MAGIC: we don't use the VSID 0xfffffffff, but
  45          * this code will generate the protoVSID 0xfffffffff for the
  46          * top segment.  That's ok, the scramble below will translate
  47          * it to VSID 0, which is reserved as a bad VSID - one which
  48          * will never have any pages in it.  */
  49
  50         /* Check if hitting the linear mapping or some other kernel space
  51         */
  52         bne     cr7,1f
  53
  54         /* Linear mapping encoding bits, the "li" instruction below will
  55          * be patched by the kernel at boot
  56          */
  57 _GLOBAL(slb_miss_kernel_load_linear)
  58         li      r11,0
  59         li      r9,0x1
  60         /*
  61          * for 1T we shift 12 bits more.  slb_finish_load_1T will do
  62          * the necessary adjustment
  63          */
  64         rldimi  r10,r9,(CONTEXT_BITS + USER_ESID_BITS),0
  65 BEGIN_FTR_SECTION
  66         b       slb_finish_load
  67 END_MMU_FTR_SECTION_IFCLR(MMU_FTR_1T_SEGMENT)
  68         b       slb_finish_load_1T
  69
  70 1:
  71 #ifdef CONFIG_SPARSEMEM_VMEMMAP
  72         /* Check virtual memmap region. To be patches at kernel boot */
  73         cmpldi  cr0,r9,0xf
  74         bne     1f
  75 _GLOBAL(slb_miss_kernel_load_vmemmap)
  76         li      r11,0
  77         b       6f
  78 1:
  79 #endif /* CONFIG_SPARSEMEM_VMEMMAP */
  80
  81         /* vmalloc mapping gets the encoding from the PACA as the mapping
  82          * can be demoted from 64K -> 4K dynamically on some machines
  83          */
  84         clrldi  r11,r10,48
  85         cmpldi  r11,(VMALLOC_SIZE >> 28) - 1
  86         bgt     5f
  87         lhz     r11,PACAVMALLOCSLLP(r13)
  88         b       6f
  89 5:
  90         /* IO mapping */
  91         _GLOBAL(slb_miss_kernel_load_io)
  92         li      r11,0
  93 6:
  94         li      r9,0x1
  95         /*
  96          * for 1T we shift 12 bits more.  slb_finish_load_1T will do
  97          * the necessary adjustment
  98          */
  99         rldimi  r10,r9,(CONTEXT_BITS + USER_ESID_BITS),0
 100 BEGIN_FTR_SECTION
 101         b       slb_finish_load
 102 END_MMU_FTR_SECTION_IFCLR(MMU_FTR_1T_SEGMENT)
 103         b       slb_finish_load_1T
 104
 105 0:      /* user address: proto-VSID = context << 15 | ESID. First check
 106          * if the address is within the boundaries of the user region
 107          */
 108         srdi.   r9,r10,USER_ESID_BITS
 109         bne-    8f                      /* invalid ea bits set */
 110
 111
 112         /* when using slices, we extract the psize off the slice bitmaps
 113          * and then we need to get the sllp encoding off the mmu_psize_defs
 114          * array.
 115          *
 116          * XXX This is a bit inefficient especially for the normal case,
 117          * so we should try to implement a fast path for the standard page
 118          * size using the old sllp value so we avoid the array. We cannot
 119          * really do dynamic patching unfortunately as processes might flip
 120          * between 4k and 64k standard page size
 121          */
 122 #ifdef CONFIG_PPC_MM_SLICES
 123         /* r10 have esid */
 124         cmpldi  r10,16
 125         /* below SLICE_LOW_TOP */
 126         blt     5f
 127         /*
 128          * Handle hpsizes,
 129          * r9 is get_paca()->context.high_slices_psize[index], r11 is mask_index
 130          */
 131         srdi    r11,r10,(SLICE_HIGH_SHIFT - SLICE_LOW_SHIFT + 1) /* index */
 132         addi    r9,r11,PACAHIGHSLICEPSIZE
 133         lbzx    r9,r13,r9               /* r9 is hpsizes[r11] */
 134         /* r11 = (r10 >> (SLICE_HIGH_SHIFT - SLICE_LOW_SHIFT)) & 0x1 */
 135         rldicl  r11,r10,(64 - (SLICE_HIGH_SHIFT - SLICE_LOW_SHIFT)),63
 136         b       6f
 137
 138 5:
 139         /*
 140          * Handle lpsizes
 141          * r9 is get_paca()->context.low_slices_psize, r11 is index
 142          */
 143         ld      r9,PACALOWSLICESPSIZE(r13)
 144         mr      r11,r10
 145 6:
 146         sldi    r11,r11,2  /* index * 4 */
 147         /* Extract the psize and multiply to get an array offset */
 148         srd     r9,r9,r11
 149         andi.   r9,r9,0xf
 150         mulli   r9,r9,MMUPSIZEDEFSIZE
 151
 152         /* Now get to the array and obtain the sllp
 153          */
 154         ld      r11,PACATOC(r13)
 155         ld      r11,mmu_psize_defs@got(r11)
 156         add     r11,r11,r9
 157         ld      r11,MMUPSIZESLLP(r11)
 158         ori     r11,r11,SLB_VSID_USER
 159 #else
 160         /* paca context sllp already contains the SLB_VSID_USER bits */
 161         lhz     r11,PACACONTEXTSLLP(r13)
 162 #endif /* CONFIG_PPC_MM_SLICES */
 163
 164         ld      r9,PACACONTEXTID(r13)
 165 BEGIN_FTR_SECTION
 166         cmpldi  r10,0x1000
 167 END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
 168         rldimi  r10,r9,USER_ESID_BITS,0
 169 BEGIN_FTR_SECTION
 170         bge     slb_finish_load_1T
 171 END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
 172         b       slb_finish_load
 173
 174 8:      /* invalid EA */
 175         li      r10,0                   /* BAD_VSID */
 176         li      r11,SLB_VSID_USER       /* flags don't much matter */
 177         b       slb_finish_load
 178
 179 #ifdef __DISABLED__
 180
 181 /* void slb_allocate_user(unsigned long ea);
 182  *
 183  * Create an SLB entry for the given EA (user or kernel).
 184  *      r3 = faulting address, r13 = PACA
 185  *      r9, r10, r11 are clobbered by this function
 186  * No other registers are examined or changed.
 187  *
 188  * It is called with translation enabled in order to be able to walk the
 189  * page tables. This is not currently used.
 190  */
 191 _GLOBAL(slb_allocate_user)
 192         /* r3 = faulting address */
 193         srdi    r10,r3,28               /* get esid */
 194
 195         crset   4*cr7+lt                /* set "user" flag for later */
 196
 197         /* check if we fit in the range covered by the pagetables*/
 198         srdi.   r9,r3,PGTABLE_EADDR_SIZE
 199         crnot   4*cr0+eq,4*cr0+eq
 200         beqlr
 201
 202         /* now we need to get to the page tables in order to get the page
 203          * size encoding from the PMD. In the future, we'll be able to deal
 204          * with 1T segments too by getting the encoding from the PGD instead
 205          */
 206         ld      r9,PACAPGDIR(r13)
 207         cmpldi  cr0,r9,0
 208         beqlr
 209         rlwinm  r11,r10,8,25,28
 210         ldx     r9,r9,r11               /* get pgd_t */
 211         cmpldi  cr0,r9,0
 212         beqlr
 213         rlwinm  r11,r10,3,17,28
 214         ldx     r9,r9,r11               /* get pmd_t */
 215         cmpldi  cr0,r9,0
 216         beqlr
 217
 218         /* build vsid flags */
 219         andi.   r11,r9,SLB_VSID_LLP
 220         ori     r11,r11,SLB_VSID_USER
 221
 222         /* get context to calculate proto-VSID */
 223         ld      r9,PACACONTEXTID(r13)
 224         rldimi  r10,r9,USER_ESID_BITS,0
 225
 226         /* fall through slb_finish_load */
 227
 228 #endif /* __DISABLED__ */
 229
 230
 231 /*
 232  * Finish loading of an SLB entry and return
 233  *
 234  * r3 = EA, r10 = proto-VSID, r11 = flags, clobbers r9, cr7 = <> PAGE_OFFSET
 235  */
 236 slb_finish_load:
 237         ASM_VSID_SCRAMBLE(r10,r9,256M)
 238         /*
 239          * bits above VSID_BITS_256M need to be ignored from r10
 240          * also combine VSID and flags
 241          */
 242         rldimi  r11,r10,SLB_VSID_SHIFT,(64 - (SLB_VSID_SHIFT + VSID_BITS_256M))
 243
 244         /* r3 = EA, r11 = VSID data */
 245         /*
 246          * Find a slot, round robin. Previously we tried to find a
 247          * free slot first but that took too long. Unfortunately we
 248          * dont have any LRU information to help us choose a slot.
 249          */
 250
 251 7:      ld      r10,PACASTABRR(r13)
 252         addi    r10,r10,1
 253         /* This gets soft patched on boot. */
 254 _GLOBAL(slb_compare_rr_to_size)
 255         cmpldi  r10,0
 256
 257         blt+    4f
 258         li      r10,SLB_NUM_BOLTED
 259
 260 4:
 261         std     r10,PACASTABRR(r13)
 262
 263 3:
 264         rldimi  r3,r10,0,36             /* r3= EA[0:35] | entry */
 265         oris    r10,r3,SLB_ESID_V@h     /* r3 |= SLB_ESID_V */
 266
 267         /* r3 = ESID data, r11 = VSID data */
 268
 269         /*
 270          * No need for an isync before or after this slbmte. The exception
 271          * we enter with and the rfid we exit with are context synchronizing.
 272          */
 273         slbmte  r11,r10
 274
 275         /* we're done for kernel addresses */
 276         crclr   4*cr0+eq                /* set result to "success" */
 277         bgelr   cr7
 278
 279         /* Update the slb cache */
 280         lhz     r3,PACASLBCACHEPTR(r13) /* offset = paca->slb_cache_ptr */
 281         cmpldi  r3,SLB_CACHE_ENTRIES
 282         bge     1f
 283
 284         /* still room in the slb cache */
 285         sldi    r11,r3,2                /* r11 = offset * sizeof(u32) */
 286         srdi    r10,r10,28              /* get the 36 bits of the ESID */
 287         add     r11,r11,r13             /* r11 = (u32 *)paca + offset */
 288         stw     r10,PACASLBCACHE(r11)   /* paca->slb_cache[offset] = esid */
 289         addi    r3,r3,1                 /* offset++ */
 290         b       2f
 291 1:                                      /* offset >= SLB_CACHE_ENTRIES */
 292         li      r3,SLB_CACHE_ENTRIES+1
 293 2:
 294         sth     r3,PACASLBCACHEPTR(r13) /* paca->slb_cache_ptr = offset */
 295         crclr   4*cr0+eq                /* set result to "success" */
 296         blr
 297
 298 /*
 299  * Finish loading of a 1T SLB entry (for the kernel linear mapping) and return.
 300  *
 301  * r3 = EA, r10 = proto-VSID, r11 = flags, clobbers r9
 302  */
 303 slb_finish_load_1T:
 304         srdi    r10,r10,40-28           /* get 1T ESID */
 305         ASM_VSID_SCRAMBLE(r10,r9,1T)
 306         /*
 307          * bits above VSID_BITS_1T need to be ignored from r10
 308          * also combine VSID and flags
 309          */
 310         rldimi  r11,r10,SLB_VSID_SHIFT_1T,(64 - (SLB_VSID_SHIFT_1T + VSID_BITS_1T))
 311         li      r10,MMU_SEGSIZE_1T
 312         rldimi  r11,r10,SLB_VSID_SSIZE_SHIFT,0  /* insert segment size */
 313
 314         /* r3 = EA, r11 = VSID data */
 315         clrrdi  r3,r3,SID_SHIFT_1T      /* clear out non-ESID bits */
 316         b       7b
 317