arch/x86/kernel/entry_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  */
   5
   6 /*
   7  * entry.S contains the system-call and fault low-level handling routines.
   8  * This also contains the timer-interrupt handler, as well as all interrupts
   9  * and faults that can result in a task-switch.
  10  *
  11  * NOTE: This code handles signal-recognition, which happens every time
  12  * after a timer-interrupt and after each system call.
  13  *
  14  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  15  * on a 486.
  16  *
  17  * Stack layout in 'syscall_exit':
  18  *      ptrace needs to have all regs on the stack.
  19  *      if the order here is changed, it needs to be
  20  *      updated in fork.c:copy_process, signal.c:do_signal,
  21  *      ptrace.c and ptrace.h
  22  *
  23  *       0(%esp) - %ebx
  24  *       4(%esp) - %ecx
  25  *       8(%esp) - %edx
  26  *       C(%esp) - %esi
  27  *      10(%esp) - %edi
  28  *      14(%esp) - %ebp
  29  *      18(%esp) - %eax
  30  *      1C(%esp) - %ds
  31  *      20(%esp) - %es
  32  *      24(%esp) - %fs
  33  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
  34  *      2C(%esp) - orig_eax
  35  *      30(%esp) - %eip
  36  *      34(%esp) - %cs
  37  *      38(%esp) - %eflags
  38  *      3C(%esp) - %oldesp
  39  *      40(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <linux/err.h>
  46 #include <asm/thread_info.h>
  47 #include <asm/irqflags.h>
  48 #include <asm/errno.h>
  49 #include <asm/segment.h>
  50 #include <asm/smp.h>
  51 #include <asm/page_types.h>
  52 #include <asm/percpu.h>
  53 #include <asm/dwarf2.h>
  54 #include <asm/processor-flags.h>
  55 #include <asm/ftrace.h>
  56 #include <asm/irq_vectors.h>
  57 #include <asm/cpufeature.h>
  58 #include <asm/alternative-asm.h>
  59 #include <asm/asm.h>
  60 #include <asm/smap.h>
  61
  62 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  63 #include <linux/elf-em.h>
  64 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  65 #define __AUDIT_ARCH_LE    0x40000000
  66
  67 #ifndef CONFIG_AUDITSYSCALL
  68 #define sysenter_audit  syscall_trace_entry
  69 #define sysexit_audit   syscall_exit_work
  70 #endif
  71
  72         .section .entry.text, "ax"
  73
  74 /*
  75  * We use macros for low-level operations which need to be overridden
  76  * for paravirtualization.  The following will never clobber any registers:
  77  *   INTERRUPT_RETURN (aka. "iret")
  78  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  79  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  80  *
  81  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  82  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  83  * Allowing a register to be clobbered can shrink the paravirt replacement
  84  * enough to patch inline, increasing performance.
  85  */
  86
  87 #ifdef CONFIG_PREEMPT
  88 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  89 #else
  90 #define preempt_stop(clobbers)
  91 #define resume_kernel           restore_all
  92 #endif
  93
  94 .macro TRACE_IRQS_IRET
  95 #ifdef CONFIG_TRACE_IRQFLAGS
  96         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)     # interrupts off?
  97         jz 1f
  98         TRACE_IRQS_ON
  99 1:
 100 #endif
 101 .endm
 102
 103 /*
 104  * User gs save/restore
 105  *
 106  * %gs is used for userland TLS and kernel only uses it for stack
 107  * canary which is required to be at %gs:20 by gcc.  Read the comment
 108  * at the top of stackprotector.h for more info.
 109  *
 110  * Local labels 98 and 99 are used.
 111  */
 112 #ifdef CONFIG_X86_32_LAZY_GS
 113
 114  /* unfortunately push/pop can't be no-op */
 115 .macro PUSH_GS
 116         pushl_cfi $0
 117 .endm
 118 .macro POP_GS pop=0
 119         addl $(4 + \pop), %esp
 120         CFI_ADJUST_CFA_OFFSET -(4 + \pop)
 121 .endm
 122 .macro POP_GS_EX
 123 .endm
 124
 125  /* all the rest are no-op */
 126 .macro PTGS_TO_GS
 127 .endm
 128 .macro PTGS_TO_GS_EX
 129 .endm
 130 .macro GS_TO_REG reg
 131 .endm
 132 .macro REG_TO_PTGS reg
 133 .endm
 134 .macro SET_KERNEL_GS reg
 135 .endm
 136
 137 #else   /* CONFIG_X86_32_LAZY_GS */
 138
 139 .macro PUSH_GS
 140         pushl_cfi %gs
 141         /*CFI_REL_OFFSET gs, 0*/
 142 .endm
 143
 144 .macro POP_GS pop=0
 145 98:     popl_cfi %gs
 146         /*CFI_RESTORE gs*/
 147   .if \pop <> 0
 148         add $\pop, %esp
 149         CFI_ADJUST_CFA_OFFSET -\pop
 150   .endif
 151 .endm
 152 .macro POP_GS_EX
 153 .pushsection .fixup, "ax"
 154 99:     movl $0, (%esp)
 155         jmp 98b
 156 .popsection
 157         _ASM_EXTABLE(98b,99b)
 158 .endm
 159
 160 .macro PTGS_TO_GS
 161 98:     mov PT_GS(%esp), %gs
 162 .endm
 163 .macro PTGS_TO_GS_EX
 164 .pushsection .fixup, "ax"
 165 99:     movl $0, PT_GS(%esp)
 166         jmp 98b
 167 .popsection
 168         _ASM_EXTABLE(98b,99b)
 169 .endm
 170
 171 .macro GS_TO_REG reg
 172         movl %gs, \reg
 173         /*CFI_REGISTER gs, \reg*/
 174 .endm
 175 .macro REG_TO_PTGS reg
 176         movl \reg, PT_GS(%esp)
 177         /*CFI_REL_OFFSET gs, PT_GS*/
 178 .endm
 179 .macro SET_KERNEL_GS reg
 180         movl $(__KERNEL_STACK_CANARY), \reg
 181         movl \reg, %gs
 182 .endm
 183
 184 #endif  /* CONFIG_X86_32_LAZY_GS */
 185
 186 .macro SAVE_ALL
 187         cld
 188         PUSH_GS
 189         pushl_cfi %fs
 190         /*CFI_REL_OFFSET fs, 0;*/
 191         pushl_cfi %es
 192         /*CFI_REL_OFFSET es, 0;*/
 193         pushl_cfi %ds
 194         /*CFI_REL_OFFSET ds, 0;*/
 195         pushl_cfi %eax
 196         CFI_REL_OFFSET eax, 0
 197         pushl_cfi %ebp
 198         CFI_REL_OFFSET ebp, 0
 199         pushl_cfi %edi
 200         CFI_REL_OFFSET edi, 0
 201         pushl_cfi %esi
 202         CFI_REL_OFFSET esi, 0
 203         pushl_cfi %edx
 204         CFI_REL_OFFSET edx, 0
 205         pushl_cfi %ecx
 206         CFI_REL_OFFSET ecx, 0
 207         pushl_cfi %ebx
 208         CFI_REL_OFFSET ebx, 0
 209         movl $(__USER_DS), %edx
 210         movl %edx, %ds
 211         movl %edx, %es
 212         movl $(__KERNEL_PERCPU), %edx
 213         movl %edx, %fs
 214         SET_KERNEL_GS %edx
 215 .endm
 216
 217 .macro RESTORE_INT_REGS
 218         popl_cfi %ebx
 219         CFI_RESTORE ebx
 220         popl_cfi %ecx
 221         CFI_RESTORE ecx
 222         popl_cfi %edx
 223         CFI_RESTORE edx
 224         popl_cfi %esi
 225         CFI_RESTORE esi
 226         popl_cfi %edi
 227         CFI_RESTORE edi
 228         popl_cfi %ebp
 229         CFI_RESTORE ebp
 230         popl_cfi %eax
 231         CFI_RESTORE eax
 232 .endm
 233
 234 .macro RESTORE_REGS pop=0
 235         RESTORE_INT_REGS
 236 1:      popl_cfi %ds
 237         /*CFI_RESTORE ds;*/
 238 2:      popl_cfi %es
 239         /*CFI_RESTORE es;*/
 240 3:      popl_cfi %fs
 241         /*CFI_RESTORE fs;*/
 242         POP_GS \pop
 243 .pushsection .fixup, "ax"
 244 4:      movl $0, (%esp)
 245         jmp 1b
 246 5:      movl $0, (%esp)
 247         jmp 2b
 248 6:      movl $0, (%esp)
 249         jmp 3b
 250 .popsection
 251         _ASM_EXTABLE(1b,4b)
 252         _ASM_EXTABLE(2b,5b)
 253         _ASM_EXTABLE(3b,6b)
 254         POP_GS_EX
 255 .endm
 256
 257 .macro RING0_INT_FRAME
 258         CFI_STARTPROC simple
 259         CFI_SIGNAL_FRAME
 260         CFI_DEF_CFA esp, 3*4
 261         /*CFI_OFFSET cs, -2*4;*/
 262         CFI_OFFSET eip, -3*4
 263 .endm
 264
 265 .macro RING0_EC_FRAME
 266         CFI_STARTPROC simple
 267         CFI_SIGNAL_FRAME
 268         CFI_DEF_CFA esp, 4*4
 269         /*CFI_OFFSET cs, -2*4;*/
 270         CFI_OFFSET eip, -3*4
 271 .endm
 272
 273 .macro RING0_PTREGS_FRAME
 274         CFI_STARTPROC simple
 275         CFI_SIGNAL_FRAME
 276         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
 277         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
 278         CFI_OFFSET eip, PT_EIP-PT_OLDESP
 279         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
 280         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
 281         CFI_OFFSET eax, PT_EAX-PT_OLDESP
 282         CFI_OFFSET ebp, PT_EBP-PT_OLDESP
 283         CFI_OFFSET edi, PT_EDI-PT_OLDESP
 284         CFI_OFFSET esi, PT_ESI-PT_OLDESP
 285         CFI_OFFSET edx, PT_EDX-PT_OLDESP
 286         CFI_OFFSET ecx, PT_ECX-PT_OLDESP
 287         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 288 .endm
 289
 290 ENTRY(ret_from_fork)
 291         CFI_STARTPROC
 292         pushl_cfi %eax
 293         call schedule_tail
 294         GET_THREAD_INFO(%ebp)
 295         popl_cfi %eax
 296         pushl_cfi $0x0202               # Reset kernel eflags
 297         popfl_cfi
 298         jmp syscall_exit
 299         CFI_ENDPROC
 300 END(ret_from_fork)
 301
 302 ENTRY(ret_from_kernel_thread)
 303         CFI_STARTPROC
 304         pushl_cfi %eax
 305         call schedule_tail
 306         GET_THREAD_INFO(%ebp)
 307         popl_cfi %eax
 308         pushl_cfi $0x0202               # Reset kernel eflags
 309         popfl_cfi
 310         movl PT_EBP(%esp),%eax
 311         call *PT_EBX(%esp)
 312         movl $0,PT_EAX(%esp)
 313         jmp syscall_exit
 314         CFI_ENDPROC
 315 ENDPROC(ret_from_kernel_thread)
 316
 317 /*
 318  * Return to user mode is not as complex as all this looks,
 319  * but we want the default path for a system call return to
 320  * go as quickly as possible which is why some of this is
 321  * less clear than it otherwise should be.
 322  */
 323
 324         # userspace resumption stub bypassing syscall exit tracing
 325         ALIGN
 326         RING0_PTREGS_FRAME
 327 ret_from_exception:
 328         preempt_stop(CLBR_ANY)
 329 ret_from_intr:
 330         GET_THREAD_INFO(%ebp)
 331 #ifdef CONFIG_VM86
 332         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 333         movb PT_CS(%esp), %al
 334         andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 335 #else
 336         /*
 337          * We can be coming here from child spawned by kernel_thread().
 338          */
 339         movl PT_CS(%esp), %eax
 340         andl $SEGMENT_RPL_MASK, %eax
 341 #endif
 342         cmpl $USER_RPL, %eax
 343         jb resume_kernel                # not returning to v8086 or userspace
 344
 345 ENTRY(resume_userspace)
 346         LOCKDEP_SYS_EXIT
 347         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 348                                         # setting need_resched or sigpending
 349                                         # between sampling and the iret
 350         TRACE_IRQS_OFF
 351         movl TI_flags(%ebp), %ecx
 352         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 353                                         # int/exception return?
 354         jne work_pending
 355         jmp restore_all
 356 END(ret_from_exception)
 357
 358 #ifdef CONFIG_PREEMPT
 359 ENTRY(resume_kernel)
 360         DISABLE_INTERRUPTS(CLBR_ANY)
 361 need_resched:
 362         cmpl $0,PER_CPU_VAR(__preempt_count)
 363         jnz restore_all
 364         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)    # interrupts off (exception path) ?
 365         jz restore_all
 366         call preempt_schedule_irq
 367         jmp need_resched
 368 END(resume_kernel)
 369 #endif
 370         CFI_ENDPROC
 371
 372 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 373    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 374
 375         # sysenter call handler stub
 376 ENTRY(ia32_sysenter_target)
 377         CFI_STARTPROC simple
 378         CFI_SIGNAL_FRAME
 379         CFI_DEF_CFA esp, 0
 380         CFI_REGISTER esp, ebp
 381         movl TSS_sysenter_sp0(%esp),%esp
 382 sysenter_past_esp:
 383         /*
 384          * Interrupts are disabled here, but we can't trace it until
 385          * enough kernel state to call TRACE_IRQS_OFF can be called - but
 386          * we immediately enable interrupts at that point anyway.
 387          */
 388         pushl_cfi $__USER_DS
 389         /*CFI_REL_OFFSET ss, 0*/
 390         pushl_cfi %ebp
 391         CFI_REL_OFFSET esp, 0
 392         pushfl_cfi
 393         orl $X86_EFLAGS_IF, (%esp)
 394         pushl_cfi $__USER_CS
 395         /*CFI_REL_OFFSET cs, 0*/
 396         /*
 397          * Push current_thread_info()->sysenter_return to the stack.
 398          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 399          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 400          */
 401         pushl_cfi ((TI_sysenter_return)-THREAD_SIZE+8+4*4)(%esp)
 402         CFI_REL_OFFSET eip, 0
 403
 404         pushl_cfi %eax
 405         SAVE_ALL
 406         ENABLE_INTERRUPTS(CLBR_NONE)
 407
 408 /*
 409  * Load the potential sixth argument from user stack.
 410  * Careful about security.
 411  */
 412         cmpl $__PAGE_OFFSET-3,%ebp
 413         jae syscall_fault
 414         ASM_STAC
 415 1:      movl (%ebp),%ebp
 416         ASM_CLAC
 417         movl %ebp,PT_EBP(%esp)
 418         _ASM_EXTABLE(1b,syscall_fault)
 419
 420         GET_THREAD_INFO(%ebp)
 421
 422         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 423         jnz sysenter_audit
 424 sysenter_do_call:
 425         cmpl $(NR_syscalls), %eax
 426         jae syscall_badsys
 427         call *sys_call_table(,%eax,4)
 428         movl %eax,PT_EAX(%esp)
 429         LOCKDEP_SYS_EXIT
 430         DISABLE_INTERRUPTS(CLBR_ANY)
 431         TRACE_IRQS_OFF
 432         movl TI_flags(%ebp), %ecx
 433         testl $_TIF_ALLWORK_MASK, %ecx
 434         jne sysexit_audit
 435 sysenter_exit:
 436 /* if something modifies registers it must also disable sysexit */
 437         movl PT_EIP(%esp), %edx
 438         movl PT_OLDESP(%esp), %ecx
 439         xorl %ebp,%ebp
 440         TRACE_IRQS_ON
 441 1:      mov  PT_FS(%esp), %fs
 442         PTGS_TO_GS
 443         ENABLE_INTERRUPTS_SYSEXIT
 444
 445 #ifdef CONFIG_AUDITSYSCALL
 446 sysenter_audit:
 447         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 448         jnz syscall_trace_entry
 449         addl $4,%esp
 450         CFI_ADJUST_CFA_OFFSET -4
 451         /* %esi already in 8(%esp)         6th arg: 4th syscall arg */
 452         /* %edx already in 4(%esp)         5th arg: 3rd syscall arg */
 453         /* %ecx already in 0(%esp)         4th arg: 2nd syscall arg */
 454         movl %ebx,%ecx                  /* 3rd arg: 1st syscall arg */
 455         movl %eax,%edx                  /* 2nd arg: syscall number */
 456         movl $AUDIT_ARCH_I386,%eax      /* 1st arg: audit arch */
 457         call __audit_syscall_entry
 458         pushl_cfi %ebx
 459         movl PT_EAX(%esp),%eax          /* reload syscall number */
 460         jmp sysenter_do_call
 461
 462 sysexit_audit:
 463         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 464         jne syscall_exit_work
 465         TRACE_IRQS_ON
 466         ENABLE_INTERRUPTS(CLBR_ANY)
 467         movl %eax,%edx          /* second arg, syscall return value */
 468         cmpl $-MAX_ERRNO,%eax   /* is it an error ? */
 469         setbe %al               /* 1 if so, 0 if not */
 470         movzbl %al,%eax         /* zero-extend that */
 471         call __audit_syscall_exit
 472         DISABLE_INTERRUPTS(CLBR_ANY)
 473         TRACE_IRQS_OFF
 474         movl TI_flags(%ebp), %ecx
 475         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 476         jne syscall_exit_work
 477         movl PT_EAX(%esp),%eax  /* reload syscall return value */
 478         jmp sysenter_exit
 479 #endif
 480
 481         CFI_ENDPROC
 482 .pushsection .fixup,"ax"
 483 2:      movl $0,PT_FS(%esp)
 484         jmp 1b
 485 .popsection
 486         _ASM_EXTABLE(1b,2b)
 487         PTGS_TO_GS_EX
 488 ENDPROC(ia32_sysenter_target)
 489
 490         # system call handler stub
 491 ENTRY(system_call)
 492         RING0_INT_FRAME                 # can't unwind into user space anyway
 493         ASM_CLAC
 494         pushl_cfi %eax                  # save orig_eax
 495         SAVE_ALL
 496         GET_THREAD_INFO(%ebp)
 497                                         # system call tracing in operation / emulation
 498         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 499         jnz syscall_trace_entry
 500         cmpl $(NR_syscalls), %eax
 501         jae syscall_badsys
 502 syscall_call:
 503         call *sys_call_table(,%eax,4)
 504         movl %eax,PT_EAX(%esp)          # store the return value
 505 syscall_exit:
 506         LOCKDEP_SYS_EXIT
 507         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 508                                         # setting need_resched or sigpending
 509                                         # between sampling and the iret
 510         TRACE_IRQS_OFF
 511         movl TI_flags(%ebp), %ecx
 512         testl $_TIF_ALLWORK_MASK, %ecx  # current->work
 513         jne syscall_exit_work
 514
 515 restore_all:
 516         TRACE_IRQS_IRET
 517 restore_all_notrace:
 518 #ifdef CONFIG_X86_ESPFIX32
 519         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 520         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 521         # are returning to the kernel.
 522         # See comments in process.c:copy_thread() for details.
 523         movb PT_OLDSS(%esp), %ah
 524         movb PT_CS(%esp), %al
 525         andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 526         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 527         CFI_REMEMBER_STATE
 528         je ldt_ss                       # returning to user-space with LDT SS
 529 #endif
 530 restore_nocheck:
 531         RESTORE_REGS 4                  # skip orig_eax/error_code
 532 irq_return:
 533         INTERRUPT_RETURN
 534 .section .fixup,"ax"
 535 ENTRY(iret_exc)
 536         pushl $0                        # no error code
 537         pushl $do_iret_error
 538         jmp error_code
 539 .previous
 540         _ASM_EXTABLE(irq_return,iret_exc)
 541
 542 #ifdef CONFIG_X86_ESPFIX32
 543         CFI_RESTORE_STATE
 544 ldt_ss:
 545 #ifdef CONFIG_PARAVIRT
 546         /*
 547          * The kernel can't run on a non-flat stack if paravirt mode
 548          * is active.  Rather than try to fixup the high bits of
 549          * ESP, bypass this code entirely.  This may break DOSemu
 550          * and/or Wine support in a paravirt VM, although the option
 551          * is still available to implement the setting of the high
 552          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 553          */
 554         cmpl $0, pv_info+PARAVIRT_enabled
 555         jne restore_nocheck
 556 #endif
 557
 558 /*
 559  * Setup and switch to ESPFIX stack
 560  *
 561  * We're returning to userspace with a 16 bit stack. The CPU will not
 562  * restore the high word of ESP for us on executing iret... This is an
 563  * "official" bug of all the x86-compatible CPUs, which we can work
 564  * around to make dosemu and wine happy. We do this by preloading the
 565  * high word of ESP with the high word of the userspace ESP while
 566  * compensating for the offset by changing to the ESPFIX segment with
 567  * a base address that matches for the difference.
 568  */
 569 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
 570         mov %esp, %edx                  /* load kernel esp */
 571         mov PT_OLDESP(%esp), %eax       /* load userspace esp */
 572         mov %dx, %ax                    /* eax: new kernel esp */
 573         sub %eax, %edx                  /* offset (low word is 0) */
 574         shr $16, %edx
 575         mov %dl, GDT_ESPFIX_SS + 4 /* bits 16..23 */
 576         mov %dh, GDT_ESPFIX_SS + 7 /* bits 24..31 */
 577         pushl_cfi $__ESPFIX_SS
 578         pushl_cfi %eax                  /* new kernel esp */
 579         /* Disable interrupts, but do not irqtrace this section: we
 580          * will soon execute iret and the tracer was already set to
 581          * the irqstate after the iret */
 582         DISABLE_INTERRUPTS(CLBR_EAX)
 583         lss (%esp), %esp                /* switch to espfix segment */
 584         CFI_ADJUST_CFA_OFFSET -8
 585         jmp restore_nocheck
 586 #endif
 587         CFI_ENDPROC
 588 ENDPROC(system_call)
 589
 590         # perform work that needs to be done immediately before resumption
 591         ALIGN
 592         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 593 work_pending:
 594         testb $_TIF_NEED_RESCHED, %cl
 595         jz work_notifysig
 596 work_resched:
 597         call schedule
 598         LOCKDEP_SYS_EXIT
 599         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 600                                         # setting need_resched or sigpending
 601                                         # between sampling and the iret
 602         TRACE_IRQS_OFF
 603         movl TI_flags(%ebp), %ecx
 604         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 605                                         # than syscall tracing?
 606         jz restore_all
 607         testb $_TIF_NEED_RESCHED, %cl
 608         jnz work_resched
 609
 610 work_notifysig:                         # deal with pending signals and
 611                                         # notify-resume requests
 612 #ifdef CONFIG_VM86
 613         testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
 614         movl %esp, %eax
 615         jne work_notifysig_v86          # returning to kernel-space or
 616                                         # vm86-space
 617 1:
 618 #else
 619         movl %esp, %eax
 620 #endif
 621         TRACE_IRQS_ON
 622         ENABLE_INTERRUPTS(CLBR_NONE)
 623         movb PT_CS(%esp), %bl
 624         andb $SEGMENT_RPL_MASK, %bl
 625         cmpb $USER_RPL, %bl
 626         jb resume_kernel
 627         xorl %edx, %edx
 628         call do_notify_resume
 629         jmp resume_userspace
 630
 631 #ifdef CONFIG_VM86
 632         ALIGN
 633 work_notifysig_v86:
 634         pushl_cfi %ecx                  # save ti_flags for do_notify_resume
 635         call save_v86_state             # %eax contains pt_regs pointer
 636         popl_cfi %ecx
 637         movl %eax, %esp
 638         jmp 1b
 639 #endif
 640 END(work_pending)
 641
 642         # perform syscall exit tracing
 643         ALIGN
 644 syscall_trace_entry:
 645         movl $-ENOSYS,PT_EAX(%esp)
 646         movl %esp, %eax
 647         call syscall_trace_enter
 648         /* What it returned is what we'll actually use.  */
 649         cmpl $(NR_syscalls), %eax
 650         jnae syscall_call
 651         jmp syscall_exit
 652 END(syscall_trace_entry)
 653
 654         # perform syscall exit tracing
 655         ALIGN
 656 syscall_exit_work:
 657         testl $_TIF_WORK_SYSCALL_EXIT, %ecx
 658         jz work_pending
 659         TRACE_IRQS_ON
 660         ENABLE_INTERRUPTS(CLBR_ANY)     # could let syscall_trace_leave() call
 661                                         # schedule() instead
 662         movl %esp, %eax
 663         call syscall_trace_leave
 664         jmp resume_userspace
 665 END(syscall_exit_work)
 666         CFI_ENDPROC
 667
 668         RING0_INT_FRAME                 # can't unwind into user space anyway
 669 syscall_fault:
 670         ASM_CLAC
 671         GET_THREAD_INFO(%ebp)
 672         movl $-EFAULT,PT_EAX(%esp)
 673         jmp resume_userspace
 674 END(syscall_fault)
 675
 676 syscall_badsys:
 677         movl $-ENOSYS,PT_EAX(%esp)
 678         jmp resume_userspace
 679 END(syscall_badsys)
 680         CFI_ENDPROC
 681
 682 .macro FIXUP_ESPFIX_STACK
 683 /*
 684  * Switch back for ESPFIX stack to the normal zerobased stack
 685  *
 686  * We can't call C functions using the ESPFIX stack. This code reads
 687  * the high word of the segment base from the GDT and swiches to the
 688  * normal stack and adjusts ESP with the matching offset.
 689  */
 690 #ifdef CONFIG_X86_ESPFIX32
 691         /* fixup the stack */
 692         mov GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
 693         mov GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
 694         shl $16, %eax
 695         addl %esp, %eax                 /* the adjusted stack pointer */
 696         pushl_cfi $__KERNEL_DS
 697         pushl_cfi %eax
 698         lss (%esp), %esp                /* switch to the normal stack segment */
 699         CFI_ADJUST_CFA_OFFSET -8
 700 #endif
 701 .endm
 702 .macro UNWIND_ESPFIX_STACK
 703 #ifdef CONFIG_X86_ESPFIX32
 704         movl %ss, %eax
 705         /* see if on espfix stack */
 706         cmpw $__ESPFIX_SS, %ax
 707         jne 27f
 708         movl $__KERNEL_DS, %eax
 709         movl %eax, %ds
 710         movl %eax, %es
 711         /* switch to normal stack */
 712         FIXUP_ESPFIX_STACK
 713 27:
 714 #endif
 715 .endm
 716
 717 /*
 718  * Build the entry stubs and pointer table with some assembler magic.
 719  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 720  * single cache line on all modern x86 implementations.
 721  */
 722 .section .init.rodata,"a"
 723 ENTRY(interrupt)
 724 .section .entry.text, "ax"
 725         .p2align 5
 726         .p2align CONFIG_X86_L1_CACHE_SHIFT
 727 ENTRY(irq_entries_start)
 728         RING0_INT_FRAME
 729 vector=FIRST_EXTERNAL_VECTOR
 730 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 731         .balign 32
 732   .rept 7
 733     .if vector < NR_VECTORS
 734       .if vector <> FIRST_EXTERNAL_VECTOR
 735         CFI_ADJUST_CFA_OFFSET -4
 736       .endif
 737 1:      pushl_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 738       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 739         jmp 2f
 740       .endif
 741       .previous
 742         .long 1b
 743       .section .entry.text, "ax"
 744 vector=vector+1
 745     .endif
 746   .endr
 747 2:      jmp common_interrupt
 748 .endr
 749 END(irq_entries_start)
 750
 751 .previous
 752 END(interrupt)
 753 .previous
 754
 755 /*
 756  * the CPU automatically disables interrupts when executing an IRQ vector,
 757  * so IRQ-flags tracing has to follow that:
 758  */
 759         .p2align CONFIG_X86_L1_CACHE_SHIFT
 760 common_interrupt:
 761         ASM_CLAC
 762         addl $-0x80,(%esp)      /* Adjust vector into the [-256,-1] range */
 763         SAVE_ALL
 764         TRACE_IRQS_OFF
 765         movl %esp,%eax
 766         call do_IRQ
 767         jmp ret_from_intr
 768 ENDPROC(common_interrupt)
 769         CFI_ENDPROC
 770
 771 #define BUILD_INTERRUPT3(name, nr, fn)  \
 772 ENTRY(name)                             \
 773         RING0_INT_FRAME;                \
 774         ASM_CLAC;                       \
 775         pushl_cfi $~(nr);               \
 776         SAVE_ALL;                       \
 777         TRACE_IRQS_OFF                  \
 778         movl %esp,%eax;                 \
 779         call fn;                        \
 780         jmp ret_from_intr;              \
 781         CFI_ENDPROC;                    \
 782 ENDPROC(name)
 783
 784
 785 #ifdef CONFIG_TRACING
 786 #define TRACE_BUILD_INTERRUPT(name, nr)         \
 787         BUILD_INTERRUPT3(trace_##name, nr, smp_trace_##name)
 788 #else
 789 #define TRACE_BUILD_INTERRUPT(name, nr)
 790 #endif
 791
 792 #define BUILD_INTERRUPT(name, nr) \
 793         BUILD_INTERRUPT3(name, nr, smp_##name); \
 794         TRACE_BUILD_INTERRUPT(name, nr)
 795
 796 /* The include is where all of the SMP etc. interrupts come from */
 797 #include <asm/entry_arch.h>
 798
 799 ENTRY(coprocessor_error)
 800         RING0_INT_FRAME
 801         ASM_CLAC
 802         pushl_cfi $0
 803         pushl_cfi $do_coprocessor_error
 804         jmp error_code
 805         CFI_ENDPROC
 806 END(coprocessor_error)
 807
 808 ENTRY(simd_coprocessor_error)
 809         RING0_INT_FRAME
 810         ASM_CLAC
 811         pushl_cfi $0
 812 #ifdef CONFIG_X86_INVD_BUG
 813         /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
 814 661:    pushl_cfi $do_general_protection
 815 662:
 816 .section .altinstructions,"a"
 817         altinstruction_entry 661b, 663f, X86_FEATURE_XMM, 662b-661b, 664f-663f
 818 .previous
 819 .section .altinstr_replacement,"ax"
 820 663:    pushl $do_simd_coprocessor_error
 821 664:
 822 .previous
 823 #else
 824         pushl_cfi $do_simd_coprocessor_error
 825 #endif
 826         jmp error_code
 827         CFI_ENDPROC
 828 END(simd_coprocessor_error)
 829
 830 ENTRY(device_not_available)
 831         RING0_INT_FRAME
 832         ASM_CLAC
 833         pushl_cfi $-1                   # mark this as an int
 834         pushl_cfi $do_device_not_available
 835         jmp error_code
 836         CFI_ENDPROC
 837 END(device_not_available)
 838
 839 #ifdef CONFIG_PARAVIRT
 840 ENTRY(native_iret)
 841         iret
 842         _ASM_EXTABLE(native_iret, iret_exc)
 843 END(native_iret)
 844
 845 ENTRY(native_irq_enable_sysexit)
 846         sti
 847         sysexit
 848 END(native_irq_enable_sysexit)
 849 #endif
 850
 851 ENTRY(overflow)
 852         RING0_INT_FRAME
 853         ASM_CLAC
 854         pushl_cfi $0
 855         pushl_cfi $do_overflow
 856         jmp error_code
 857         CFI_ENDPROC
 858 END(overflow)
 859
 860 ENTRY(bounds)
 861         RING0_INT_FRAME
 862         ASM_CLAC
 863         pushl_cfi $0
 864         pushl_cfi $do_bounds
 865         jmp error_code
 866         CFI_ENDPROC
 867 END(bounds)
 868
 869 ENTRY(invalid_op)
 870         RING0_INT_FRAME
 871         ASM_CLAC
 872         pushl_cfi $0
 873         pushl_cfi $do_invalid_op
 874         jmp error_code
 875         CFI_ENDPROC
 876 END(invalid_op)
 877
 878 ENTRY(coprocessor_segment_overrun)
 879         RING0_INT_FRAME
 880         ASM_CLAC
 881         pushl_cfi $0
 882         pushl_cfi $do_coprocessor_segment_overrun
 883         jmp error_code
 884         CFI_ENDPROC
 885 END(coprocessor_segment_overrun)
 886
 887 ENTRY(invalid_TSS)
 888         RING0_EC_FRAME
 889         ASM_CLAC
 890         pushl_cfi $do_invalid_TSS
 891         jmp error_code
 892         CFI_ENDPROC
 893 END(invalid_TSS)
 894
 895 ENTRY(segment_not_present)
 896         RING0_EC_FRAME
 897         ASM_CLAC
 898         pushl_cfi $do_segment_not_present
 899         jmp error_code
 900         CFI_ENDPROC
 901 END(segment_not_present)
 902
 903 ENTRY(stack_segment)
 904         RING0_EC_FRAME
 905         ASM_CLAC
 906         pushl_cfi $do_stack_segment
 907         jmp error_code
 908         CFI_ENDPROC
 909 END(stack_segment)
 910
 911 ENTRY(alignment_check)
 912         RING0_EC_FRAME
 913         ASM_CLAC
 914         pushl_cfi $do_alignment_check
 915         jmp error_code
 916         CFI_ENDPROC
 917 END(alignment_check)
 918
 919 ENTRY(divide_error)
 920         RING0_INT_FRAME
 921         ASM_CLAC
 922         pushl_cfi $0                    # no error code
 923         pushl_cfi $do_divide_error
 924         jmp error_code
 925         CFI_ENDPROC
 926 END(divide_error)
 927
 928 #ifdef CONFIG_X86_MCE
 929 ENTRY(machine_check)
 930         RING0_INT_FRAME
 931         ASM_CLAC
 932         pushl_cfi $0
 933         pushl_cfi machine_check_vector
 934         jmp error_code
 935         CFI_ENDPROC
 936 END(machine_check)
 937 #endif
 938
 939 ENTRY(spurious_interrupt_bug)
 940         RING0_INT_FRAME
 941         ASM_CLAC
 942         pushl_cfi $0
 943         pushl_cfi $do_spurious_interrupt_bug
 944         jmp error_code
 945         CFI_ENDPROC
 946 END(spurious_interrupt_bug)
 947
 948 #ifdef CONFIG_XEN
 949 /* Xen doesn't set %esp to be precisely what the normal sysenter
 950    entrypoint expects, so fix it up before using the normal path. */
 951 ENTRY(xen_sysenter_target)
 952         RING0_INT_FRAME
 953         addl $5*4, %esp         /* remove xen-provided frame */
 954         CFI_ADJUST_CFA_OFFSET -5*4
 955         jmp sysenter_past_esp
 956         CFI_ENDPROC
 957
 958 ENTRY(xen_hypervisor_callback)
 959         CFI_STARTPROC
 960         pushl_cfi $-1 /* orig_ax = -1 => not a system call */
 961         SAVE_ALL
 962         TRACE_IRQS_OFF
 963
 964         /* Check to see if we got the event in the critical
 965            region in xen_iret_direct, after we've reenabled
 966            events and checked for pending events.  This simulates
 967            iret instruction's behaviour where it delivers a
 968            pending interrupt when enabling interrupts. */
 969         movl PT_EIP(%esp),%eax
 970         cmpl $xen_iret_start_crit,%eax
 971         jb   1f
 972         cmpl $xen_iret_end_crit,%eax
 973         jae  1f
 974
 975         jmp  xen_iret_crit_fixup
 976
 977 ENTRY(xen_do_upcall)
 978 1:      mov %esp, %eax
 979         call xen_evtchn_do_upcall
 980         jmp  ret_from_intr
 981         CFI_ENDPROC
 982 ENDPROC(xen_hypervisor_callback)
 983
 984 # Hypervisor uses this for application faults while it executes.
 985 # We get here for two reasons:
 986 #  1. Fault while reloading DS, ES, FS or GS
 987 #  2. Fault while executing IRET
 988 # Category 1 we fix up by reattempting the load, and zeroing the segment
 989 # register if the load fails.
 990 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
 991 # normal Linux return path in this case because if we use the IRET hypercall
 992 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
 993 # We distinguish between categories by maintaining a status value in EAX.
 994 ENTRY(xen_failsafe_callback)
 995         CFI_STARTPROC
 996         pushl_cfi %eax
 997         movl $1,%eax
 998 1:      mov 4(%esp),%ds
 999 2:      mov 8(%esp),%es
1000 3:      mov 12(%esp),%fs
1001 4:      mov 16(%esp),%gs
1002         /* EAX == 0 => Category 1 (Bad segment)
1003            EAX != 0 => Category 2 (Bad IRET) */
1004         testl %eax,%eax
1005         popl_cfi %eax
1006         lea 16(%esp),%esp
1007         CFI_ADJUST_CFA_OFFSET -16
1008         jz 5f
1009         jmp iret_exc
1010 5:      pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1011         SAVE_ALL
1012         jmp ret_from_exception
1013         CFI_ENDPROC
1014
1015 .section .fixup,"ax"
1016 6:      xorl %eax,%eax
1017         movl %eax,4(%esp)
1018         jmp 1b
1019 7:      xorl %eax,%eax
1020         movl %eax,8(%esp)
1021         jmp 2b
1022 8:      xorl %eax,%eax
1023         movl %eax,12(%esp)
1024         jmp 3b
1025 9:      xorl %eax,%eax
1026         movl %eax,16(%esp)
1027         jmp 4b
1028 .previous
1029         _ASM_EXTABLE(1b,6b)
1030         _ASM_EXTABLE(2b,7b)
1031         _ASM_EXTABLE(3b,8b)
1032         _ASM_EXTABLE(4b,9b)
1033 ENDPROC(xen_failsafe_callback)
1034
1035 BUILD_INTERRUPT3(xen_hvm_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1036                 xen_evtchn_do_upcall)
1037
1038 #endif  /* CONFIG_XEN */
1039
1040 #if IS_ENABLED(CONFIG_HYPERV)
1041
1042 BUILD_INTERRUPT3(hyperv_callback_vector, HYPERVISOR_CALLBACK_VECTOR,
1043         hyperv_vector_handler)
1044
1045 #endif /* CONFIG_HYPERV */
1046
1047 #ifdef CONFIG_FUNCTION_TRACER
1048 #ifdef CONFIG_DYNAMIC_FTRACE
1049
1050 ENTRY(mcount)
1051         ret
1052 END(mcount)
1053
1054 ENTRY(ftrace_caller)
1055         cmpl $0, function_trace_stop
1056         jne  ftrace_stub
1057
1058         pushl %eax
1059         pushl %ecx
1060         pushl %edx
1061         pushl $0        /* Pass NULL as regs pointer */
1062         movl 4*4(%esp), %eax
1063         movl 0x4(%ebp), %edx
1064         movl function_trace_op, %ecx
1065         subl $MCOUNT_INSN_SIZE, %eax
1066
1067 .globl ftrace_call
1068 ftrace_call:
1069         call ftrace_stub
1070
1071         addl $4,%esp    /* skip NULL pointer */
1072         popl %edx
1073         popl %ecx
1074         popl %eax
1075 ftrace_ret:
1076 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1077 .globl ftrace_graph_call
1078 ftrace_graph_call:
1079         jmp ftrace_stub
1080 #endif
1081
1082 .globl ftrace_stub
1083 ftrace_stub:
1084         ret
1085 END(ftrace_caller)
1086
1087 ENTRY(ftrace_regs_caller)
1088         pushf   /* push flags before compare (in cs location) */
1089         cmpl $0, function_trace_stop
1090         jne ftrace_restore_flags
1091
1092         /*
1093          * i386 does not save SS and ESP when coming from kernel.
1094          * Instead, to get sp, &regs->sp is used (see ptrace.h).
1095          * Unfortunately, that means eflags must be at the same location
1096          * as the current return ip is. We move the return ip into the
1097          * ip location, and move flags into the return ip location.
1098          */
1099         pushl 4(%esp)   /* save return ip into ip slot */
1100
1101         pushl $0        /* Load 0 into orig_ax */
1102         pushl %gs
1103         pushl %fs
1104         pushl %es
1105         pushl %ds
1106         pushl %eax
1107         pushl %ebp
1108         pushl %edi
1109         pushl %esi
1110         pushl %edx
1111         pushl %ecx
1112         pushl %ebx
1113
1114         movl 13*4(%esp), %eax   /* Get the saved flags */
1115         movl %eax, 14*4(%esp)   /* Move saved flags into regs->flags location */
1116                                 /* clobbering return ip */
1117         movl $__KERNEL_CS,13*4(%esp)
1118
1119         movl 12*4(%esp), %eax   /* Load ip (1st parameter) */
1120         subl $MCOUNT_INSN_SIZE, %eax    /* Adjust ip */
1121         movl 0x4(%ebp), %edx    /* Load parent ip (2nd parameter) */
1122         movl function_trace_op, %ecx /* Save ftrace_pos in 3rd parameter */
1123         pushl %esp              /* Save pt_regs as 4th parameter */
1124
1125 GLOBAL(ftrace_regs_call)
1126         call ftrace_stub
1127
1128         addl $4, %esp           /* Skip pt_regs */
1129         movl 14*4(%esp), %eax   /* Move flags back into cs */
1130         movl %eax, 13*4(%esp)   /* Needed to keep addl from modifying flags */
1131         movl 12*4(%esp), %eax   /* Get return ip from regs->ip */
1132         movl %eax, 14*4(%esp)   /* Put return ip back for ret */
1133
1134         popl %ebx
1135         popl %ecx
1136         popl %edx
1137         popl %esi
1138         popl %edi
1139         popl %ebp
1140         popl %eax
1141         popl %ds
1142         popl %es
1143         popl %fs
1144         popl %gs
1145         addl $8, %esp           /* Skip orig_ax and ip */
1146         popf                    /* Pop flags at end (no addl to corrupt flags) */
1147         jmp ftrace_ret
1148
1149 ftrace_restore_flags:
1150         popf
1151         jmp  ftrace_stub
1152 #else /* ! CONFIG_DYNAMIC_FTRACE */
1153
1154 ENTRY(mcount)
1155         cmpl $__PAGE_OFFSET, %esp
1156         jb ftrace_stub          /* Paging not enabled yet? */
1157
1158         cmpl $0, function_trace_stop
1159         jne  ftrace_stub
1160
1161         cmpl $ftrace_stub, ftrace_trace_function
1162         jnz trace
1163 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1164         cmpl $ftrace_stub, ftrace_graph_return
1165         jnz ftrace_graph_caller
1166
1167         cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1168         jnz ftrace_graph_caller
1169 #endif
1170 .globl ftrace_stub
1171 ftrace_stub:
1172         ret
1173
1174         /* taken from glibc */
1175 trace:
1176         pushl %eax
1177         pushl %ecx
1178         pushl %edx
1179         movl 0xc(%esp), %eax
1180         movl 0x4(%ebp), %edx
1181         subl $MCOUNT_INSN_SIZE, %eax
1182
1183         call *ftrace_trace_function
1184
1185         popl %edx
1186         popl %ecx
1187         popl %eax
1188         jmp ftrace_stub
1189 END(mcount)
1190 #endif /* CONFIG_DYNAMIC_FTRACE */
1191 #endif /* CONFIG_FUNCTION_TRACER */
1192
1193 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1194 ENTRY(ftrace_graph_caller)
1195         pushl %eax
1196         pushl %ecx
1197         pushl %edx
1198         movl 0xc(%esp), %edx
1199         lea 0x4(%ebp), %eax
1200         movl (%ebp), %ecx
1201         subl $MCOUNT_INSN_SIZE, %edx
1202         call prepare_ftrace_return
1203         popl %edx
1204         popl %ecx
1205         popl %eax
1206         ret
1207 END(ftrace_graph_caller)
1208
1209 .globl return_to_handler
1210 return_to_handler:
1211         pushl %eax
1212         pushl %edx
1213         movl %ebp, %eax
1214         call ftrace_return_to_handler
1215         movl %eax, %ecx
1216         popl %edx
1217         popl %eax
1218         jmp *%ecx
1219 #endif
1220
1221 #ifdef CONFIG_TRACING
1222 ENTRY(trace_page_fault)
1223         RING0_EC_FRAME
1224         ASM_CLAC
1225         pushl_cfi $trace_do_page_fault
1226         jmp error_code
1227         CFI_ENDPROC
1228 END(trace_page_fault)
1229 #endif
1230
1231 ENTRY(page_fault)
1232         RING0_EC_FRAME
1233         ASM_CLAC
1234         pushl_cfi $do_page_fault
1235         ALIGN
1236 error_code:
1237         /* the function address is in %gs's slot on the stack */
1238         pushl_cfi %fs
1239         /*CFI_REL_OFFSET fs, 0*/
1240         pushl_cfi %es
1241         /*CFI_REL_OFFSET es, 0*/
1242         pushl_cfi %ds
1243         /*CFI_REL_OFFSET ds, 0*/
1244         pushl_cfi %eax
1245         CFI_REL_OFFSET eax, 0
1246         pushl_cfi %ebp
1247         CFI_REL_OFFSET ebp, 0
1248         pushl_cfi %edi
1249         CFI_REL_OFFSET edi, 0
1250         pushl_cfi %esi
1251         CFI_REL_OFFSET esi, 0
1252         pushl_cfi %edx
1253         CFI_REL_OFFSET edx, 0
1254         pushl_cfi %ecx
1255         CFI_REL_OFFSET ecx, 0
1256         pushl_cfi %ebx
1257         CFI_REL_OFFSET ebx, 0
1258         cld
1259         movl $(__KERNEL_PERCPU), %ecx
1260         movl %ecx, %fs
1261         UNWIND_ESPFIX_STACK
1262         GS_TO_REG %ecx
1263         movl PT_GS(%esp), %edi          # get the function address
1264         movl PT_ORIG_EAX(%esp), %edx    # get the error code
1265         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
1266         REG_TO_PTGS %ecx
1267         SET_KERNEL_GS %ecx
1268         movl $(__USER_DS), %ecx
1269         movl %ecx, %ds
1270         movl %ecx, %es
1271         TRACE_IRQS_OFF
1272         movl %esp,%eax                  # pt_regs pointer
1273         call *%edi
1274         jmp ret_from_exception
1275         CFI_ENDPROC
1276 END(page_fault)
1277
1278 /*
1279  * Debug traps and NMI can happen at the one SYSENTER instruction
1280  * that sets up the real kernel stack. Check here, since we can't
1281  * allow the wrong stack to be used.
1282  *
1283  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1284  * already pushed 3 words if it hits on the sysenter instruction:
1285  * eflags, cs and eip.
1286  *
1287  * We just load the right stack, and push the three (known) values
1288  * by hand onto the new stack - while updating the return eip past
1289  * the instruction that would have done it for sysenter.
1290  */
1291 .macro FIX_STACK offset ok label
1292         cmpw $__KERNEL_CS, 4(%esp)
1293         jne \ok
1294 \label:
1295         movl TSS_sysenter_sp0 + \offset(%esp), %esp
1296         CFI_DEF_CFA esp, 0
1297         CFI_UNDEFINED eip
1298         pushfl_cfi
1299         pushl_cfi $__KERNEL_CS
1300         pushl_cfi $sysenter_past_esp
1301         CFI_REL_OFFSET eip, 0
1302 .endm
1303
1304 ENTRY(debug)
1305         RING0_INT_FRAME
1306         ASM_CLAC
1307         cmpl $ia32_sysenter_target,(%esp)
1308         jne debug_stack_correct
1309         FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1310 debug_stack_correct:
1311         pushl_cfi $-1                   # mark this as an int
1312         SAVE_ALL
1313         TRACE_IRQS_OFF
1314         xorl %edx,%edx                  # error code 0
1315         movl %esp,%eax                  # pt_regs pointer
1316         call do_debug
1317         jmp ret_from_exception
1318         CFI_ENDPROC
1319 END(debug)
1320
1321 /*
1322  * NMI is doubly nasty. It can happen _while_ we're handling
1323  * a debug fault, and the debug fault hasn't yet been able to
1324  * clear up the stack. So we first check whether we got  an
1325  * NMI on the sysenter entry path, but after that we need to
1326  * check whether we got an NMI on the debug path where the debug
1327  * fault happened on the sysenter path.
1328  */
1329 ENTRY(nmi)
1330         RING0_INT_FRAME
1331         ASM_CLAC
1332 #ifdef CONFIG_X86_ESPFIX32
1333         pushl_cfi %eax
1334         movl %ss, %eax
1335         cmpw $__ESPFIX_SS, %ax
1336         popl_cfi %eax
1337         je nmi_espfix_stack
1338 #endif
1339         cmpl $ia32_sysenter_target,(%esp)
1340         je nmi_stack_fixup
1341         pushl_cfi %eax
1342         movl %esp,%eax
1343         /* Do not access memory above the end of our stack page,
1344          * it might not exist.
1345          */
1346         andl $(THREAD_SIZE-1),%eax
1347         cmpl $(THREAD_SIZE-20),%eax
1348         popl_cfi %eax
1349         jae nmi_stack_correct
1350         cmpl $ia32_sysenter_target,12(%esp)
1351         je nmi_debug_stack_check
1352 nmi_stack_correct:
1353         /* We have a RING0_INT_FRAME here */
1354         pushl_cfi %eax
1355         SAVE_ALL
1356         xorl %edx,%edx          # zero error code
1357         movl %esp,%eax          # pt_regs pointer
1358         call do_nmi
1359         jmp restore_all_notrace
1360         CFI_ENDPROC
1361
1362 nmi_stack_fixup:
1363         RING0_INT_FRAME
1364         FIX_STACK 12, nmi_stack_correct, 1
1365         jmp nmi_stack_correct
1366
1367 nmi_debug_stack_check:
1368         /* We have a RING0_INT_FRAME here */
1369         cmpw $__KERNEL_CS,16(%esp)
1370         jne nmi_stack_correct
1371         cmpl $debug,(%esp)
1372         jb nmi_stack_correct
1373         cmpl $debug_esp_fix_insn,(%esp)
1374         ja nmi_stack_correct
1375         FIX_STACK 24, nmi_stack_correct, 1
1376         jmp nmi_stack_correct
1377
1378 #ifdef CONFIG_X86_ESPFIX32
1379 nmi_espfix_stack:
1380         /* We have a RING0_INT_FRAME here.
1381          *
1382          * create the pointer to lss back
1383          */
1384         pushl_cfi %ss
1385         pushl_cfi %esp
1386         addl $4, (%esp)
1387         /* copy the iret frame of 12 bytes */
1388         .rept 3
1389         pushl_cfi 16(%esp)
1390         .endr
1391         pushl_cfi %eax
1392         SAVE_ALL
1393         FIXUP_ESPFIX_STACK              # %eax == %esp
1394         xorl %edx,%edx                  # zero error code
1395         call do_nmi
1396         RESTORE_REGS
1397         lss 12+4(%esp), %esp            # back to espfix stack
1398         CFI_ADJUST_CFA_OFFSET -24
1399         jmp irq_return
1400 #endif
1401         CFI_ENDPROC
1402 END(nmi)
1403
1404 ENTRY(int3)
1405         RING0_INT_FRAME
1406         ASM_CLAC
1407         pushl_cfi $-1                   # mark this as an int
1408         SAVE_ALL
1409         TRACE_IRQS_OFF
1410         xorl %edx,%edx          # zero error code
1411         movl %esp,%eax          # pt_regs pointer
1412         call do_int3
1413         jmp ret_from_exception
1414         CFI_ENDPROC
1415 END(int3)
1416
1417 ENTRY(general_protection)
1418         RING0_EC_FRAME
1419         pushl_cfi $do_general_protection
1420         jmp error_code
1421         CFI_ENDPROC
1422 END(general_protection)
1423
1424 #ifdef CONFIG_KVM_GUEST
1425 ENTRY(async_page_fault)
1426         RING0_EC_FRAME
1427         ASM_CLAC
1428         pushl_cfi $do_async_page_fault
1429         jmp error_code
1430         CFI_ENDPROC
1431 END(async_page_fault)
1432 #endif
1433