arch/x86/entry/thunk_64.S

   1 /*
   2  * Save registers before calling assembly functions. This avoids
   3  * disturbance of register allocation in some inline assembly constructs.
   4  * Copyright 2001,2002 by Andi Kleen, SuSE Labs.
   5  * Added trace_hardirqs callers - Copyright 2007 Steven Rostedt, Red Hat, Inc.
   6  * Subject to the GNU public license, v.2. No warranty of any kind.
   7  */
   8 #include <linux/linkage.h>
   9 #include "calling.h"
  10 #include <asm/asm.h>
  11 #include <asm/frame.h>
  12
  13         /* rdi: arg1 ... normal C conventions. rax is saved/restored. */
  14         .macro THUNK name, func, put_ret_addr_in_rdi=0
  15         .globl \name
  16         .type \name, @function
  17 \name:
  18         FRAME_BEGIN
  19
  20         /* this one pushes 9 elems, the next one would be %rIP */
  21         pushq %rdi
  22         pushq %rsi
  23         pushq %rdx
  24         pushq %rcx
  25         pushq %rax
  26         pushq %r8
  27         pushq %r9
  28         pushq %r10
  29         pushq %r11
  30
  31         .if \put_ret_addr_in_rdi
  32         /* 9*8(%rsp) is return addr on stack */
  33         movq 9*8(%rsp), %rdi
  34         .endif
  35
  36         call \func
  37         jmp  restore
  38         _ASM_NOKPROBE(\name)
  39         .endm
  40
  41 #ifdef CONFIG_TRACE_IRQFLAGS
  42         THUNK trace_hardirqs_on_thunk,trace_hardirqs_on_caller,1
  43         THUNK trace_hardirqs_off_thunk,trace_hardirqs_off_caller,1
  44 #endif
  45
  46 #ifdef CONFIG_DEBUG_LOCK_ALLOC
  47         THUNK lockdep_sys_exit_thunk,lockdep_sys_exit
  48 #endif
  49
  50 #ifdef CONFIG_PREEMPT
  51         THUNK ___preempt_schedule, preempt_schedule
  52         THUNK ___preempt_schedule_notrace, preempt_schedule_notrace
  53 #endif
  54
  55 #if defined(CONFIG_TRACE_IRQFLAGS) \
  56  || defined(CONFIG_DEBUG_LOCK_ALLOC) \
  57  || defined(CONFIG_PREEMPT)
  58 restore:
  59         popq %r11
  60         popq %r10
  61         popq %r9
  62         popq %r8
  63         popq %rax
  64         popq %rcx
  65         popq %rdx
  66         popq %rsi
  67         popq %rdi
  68         FRAME_END
  69         ret
  70         _ASM_NOKPROBE(restore)
  71 #endif