arch/x86/kernel/entry_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  */
   5
   6 /*
   7  * entry.S contains the system-call and fault low-level handling routines.
   8  * This also contains the timer-interrupt handler, as well as all interrupts
   9  * and faults that can result in a task-switch.
  10  *
  11  * NOTE: This code handles signal-recognition, which happens every time
  12  * after a timer-interrupt and after each system call.
  13  *
  14  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  15  * on a 486.
  16  *
  17  * Stack layout in 'syscall_exit':
  18  *      ptrace needs to have all regs on the stack.
  19  *      if the order here is changed, it needs to be
  20  *      updated in fork.c:copy_process, signal.c:do_signal,
  21  *      ptrace.c and ptrace.h
  22  *
  23  *       0(%esp) - %ebx
  24  *       4(%esp) - %ecx
  25  *       8(%esp) - %edx
  26  *       C(%esp) - %esi
  27  *      10(%esp) - %edi
  28  *      14(%esp) - %ebp
  29  *      18(%esp) - %eax
  30  *      1C(%esp) - %ds
  31  *      20(%esp) - %es
  32  *      24(%esp) - %fs
  33  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
  34  *      2C(%esp) - orig_eax
  35  *      30(%esp) - %eip
  36  *      34(%esp) - %cs
  37  *      38(%esp) - %eflags
  38  *      3C(%esp) - %oldesp
  39  *      40(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <linux/err.h>
  46 #include <asm/thread_info.h>
  47 #include <asm/irqflags.h>
  48 #include <asm/errno.h>
  49 #include <asm/segment.h>
  50 #include <asm/smp.h>
  51 #include <asm/page_types.h>
  52 #include <asm/percpu.h>
  53 #include <asm/dwarf2.h>
  54 #include <asm/processor-flags.h>
  55 #include <asm/ftrace.h>
  56 #include <asm/irq_vectors.h>
  57 #include <asm/cpufeature.h>
  58 #include <asm/alternative-asm.h>
  59 #include <asm/asm.h>
  60 #include <asm/smap.h>
  61
  62 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  63 #include <linux/elf-em.h>
  64 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  65 #define __AUDIT_ARCH_LE    0x40000000
  66
  67 #ifndef CONFIG_AUDITSYSCALL
  68 #define sysenter_audit  syscall_trace_entry
  69 #define sysexit_audit   syscall_exit_work
  70 #endif
  71
  72         .section .entry.text, "ax"
  73
  74 /*
  75  * We use macros for low-level operations which need to be overridden
  76  * for paravirtualization.  The following will never clobber any registers:
  77  *   INTERRUPT_RETURN (aka. "iret")
  78  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  79  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  80  *
  81  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  82  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  83  * Allowing a register to be clobbered can shrink the paravirt replacement
  84  * enough to patch inline, increasing performance.
  85  */
  86
  87 #ifdef CONFIG_PREEMPT
  88 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  89 #else
  90 #define preempt_stop(clobbers)
  91 #define resume_kernel           restore_all
  92 #endif
  93
  94 .macro TRACE_IRQS_IRET
  95 #ifdef CONFIG_TRACE_IRQFLAGS
  96         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)     # interrupts off?
  97         jz 1f
  98         TRACE_IRQS_ON
  99 1:
 100 #endif
 101 .endm
 102
 103 /*
 104  * User gs save/restore
 105  *
 106  * %gs is used for userland TLS and kernel only uses it for stack
 107  * canary which is required to be at %gs:20 by gcc.  Read the comment
 108  * at the top of stackprotector.h for more info.
 109  *
 110  * Local labels 98 and 99 are used.
 111  */
 112 #ifdef CONFIG_X86_32_LAZY_GS
 113
 114  /* unfortunately push/pop can't be no-op */
 115 .macro PUSH_GS
 116         pushl_cfi $0
 117 .endm
 118 .macro POP_GS pop=0
 119         addl $(4 + \pop), %esp
 120         CFI_ADJUST_CFA_OFFSET -(4 + \pop)
 121 .endm
 122 .macro POP_GS_EX
 123 .endm
 124
 125  /* all the rest are no-op */
 126 .macro PTGS_TO_GS
 127 .endm
 128 .macro PTGS_TO_GS_EX
 129 .endm
 130 .macro GS_TO_REG reg
 131 .endm
 132 .macro REG_TO_PTGS reg
 133 .endm
 134 .macro SET_KERNEL_GS reg
 135 .endm
 136
 137 #else   /* CONFIG_X86_32_LAZY_GS */
 138
 139 .macro PUSH_GS
 140         pushl_cfi %gs
 141         /*CFI_REL_OFFSET gs, 0*/
 142 .endm
 143
 144 .macro POP_GS pop=0
 145 98:     popl_cfi %gs
 146         /*CFI_RESTORE gs*/
 147   .if \pop <> 0
 148         add $\pop, %esp
 149         CFI_ADJUST_CFA_OFFSET -\pop
 150   .endif
 151 .endm
 152 .macro POP_GS_EX
 153 .pushsection .fixup, "ax"
 154 99:     movl $0, (%esp)
 155         jmp 98b
 156 .popsection
 157         _ASM_EXTABLE(98b,99b)
 158 .endm
 159
 160 .macro PTGS_TO_GS
 161 98:     mov PT_GS(%esp), %gs
 162 .endm
 163 .macro PTGS_TO_GS_EX
 164 .pushsection .fixup, "ax"
 165 99:     movl $0, PT_GS(%esp)
 166         jmp 98b
 167 .popsection
 168         _ASM_EXTABLE(98b,99b)
 169 .endm
 170
 171 .macro GS_TO_REG reg
 172         movl %gs, \reg
 173         /*CFI_REGISTER gs, \reg*/
 174 .endm
 175 .macro REG_TO_PTGS reg
 176         movl \reg, PT_GS(%esp)
 177         /*CFI_REL_OFFSET gs, PT_GS*/
 178 .endm
 179 .macro SET_KERNEL_GS reg
 180         movl $(__KERNEL_STACK_CANARY), \reg
 181         movl \reg, %gs
 182 .endm
 183
 184 #endif  /* CONFIG_X86_32_LAZY_GS */
 185
 186 .macro SAVE_ALL
 187         cld
 188         PUSH_GS
 189         pushl_cfi %fs
 190         /*CFI_REL_OFFSET fs, 0;*/
 191         pushl_cfi %es
 192         /*CFI_REL_OFFSET es, 0;*/
 193         pushl_cfi %ds
 194         /*CFI_REL_OFFSET ds, 0;*/
 195         pushl_cfi %eax
 196         CFI_REL_OFFSET eax, 0
 197         pushl_cfi %ebp
 198         CFI_REL_OFFSET ebp, 0
 199         pushl_cfi %edi
 200         CFI_REL_OFFSET edi, 0
 201         pushl_cfi %esi
 202         CFI_REL_OFFSET esi, 0
 203         pushl_cfi %edx
 204         CFI_REL_OFFSET edx, 0
 205         pushl_cfi %ecx
 206         CFI_REL_OFFSET ecx, 0
 207         pushl_cfi %ebx
 208         CFI_REL_OFFSET ebx, 0
 209         movl $(__USER_DS), %edx
 210         movl %edx, %ds
 211         movl %edx, %es
 212         movl $(__KERNEL_PERCPU), %edx
 213         movl %edx, %fs
 214         SET_KERNEL_GS %edx
 215 .endm
 216
 217 .macro RESTORE_INT_REGS
 218         popl_cfi %ebx
 219         CFI_RESTORE ebx
 220         popl_cfi %ecx
 221         CFI_RESTORE ecx
 222         popl_cfi %edx
 223         CFI_RESTORE edx
 224         popl_cfi %esi
 225         CFI_RESTORE esi
 226         popl_cfi %edi
 227         CFI_RESTORE edi
 228         popl_cfi %ebp
 229         CFI_RESTORE ebp
 230         popl_cfi %eax
 231         CFI_RESTORE eax
 232 .endm
 233
 234 .macro RESTORE_REGS pop=0
 235         RESTORE_INT_REGS
 236 1:      popl_cfi %ds
 237         /*CFI_RESTORE ds;*/
 238 2:      popl_cfi %es
 239         /*CFI_RESTORE es;*/
 240 3:      popl_cfi %fs
 241         /*CFI_RESTORE fs;*/
 242         POP_GS \pop
 243 .pushsection .fixup, "ax"
 244 4:      movl $0, (%esp)
 245         jmp 1b
 246 5:      movl $0, (%esp)
 247         jmp 2b
 248 6:      movl $0, (%esp)
 249         jmp 3b
 250 .popsection
 251         _ASM_EXTABLE(1b,4b)
 252         _ASM_EXTABLE(2b,5b)
 253         _ASM_EXTABLE(3b,6b)
 254         POP_GS_EX
 255 .endm
 256
 257 .macro RING0_INT_FRAME
 258         CFI_STARTPROC simple
 259         CFI_SIGNAL_FRAME
 260         CFI_DEF_CFA esp, 3*4
 261         /*CFI_OFFSET cs, -2*4;*/
 262         CFI_OFFSET eip, -3*4
 263 .endm
 264
 265 .macro RING0_EC_FRAME
 266         CFI_STARTPROC simple
 267         CFI_SIGNAL_FRAME
 268         CFI_DEF_CFA esp, 4*4
 269         /*CFI_OFFSET cs, -2*4;*/
 270         CFI_OFFSET eip, -3*4
 271 .endm
 272
 273 .macro RING0_PTREGS_FRAME
 274         CFI_STARTPROC simple
 275         CFI_SIGNAL_FRAME
 276         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
 277         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
 278         CFI_OFFSET eip, PT_EIP-PT_OLDESP
 279         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
 280         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
 281         CFI_OFFSET eax, PT_EAX-PT_OLDESP
 282         CFI_OFFSET ebp, PT_EBP-PT_OLDESP
 283         CFI_OFFSET edi, PT_EDI-PT_OLDESP
 284         CFI_OFFSET esi, PT_ESI-PT_OLDESP
 285         CFI_OFFSET edx, PT_EDX-PT_OLDESP
 286         CFI_OFFSET ecx, PT_ECX-PT_OLDESP
 287         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 288 .endm
 289
 290 ENTRY(ret_from_fork)
 291         CFI_STARTPROC
 292         pushl_cfi %eax
 293         call schedule_tail
 294         GET_THREAD_INFO(%ebp)
 295         popl_cfi %eax
 296         pushl_cfi $0x0202               # Reset kernel eflags
 297         popfl_cfi
 298         jmp syscall_exit
 299         CFI_ENDPROC
 300 END(ret_from_fork)
 301
 302 ENTRY(ret_from_kernel_thread)
 303         CFI_STARTPROC
 304         pushl_cfi %eax
 305         call schedule_tail
 306         GET_THREAD_INFO(%ebp)
 307         popl_cfi %eax
 308         pushl_cfi $0x0202               # Reset kernel eflags
 309         popfl_cfi
 310         movl PT_EBP(%esp),%eax
 311         call *PT_EBX(%esp)
 312         movl $0,PT_EAX(%esp)
 313         jmp syscall_exit
 314         CFI_ENDPROC
 315 ENDPROC(ret_from_kernel_thread)
 316
 317 /*
 318  * Interrupt exit functions should be protected against kprobes
 319  */
 320         .pushsection .kprobes.text, "ax"
 321 /*
 322  * Return to user mode is not as complex as all this looks,
 323  * but we want the default path for a system call return to
 324  * go as quickly as possible which is why some of this is
 325  * less clear than it otherwise should be.
 326  */
 327
 328         # userspace resumption stub bypassing syscall exit tracing
 329         ALIGN
 330         RING0_PTREGS_FRAME
 331 ret_from_exception:
 332         preempt_stop(CLBR_ANY)
 333 ret_from_intr:
 334         GET_THREAD_INFO(%ebp)
 335 #ifdef CONFIG_VM86
 336         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 337         movb PT_CS(%esp), %al
 338         andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 339 #else
 340         /*
 341          * We can be coming here from child spawned by kernel_thread().
 342          */
 343         movl PT_CS(%esp), %eax
 344         andl $SEGMENT_RPL_MASK, %eax
 345 #endif
 346         cmpl $USER_RPL, %eax
 347         jb resume_kernel                # not returning to v8086 or userspace
 348
 349 ENTRY(resume_userspace)
 350         LOCKDEP_SYS_EXIT
 351         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 352                                         # setting need_resched or sigpending
 353                                         # between sampling and the iret
 354         TRACE_IRQS_OFF
 355         movl TI_flags(%ebp), %ecx
 356         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 357                                         # int/exception return?
 358         jne work_pending
 359         jmp restore_all
 360 END(ret_from_exception)
 361
 362 #ifdef CONFIG_PREEMPT
 363 ENTRY(resume_kernel)
 364         DISABLE_INTERRUPTS(CLBR_ANY)
 365         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
 366         jnz restore_all
 367 need_resched:
 368         movl TI_flags(%ebp), %ecx       # need_resched set ?
 369         testb $_TIF_NEED_RESCHED, %cl
 370         jz restore_all
 371         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)    # interrupts off (exception path) ?
 372         jz restore_all
 373         call preempt_schedule_irq
 374         jmp need_resched
 375 END(resume_kernel)
 376 #endif
 377         CFI_ENDPROC
 378 /*
 379  * End of kprobes section
 380  */
 381         .popsection
 382
 383 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 384    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 385
 386         # sysenter call handler stub
 387 ENTRY(ia32_sysenter_target)
 388         CFI_STARTPROC simple
 389         CFI_SIGNAL_FRAME
 390         CFI_DEF_CFA esp, 0
 391         CFI_REGISTER esp, ebp
 392         movl TSS_sysenter_sp0(%esp),%esp
 393 sysenter_past_esp:
 394         /*
 395          * Interrupts are disabled here, but we can't trace it until
 396          * enough kernel state to call TRACE_IRQS_OFF can be called - but
 397          * we immediately enable interrupts at that point anyway.
 398          */
 399         pushl_cfi $__USER_DS
 400         /*CFI_REL_OFFSET ss, 0*/
 401         pushl_cfi %ebp
 402         CFI_REL_OFFSET esp, 0
 403         pushfl_cfi
 404         orl $X86_EFLAGS_IF, (%esp)
 405         pushl_cfi $__USER_CS
 406         /*CFI_REL_OFFSET cs, 0*/
 407         /*
 408          * Push current_thread_info()->sysenter_return to the stack.
 409          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 410          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 411          */
 412         pushl_cfi ((TI_sysenter_return)-THREAD_SIZE+8+4*4)(%esp)
 413         CFI_REL_OFFSET eip, 0
 414
 415         pushl_cfi %eax
 416         SAVE_ALL
 417         ENABLE_INTERRUPTS(CLBR_NONE)
 418
 419 /*
 420  * Load the potential sixth argument from user stack.
 421  * Careful about security.
 422  */
 423         cmpl $__PAGE_OFFSET-3,%ebp
 424         jae syscall_fault
 425         ASM_STAC
 426 1:      movl (%ebp),%ebp
 427         ASM_CLAC
 428         movl %ebp,PT_EBP(%esp)
 429         _ASM_EXTABLE(1b,syscall_fault)
 430
 431         GET_THREAD_INFO(%ebp)
 432
 433         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 434         jnz sysenter_audit
 435 sysenter_do_call:
 436         cmpl $(NR_syscalls), %eax
 437         jae syscall_badsys
 438         call *sys_call_table(,%eax,4)
 439         movl %eax,PT_EAX(%esp)
 440         LOCKDEP_SYS_EXIT
 441         DISABLE_INTERRUPTS(CLBR_ANY)
 442         TRACE_IRQS_OFF
 443         movl TI_flags(%ebp), %ecx
 444         testl $_TIF_ALLWORK_MASK, %ecx
 445         jne sysexit_audit
 446 sysenter_exit:
 447 /* if something modifies registers it must also disable sysexit */
 448         movl PT_EIP(%esp), %edx
 449         movl PT_OLDESP(%esp), %ecx
 450         xorl %ebp,%ebp
 451         TRACE_IRQS_ON
 452 1:      mov  PT_FS(%esp), %fs
 453         PTGS_TO_GS
 454         ENABLE_INTERRUPTS_SYSEXIT
 455
 456 #ifdef CONFIG_AUDITSYSCALL
 457 sysenter_audit:
 458         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 459         jnz syscall_trace_entry
 460         addl $4,%esp
 461         CFI_ADJUST_CFA_OFFSET -4
 462         /* %esi already in 8(%esp)         6th arg: 4th syscall arg */
 463         /* %edx already in 4(%esp)         5th arg: 3rd syscall arg */
 464         /* %ecx already in 0(%esp)         4th arg: 2nd syscall arg */
 465         movl %ebx,%ecx                  /* 3rd arg: 1st syscall arg */
 466         movl %eax,%edx                  /* 2nd arg: syscall number */
 467         movl $AUDIT_ARCH_I386,%eax      /* 1st arg: audit arch */
 468         call __audit_syscall_entry
 469         pushl_cfi %ebx
 470         movl PT_EAX(%esp),%eax          /* reload syscall number */
 471         jmp sysenter_do_call
 472
 473 sysexit_audit:
 474         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 475         jne syscall_exit_work
 476         TRACE_IRQS_ON
 477         ENABLE_INTERRUPTS(CLBR_ANY)
 478         movl %eax,%edx          /* second arg, syscall return value */
 479         cmpl $-MAX_ERRNO,%eax   /* is it an error ? */
 480         setbe %al               /* 1 if so, 0 if not */
 481         movzbl %al,%eax         /* zero-extend that */
 482         call __audit_syscall_exit
 483         DISABLE_INTERRUPTS(CLBR_ANY)
 484         TRACE_IRQS_OFF
 485         movl TI_flags(%ebp), %ecx
 486         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 487         jne syscall_exit_work
 488         movl PT_EAX(%esp),%eax  /* reload syscall return value */
 489         jmp sysenter_exit
 490 #endif
 491
 492         CFI_ENDPROC
 493 .pushsection .fixup,"ax"
 494 2:      movl $0,PT_FS(%esp)
 495         jmp 1b
 496 .popsection
 497         _ASM_EXTABLE(1b,2b)
 498         PTGS_TO_GS_EX
 499 ENDPROC(ia32_sysenter_target)
 500
 501 /*
 502  * syscall stub including irq exit should be protected against kprobes
 503  */
 504         .pushsection .kprobes.text, "ax"
 505         # system call handler stub
 506 ENTRY(system_call)
 507         RING0_INT_FRAME                 # can't unwind into user space anyway
 508         ASM_CLAC
 509         pushl_cfi %eax                  # save orig_eax
 510         SAVE_ALL
 511         GET_THREAD_INFO(%ebp)
 512                                         # system call tracing in operation / emulation
 513         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 514         jnz syscall_trace_entry
 515         cmpl $(NR_syscalls), %eax
 516         jae syscall_badsys
 517 syscall_call:
 518         call *sys_call_table(,%eax,4)
 519         movl %eax,PT_EAX(%esp)          # store the return value
 520 syscall_exit:
 521         LOCKDEP_SYS_EXIT
 522         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 523                                         # setting need_resched or sigpending
 524                                         # between sampling and the iret
 525         TRACE_IRQS_OFF
 526         movl TI_flags(%ebp), %ecx
 527         testl $_TIF_ALLWORK_MASK, %ecx  # current->work
 528         jne syscall_exit_work
 529
 530 restore_all:
 531         TRACE_IRQS_IRET
 532 restore_all_notrace:
 533         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 534         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 535         # are returning to the kernel.
 536         # See comments in process.c:copy_thread() for details.
 537         movb PT_OLDSS(%esp), %ah
 538         movb PT_CS(%esp), %al
 539         andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 540         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 541         CFI_REMEMBER_STATE
 542         je ldt_ss                       # returning to user-space with LDT SS
 543 restore_nocheck:
 544         RESTORE_REGS 4                  # skip orig_eax/error_code
 545 irq_return:
 546         INTERRUPT_RETURN
 547 .section .fixup,"ax"
 548 ENTRY(iret_exc)
 549         pushl $0                        # no error code
 550         pushl $do_iret_error
 551         jmp error_code
 552 .previous
 553         _ASM_EXTABLE(irq_return,iret_exc)
 554
 555         CFI_RESTORE_STATE
 556 ldt_ss:
 557         larl PT_OLDSS(%esp), %eax
 558         jnz restore_nocheck
 559         testl $0x00400000, %eax         # returning to 32bit stack?
 560         jnz restore_nocheck             # allright, normal return
 561
 562 #ifdef CONFIG_PARAVIRT
 563         /*
 564          * The kernel can't run on a non-flat stack if paravirt mode
 565          * is active.  Rather than try to fixup the high bits of
 566          * ESP, bypass this code entirely.  This may break DOSemu
 567          * and/or Wine support in a paravirt VM, although the option
 568          * is still available to implement the setting of the high
 569          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 570          */
 571         cmpl $0, pv_info+PARAVIRT_enabled
 572         jne restore_nocheck
 573 #endif
 574
 575 /*
 576  * Setup and switch to ESPFIX stack
 577  *
 578  * We're returning to userspace with a 16 bit stack. The CPU will not
 579  * restore the high word of ESP for us on executing iret... This is an
 580  * "official" bug of all the x86-compatible CPUs, which we can work
 581  * around to make dosemu and wine happy. We do this by preloading the
 582  * high word of ESP with the high word of the userspace ESP while
 583  * compensating for the offset by changing to the ESPFIX segment with
 584  * a base address that matches for the difference.
 585  */
 586 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
 587         mov %esp, %edx                  /* load kernel esp */
 588         mov PT_OLDESP(%esp), %eax       /* load userspace esp */
 589         mov %dx, %ax                    /* eax: new kernel esp */
 590         sub %eax, %edx                  /* offset (low word is 0) */
 591         shr $16, %edx
 592         mov %dl, GDT_ESPFIX_SS + 4 /* bits 16..23 */
 593         mov %dh, GDT_ESPFIX_SS + 7 /* bits 24..31 */
 594         pushl_cfi $__ESPFIX_SS
 595         pushl_cfi %eax                  /* new kernel esp */
 596         /* Disable interrupts, but do not irqtrace this section: we
 597          * will soon execute iret and the tracer was already set to
 598          * the irqstate after the iret */
 599         DISABLE_INTERRUPTS(CLBR_EAX)
 600         lss (%esp), %esp                /* switch to espfix segment */
 601         CFI_ADJUST_CFA_OFFSET -8
 602         jmp restore_nocheck
 603         CFI_ENDPROC
 604 ENDPROC(system_call)
 605
 606         # perform work that needs to be done immediately before resumption
 607         ALIGN
 608         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 609 work_pending:
 610         testb $_TIF_NEED_RESCHED, %cl
 611         jz work_notifysig
 612 work_resched:
 613         call schedule
 614         LOCKDEP_SYS_EXIT
 615         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 616                                         # setting need_resched or sigpending
 617                                         # between sampling and the iret
 618         TRACE_IRQS_OFF
 619         movl TI_flags(%ebp), %ecx
 620         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 621                                         # than syscall tracing?
 622         jz restore_all
 623         testb $_TIF_NEED_RESCHED, %cl
 624         jnz work_resched
 625
 626 work_notifysig:                         # deal with pending signals and
 627                                         # notify-resume requests
 628 #ifdef CONFIG_VM86
 629         testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
 630         movl %esp, %eax
 631         jne work_notifysig_v86          # returning to kernel-space or
 632                                         # vm86-space
 633 1:
 634 #else
 635         movl %esp, %eax
 636 #endif
 637         TRACE_IRQS_ON
 638         ENABLE_INTERRUPTS(CLBR_NONE)
 639         movb PT_CS(%esp), %bl
 640         andb $SEGMENT_RPL_MASK, %bl
 641         cmpb $USER_RPL, %bl
 642         jb resume_kernel
 643         xorl %edx, %edx
 644         call do_notify_resume
 645         jmp resume_userspace
 646
 647 #ifdef CONFIG_VM86
 648         ALIGN
 649 work_notifysig_v86:
 650         pushl_cfi %ecx                  # save ti_flags for do_notify_resume
 651         call save_v86_state             # %eax contains pt_regs pointer
 652         popl_cfi %ecx
 653         movl %eax, %esp
 654         jmp 1b
 655 #endif
 656 END(work_pending)
 657
 658         # perform syscall exit tracing
 659         ALIGN
 660 syscall_trace_entry:
 661         movl $-ENOSYS,PT_EAX(%esp)
 662         movl %esp, %eax
 663         call syscall_trace_enter
 664         /* What it returned is what we'll actually use.  */
 665         cmpl $(NR_syscalls), %eax
 666         jnae syscall_call
 667         jmp syscall_exit
 668 END(syscall_trace_entry)
 669
 670         # perform syscall exit tracing
 671         ALIGN
 672 syscall_exit_work:
 673         testl $_TIF_WORK_SYSCALL_EXIT, %ecx
 674         jz work_pending
 675         TRACE_IRQS_ON
 676         ENABLE_INTERRUPTS(CLBR_ANY)     # could let syscall_trace_leave() call
 677                                         # schedule() instead
 678         movl %esp, %eax
 679         call syscall_trace_leave
 680         jmp resume_userspace
 681 END(syscall_exit_work)
 682         CFI_ENDPROC
 683
 684         RING0_INT_FRAME                 # can't unwind into user space anyway
 685 syscall_fault:
 686         ASM_CLAC
 687         GET_THREAD_INFO(%ebp)
 688         movl $-EFAULT,PT_EAX(%esp)
 689         jmp resume_userspace
 690 END(syscall_fault)
 691
 692 syscall_badsys:
 693         movl $-ENOSYS,PT_EAX(%esp)
 694         jmp resume_userspace
 695 END(syscall_badsys)
 696         CFI_ENDPROC
 697 /*
 698  * End of kprobes section
 699  */
 700         .popsection
 701
 702 /*
 703  * System calls that need a pt_regs pointer.
 704  */
 705 #define PTREGSCALL0(name) \
 706 ENTRY(ptregs_##name) ;  \
 707         leal 4(%esp),%eax; \
 708         jmp sys_##name; \
 709 ENDPROC(ptregs_##name)
 710
 711 #define PTREGSCALL1(name) \
 712 ENTRY(ptregs_##name) ; \
 713         leal 4(%esp),%edx; \
 714         movl (PT_EBX+4)(%esp),%eax; \
 715         jmp sys_##name; \
 716 ENDPROC(ptregs_##name)
 717
 718 #define PTREGSCALL2(name) \
 719 ENTRY(ptregs_##name) ; \
 720         leal 4(%esp),%ecx; \
 721         movl (PT_ECX+4)(%esp),%edx; \
 722         movl (PT_EBX+4)(%esp),%eax; \
 723         jmp sys_##name; \
 724 ENDPROC(ptregs_##name)
 725
 726 #define PTREGSCALL3(name) \
 727 ENTRY(ptregs_##name) ; \
 728         CFI_STARTPROC; \
 729         leal 4(%esp),%eax; \
 730         pushl_cfi %eax; \
 731         movl PT_EDX(%eax),%ecx; \
 732         movl PT_ECX(%eax),%edx; \
 733         movl PT_EBX(%eax),%eax; \
 734         call sys_##name; \
 735         addl $4,%esp; \
 736         CFI_ADJUST_CFA_OFFSET -4; \
 737         ret; \
 738         CFI_ENDPROC; \
 739 ENDPROC(ptregs_##name)
 740
 741 PTREGSCALL1(iopl)
 742 PTREGSCALL2(sigaltstack)
 743 PTREGSCALL0(sigreturn)
 744 PTREGSCALL0(rt_sigreturn)
 745 PTREGSCALL2(vm86)
 746 PTREGSCALL1(vm86old)
 747
 748 .macro FIXUP_ESPFIX_STACK
 749 /*
 750  * Switch back for ESPFIX stack to the normal zerobased stack
 751  *
 752  * We can't call C functions using the ESPFIX stack. This code reads
 753  * the high word of the segment base from the GDT and swiches to the
 754  * normal stack and adjusts ESP with the matching offset.
 755  */
 756         /* fixup the stack */
 757         mov GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
 758         mov GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
 759         shl $16, %eax
 760         addl %esp, %eax                 /* the adjusted stack pointer */
 761         pushl_cfi $__KERNEL_DS
 762         pushl_cfi %eax
 763         lss (%esp), %esp                /* switch to the normal stack segment */
 764         CFI_ADJUST_CFA_OFFSET -8
 765 .endm
 766 .macro UNWIND_ESPFIX_STACK
 767         movl %ss, %eax
 768         /* see if on espfix stack */
 769         cmpw $__ESPFIX_SS, %ax
 770         jne 27f
 771         movl $__KERNEL_DS, %eax
 772         movl %eax, %ds
 773         movl %eax, %es
 774         /* switch to normal stack */
 775         FIXUP_ESPFIX_STACK
 776 27:
 777 .endm
 778
 779 /*
 780  * Build the entry stubs and pointer table with some assembler magic.
 781  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 782  * single cache line on all modern x86 implementations.
 783  */
 784 .section .init.rodata,"a"
 785 ENTRY(interrupt)
 786 .section .entry.text, "ax"
 787         .p2align 5
 788         .p2align CONFIG_X86_L1_CACHE_SHIFT
 789 ENTRY(irq_entries_start)
 790         RING0_INT_FRAME
 791 vector=FIRST_EXTERNAL_VECTOR
 792 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 793         .balign 32
 794   .rept 7
 795     .if vector < NR_VECTORS
 796       .if vector <> FIRST_EXTERNAL_VECTOR
 797         CFI_ADJUST_CFA_OFFSET -4
 798       .endif
 799 1:      pushl_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 800       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 801         jmp 2f
 802       .endif
 803       .previous
 804         .long 1b
 805       .section .entry.text, "ax"
 806 vector=vector+1
 807     .endif
 808   .endr
 809 2:      jmp common_interrupt
 810 .endr
 811 END(irq_entries_start)
 812
 813 .previous
 814 END(interrupt)
 815 .previous
 816
 817 /*
 818  * the CPU automatically disables interrupts when executing an IRQ vector,
 819  * so IRQ-flags tracing has to follow that:
 820  */
 821         .p2align CONFIG_X86_L1_CACHE_SHIFT
 822 common_interrupt:
 823         ASM_CLAC
 824         addl $-0x80,(%esp)      /* Adjust vector into the [-256,-1] range */
 825         SAVE_ALL
 826         TRACE_IRQS_OFF
 827         movl %esp,%eax
 828         call do_IRQ
 829         jmp ret_from_intr
 830 ENDPROC(common_interrupt)
 831         CFI_ENDPROC
 832
 833 /*
 834  *  Irq entries should be protected against kprobes
 835  */
 836         .pushsection .kprobes.text, "ax"
 837 #define BUILD_INTERRUPT3(name, nr, fn)  \
 838 ENTRY(name)                             \
 839         RING0_INT_FRAME;                \
 840         ASM_CLAC;                       \
 841         pushl_cfi $~(nr);               \
 842         SAVE_ALL;                       \
 843         TRACE_IRQS_OFF                  \
 844         movl %esp,%eax;                 \
 845         call fn;                        \
 846         jmp ret_from_intr;              \
 847         CFI_ENDPROC;                    \
 848 ENDPROC(name)
 849
 850 #define BUILD_INTERRUPT(name, nr)       BUILD_INTERRUPT3(name, nr, smp_##name)
 851
 852 /* The include is where all of the SMP etc. interrupts come from */
 853 #include <asm/entry_arch.h>
 854
 855 ENTRY(coprocessor_error)
 856         RING0_INT_FRAME
 857         ASM_CLAC
 858         pushl_cfi $0
 859         pushl_cfi $do_coprocessor_error
 860         jmp error_code
 861         CFI_ENDPROC
 862 END(coprocessor_error)
 863
 864 ENTRY(simd_coprocessor_error)
 865         RING0_INT_FRAME
 866         ASM_CLAC
 867         pushl_cfi $0
 868 #ifdef CONFIG_X86_INVD_BUG
 869         /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
 870 661:    pushl_cfi $do_general_protection
 871 662:
 872 .section .altinstructions,"a"
 873         altinstruction_entry 661b, 663f, X86_FEATURE_XMM, 662b-661b, 664f-663f
 874 .previous
 875 .section .altinstr_replacement,"ax"
 876 663:    pushl $do_simd_coprocessor_error
 877 664:
 878 .previous
 879 #else
 880         pushl_cfi $do_simd_coprocessor_error
 881 #endif
 882         jmp error_code
 883         CFI_ENDPROC
 884 END(simd_coprocessor_error)
 885
 886 ENTRY(device_not_available)
 887         RING0_INT_FRAME
 888         ASM_CLAC
 889         pushl_cfi $-1                   # mark this as an int
 890         pushl_cfi $do_device_not_available
 891         jmp error_code
 892         CFI_ENDPROC
 893 END(device_not_available)
 894
 895 #ifdef CONFIG_PARAVIRT
 896 ENTRY(native_iret)
 897         iret
 898         _ASM_EXTABLE(native_iret, iret_exc)
 899 END(native_iret)
 900
 901 ENTRY(native_irq_enable_sysexit)
 902         sti
 903         sysexit
 904 END(native_irq_enable_sysexit)
 905 #endif
 906
 907 ENTRY(overflow)
 908         RING0_INT_FRAME
 909         ASM_CLAC
 910         pushl_cfi $0
 911         pushl_cfi $do_overflow
 912         jmp error_code
 913         CFI_ENDPROC
 914 END(overflow)
 915
 916 ENTRY(bounds)
 917         RING0_INT_FRAME
 918         ASM_CLAC
 919         pushl_cfi $0
 920         pushl_cfi $do_bounds
 921         jmp error_code
 922         CFI_ENDPROC
 923 END(bounds)
 924
 925 ENTRY(invalid_op)
 926         RING0_INT_FRAME
 927         ASM_CLAC
 928         pushl_cfi $0
 929         pushl_cfi $do_invalid_op
 930         jmp error_code
 931         CFI_ENDPROC
 932 END(invalid_op)
 933
 934 ENTRY(coprocessor_segment_overrun)
 935         RING0_INT_FRAME
 936         ASM_CLAC
 937         pushl_cfi $0
 938         pushl_cfi $do_coprocessor_segment_overrun
 939         jmp error_code
 940         CFI_ENDPROC
 941 END(coprocessor_segment_overrun)
 942
 943 ENTRY(invalid_TSS)
 944         RING0_EC_FRAME
 945         ASM_CLAC
 946         pushl_cfi $do_invalid_TSS
 947         jmp error_code
 948         CFI_ENDPROC
 949 END(invalid_TSS)
 950
 951 ENTRY(segment_not_present)
 952         RING0_EC_FRAME
 953         ASM_CLAC
 954         pushl_cfi $do_segment_not_present
 955         jmp error_code
 956         CFI_ENDPROC
 957 END(segment_not_present)
 958
 959 ENTRY(stack_segment)
 960         RING0_EC_FRAME
 961         ASM_CLAC
 962         pushl_cfi $do_stack_segment
 963         jmp error_code
 964         CFI_ENDPROC
 965 END(stack_segment)
 966
 967 ENTRY(alignment_check)
 968         RING0_EC_FRAME
 969         ASM_CLAC
 970         pushl_cfi $do_alignment_check
 971         jmp error_code
 972         CFI_ENDPROC
 973 END(alignment_check)
 974
 975 ENTRY(divide_error)
 976         RING0_INT_FRAME
 977         ASM_CLAC
 978         pushl_cfi $0                    # no error code
 979         pushl_cfi $do_divide_error
 980         jmp error_code
 981         CFI_ENDPROC
 982 END(divide_error)
 983
 984 #ifdef CONFIG_X86_MCE
 985 ENTRY(machine_check)
 986         RING0_INT_FRAME
 987         ASM_CLAC
 988         pushl_cfi $0
 989         pushl_cfi machine_check_vector
 990         jmp error_code
 991         CFI_ENDPROC
 992 END(machine_check)
 993 #endif
 994
 995 ENTRY(spurious_interrupt_bug)
 996         RING0_INT_FRAME
 997         ASM_CLAC
 998         pushl_cfi $0
 999         pushl_cfi $do_spurious_interrupt_bug
1000         jmp error_code
1001         CFI_ENDPROC
1002 END(spurious_interrupt_bug)
1003 /*
1004  * End of kprobes section
1005  */
1006         .popsection
1007
1008 #ifdef CONFIG_XEN
1009 /* Xen doesn't set %esp to be precisely what the normal sysenter
1010    entrypoint expects, so fix it up before using the normal path. */
1011 ENTRY(xen_sysenter_target)
1012         RING0_INT_FRAME
1013         addl $5*4, %esp         /* remove xen-provided frame */
1014         CFI_ADJUST_CFA_OFFSET -5*4
1015         jmp sysenter_past_esp
1016         CFI_ENDPROC
1017
1018 ENTRY(xen_hypervisor_callback)
1019         CFI_STARTPROC
1020         pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1021         SAVE_ALL
1022         TRACE_IRQS_OFF
1023
1024         /* Check to see if we got the event in the critical
1025            region in xen_iret_direct, after we've reenabled
1026            events and checked for pending events.  This simulates
1027            iret instruction's behaviour where it delivers a
1028            pending interrupt when enabling interrupts. */
1029         movl PT_EIP(%esp),%eax
1030         cmpl $xen_iret_start_crit,%eax
1031         jb   1f
1032         cmpl $xen_iret_end_crit,%eax
1033         jae  1f
1034
1035         jmp  xen_iret_crit_fixup
1036
1037 ENTRY(xen_do_upcall)
1038 1:      mov %esp, %eax
1039         call xen_evtchn_do_upcall
1040         jmp  ret_from_intr
1041         CFI_ENDPROC
1042 ENDPROC(xen_hypervisor_callback)
1043
1044 # Hypervisor uses this for application faults while it executes.
1045 # We get here for two reasons:
1046 #  1. Fault while reloading DS, ES, FS or GS
1047 #  2. Fault while executing IRET
1048 # Category 1 we fix up by reattempting the load, and zeroing the segment
1049 # register if the load fails.
1050 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
1051 # normal Linux return path in this case because if we use the IRET hypercall
1052 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1053 # We distinguish between categories by maintaining a status value in EAX.
1054 ENTRY(xen_failsafe_callback)
1055         CFI_STARTPROC
1056         pushl_cfi %eax
1057         movl $1,%eax
1058 1:      mov 4(%esp),%ds
1059 2:      mov 8(%esp),%es
1060 3:      mov 12(%esp),%fs
1061 4:      mov 16(%esp),%gs
1062         /* EAX == 0 => Category 1 (Bad segment)
1063            EAX != 0 => Category 2 (Bad IRET) */
1064         testl %eax,%eax
1065         popl_cfi %eax
1066         lea 16(%esp),%esp
1067         CFI_ADJUST_CFA_OFFSET -16
1068         jz 5f
1069         addl $16,%esp
1070         jmp iret_exc
1071 5:      pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1072         SAVE_ALL
1073         jmp ret_from_exception
1074         CFI_ENDPROC
1075
1076 .section .fixup,"ax"
1077 6:      xorl %eax,%eax
1078         movl %eax,4(%esp)
1079         jmp 1b
1080 7:      xorl %eax,%eax
1081         movl %eax,8(%esp)
1082         jmp 2b
1083 8:      xorl %eax,%eax
1084         movl %eax,12(%esp)
1085         jmp 3b
1086 9:      xorl %eax,%eax
1087         movl %eax,16(%esp)
1088         jmp 4b
1089 .previous
1090         _ASM_EXTABLE(1b,6b)
1091         _ASM_EXTABLE(2b,7b)
1092         _ASM_EXTABLE(3b,8b)
1093         _ASM_EXTABLE(4b,9b)
1094 ENDPROC(xen_failsafe_callback)
1095
1096 BUILD_INTERRUPT3(xen_hvm_callback_vector, XEN_HVM_EVTCHN_CALLBACK,
1097                 xen_evtchn_do_upcall)
1098
1099 #endif  /* CONFIG_XEN */
1100
1101 #ifdef CONFIG_FUNCTION_TRACER
1102 #ifdef CONFIG_DYNAMIC_FTRACE
1103
1104 ENTRY(mcount)
1105         ret
1106 END(mcount)
1107
1108 ENTRY(ftrace_caller)
1109         cmpl $0, function_trace_stop
1110         jne  ftrace_stub
1111
1112         pushl %eax
1113         pushl %ecx
1114         pushl %edx
1115         pushl $0        /* Pass NULL as regs pointer */
1116         movl 4*4(%esp), %eax
1117         movl 0x4(%ebp), %edx
1118         leal function_trace_op, %ecx
1119         subl $MCOUNT_INSN_SIZE, %eax
1120
1121 .globl ftrace_call
1122 ftrace_call:
1123         call ftrace_stub
1124
1125         addl $4,%esp    /* skip NULL pointer */
1126         popl %edx
1127         popl %ecx
1128         popl %eax
1129 ftrace_ret:
1130 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1131 .globl ftrace_graph_call
1132 ftrace_graph_call:
1133         jmp ftrace_stub
1134 #endif
1135
1136 .globl ftrace_stub
1137 ftrace_stub:
1138         ret
1139 END(ftrace_caller)
1140
1141 ENTRY(ftrace_regs_caller)
1142         pushf   /* push flags before compare (in cs location) */
1143         cmpl $0, function_trace_stop
1144         jne ftrace_restore_flags
1145
1146         /*
1147          * i386 does not save SS and ESP when coming from kernel.
1148          * Instead, to get sp, &regs->sp is used (see ptrace.h).
1149          * Unfortunately, that means eflags must be at the same location
1150          * as the current return ip is. We move the return ip into the
1151          * ip location, and move flags into the return ip location.
1152          */
1153         pushl 4(%esp)   /* save return ip into ip slot */
1154
1155         pushl $0        /* Load 0 into orig_ax */
1156         pushl %gs
1157         pushl %fs
1158         pushl %es
1159         pushl %ds
1160         pushl %eax
1161         pushl %ebp
1162         pushl %edi
1163         pushl %esi
1164         pushl %edx
1165         pushl %ecx
1166         pushl %ebx
1167
1168         movl 13*4(%esp), %eax   /* Get the saved flags */
1169         movl %eax, 14*4(%esp)   /* Move saved flags into regs->flags location */
1170                                 /* clobbering return ip */
1171         movl $__KERNEL_CS,13*4(%esp)
1172
1173         movl 12*4(%esp), %eax   /* Load ip (1st parameter) */
1174         subl $MCOUNT_INSN_SIZE, %eax    /* Adjust ip */
1175         movl 0x4(%ebp), %edx    /* Load parent ip (2nd parameter) */
1176         leal function_trace_op, %ecx /* Save ftrace_pos in 3rd parameter */
1177         pushl %esp              /* Save pt_regs as 4th parameter */
1178
1179 GLOBAL(ftrace_regs_call)
1180         call ftrace_stub
1181
1182         addl $4, %esp           /* Skip pt_regs */
1183         movl 14*4(%esp), %eax   /* Move flags back into cs */
1184         movl %eax, 13*4(%esp)   /* Needed to keep addl from modifying flags */
1185         movl 12*4(%esp), %eax   /* Get return ip from regs->ip */
1186         movl %eax, 14*4(%esp)   /* Put return ip back for ret */
1187
1188         popl %ebx
1189         popl %ecx
1190         popl %edx
1191         popl %esi
1192         popl %edi
1193         popl %ebp
1194         popl %eax
1195         popl %ds
1196         popl %es
1197         popl %fs
1198         popl %gs
1199         addl $8, %esp           /* Skip orig_ax and ip */
1200         popf                    /* Pop flags at end (no addl to corrupt flags) */
1201         jmp ftrace_ret
1202
1203 ftrace_restore_flags:
1204         popf
1205         jmp  ftrace_stub
1206 #else /* ! CONFIG_DYNAMIC_FTRACE */
1207
1208 ENTRY(mcount)
1209         cmpl $0, function_trace_stop
1210         jne  ftrace_stub
1211
1212         cmpl $ftrace_stub, ftrace_trace_function
1213         jnz trace
1214 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1215         cmpl $ftrace_stub, ftrace_graph_return
1216         jnz ftrace_graph_caller
1217
1218         cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1219         jnz ftrace_graph_caller
1220 #endif
1221 .globl ftrace_stub
1222 ftrace_stub:
1223         ret
1224
1225         /* taken from glibc */
1226 trace:
1227         pushl %eax
1228         pushl %ecx
1229         pushl %edx
1230         movl 0xc(%esp), %eax
1231         movl 0x4(%ebp), %edx
1232         subl $MCOUNT_INSN_SIZE, %eax
1233
1234         call *ftrace_trace_function
1235
1236         popl %edx
1237         popl %ecx
1238         popl %eax
1239         jmp ftrace_stub
1240 END(mcount)
1241 #endif /* CONFIG_DYNAMIC_FTRACE */
1242 #endif /* CONFIG_FUNCTION_TRACER */
1243
1244 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1245 ENTRY(ftrace_graph_caller)
1246         pushl %eax
1247         pushl %ecx
1248         pushl %edx
1249         movl 0xc(%esp), %edx
1250         lea 0x4(%ebp), %eax
1251         movl (%ebp), %ecx
1252         subl $MCOUNT_INSN_SIZE, %edx
1253         call prepare_ftrace_return
1254         popl %edx
1255         popl %ecx
1256         popl %eax
1257         ret
1258 END(ftrace_graph_caller)
1259
1260 .globl return_to_handler
1261 return_to_handler:
1262         pushl %eax
1263         pushl %edx
1264         movl %ebp, %eax
1265         call ftrace_return_to_handler
1266         movl %eax, %ecx
1267         popl %edx
1268         popl %eax
1269         jmp *%ecx
1270 #endif
1271
1272 /*
1273  * Some functions should be protected against kprobes
1274  */
1275         .pushsection .kprobes.text, "ax"
1276
1277 ENTRY(page_fault)
1278         RING0_EC_FRAME
1279         ASM_CLAC
1280         pushl_cfi $do_page_fault
1281         ALIGN
1282 error_code:
1283         /* the function address is in %gs's slot on the stack */
1284         pushl_cfi %fs
1285         /*CFI_REL_OFFSET fs, 0*/
1286         pushl_cfi %es
1287         /*CFI_REL_OFFSET es, 0*/
1288         pushl_cfi %ds
1289         /*CFI_REL_OFFSET ds, 0*/
1290         pushl_cfi %eax
1291         CFI_REL_OFFSET eax, 0
1292         pushl_cfi %ebp
1293         CFI_REL_OFFSET ebp, 0
1294         pushl_cfi %edi
1295         CFI_REL_OFFSET edi, 0
1296         pushl_cfi %esi
1297         CFI_REL_OFFSET esi, 0
1298         pushl_cfi %edx
1299         CFI_REL_OFFSET edx, 0
1300         pushl_cfi %ecx
1301         CFI_REL_OFFSET ecx, 0
1302         pushl_cfi %ebx
1303         CFI_REL_OFFSET ebx, 0
1304         cld
1305         movl $(__KERNEL_PERCPU), %ecx
1306         movl %ecx, %fs
1307         UNWIND_ESPFIX_STACK
1308         GS_TO_REG %ecx
1309         movl PT_GS(%esp), %edi          # get the function address
1310         movl PT_ORIG_EAX(%esp), %edx    # get the error code
1311         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
1312         REG_TO_PTGS %ecx
1313         SET_KERNEL_GS %ecx
1314         movl $(__USER_DS), %ecx
1315         movl %ecx, %ds
1316         movl %ecx, %es
1317         TRACE_IRQS_OFF
1318         movl %esp,%eax                  # pt_regs pointer
1319         call *%edi
1320         jmp ret_from_exception
1321         CFI_ENDPROC
1322 END(page_fault)
1323
1324 /*
1325  * Debug traps and NMI can happen at the one SYSENTER instruction
1326  * that sets up the real kernel stack. Check here, since we can't
1327  * allow the wrong stack to be used.
1328  *
1329  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1330  * already pushed 3 words if it hits on the sysenter instruction:
1331  * eflags, cs and eip.
1332  *
1333  * We just load the right stack, and push the three (known) values
1334  * by hand onto the new stack - while updating the return eip past
1335  * the instruction that would have done it for sysenter.
1336  */
1337 .macro FIX_STACK offset ok label
1338         cmpw $__KERNEL_CS, 4(%esp)
1339         jne \ok
1340 \label:
1341         movl TSS_sysenter_sp0 + \offset(%esp), %esp
1342         CFI_DEF_CFA esp, 0
1343         CFI_UNDEFINED eip
1344         pushfl_cfi
1345         pushl_cfi $__KERNEL_CS
1346         pushl_cfi $sysenter_past_esp
1347         CFI_REL_OFFSET eip, 0
1348 .endm
1349
1350 ENTRY(debug)
1351         RING0_INT_FRAME
1352         ASM_CLAC
1353         cmpl $ia32_sysenter_target,(%esp)
1354         jne debug_stack_correct
1355         FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1356 debug_stack_correct:
1357         pushl_cfi $-1                   # mark this as an int
1358         SAVE_ALL
1359         TRACE_IRQS_OFF
1360         xorl %edx,%edx                  # error code 0
1361         movl %esp,%eax                  # pt_regs pointer
1362         call do_debug
1363         jmp ret_from_exception
1364         CFI_ENDPROC
1365 END(debug)
1366
1367 /*
1368  * NMI is doubly nasty. It can happen _while_ we're handling
1369  * a debug fault, and the debug fault hasn't yet been able to
1370  * clear up the stack. So we first check whether we got  an
1371  * NMI on the sysenter entry path, but after that we need to
1372  * check whether we got an NMI on the debug path where the debug
1373  * fault happened on the sysenter path.
1374  */
1375 ENTRY(nmi)
1376         RING0_INT_FRAME
1377         ASM_CLAC
1378         pushl_cfi %eax
1379         movl %ss, %eax
1380         cmpw $__ESPFIX_SS, %ax
1381         popl_cfi %eax
1382         je nmi_espfix_stack
1383         cmpl $ia32_sysenter_target,(%esp)
1384         je nmi_stack_fixup
1385         pushl_cfi %eax
1386         movl %esp,%eax
1387         /* Do not access memory above the end of our stack page,
1388          * it might not exist.
1389          */
1390         andl $(THREAD_SIZE-1),%eax
1391         cmpl $(THREAD_SIZE-20),%eax
1392         popl_cfi %eax
1393         jae nmi_stack_correct
1394         cmpl $ia32_sysenter_target,12(%esp)
1395         je nmi_debug_stack_check
1396 nmi_stack_correct:
1397         /* We have a RING0_INT_FRAME here */
1398         pushl_cfi %eax
1399         SAVE_ALL
1400         xorl %edx,%edx          # zero error code
1401         movl %esp,%eax          # pt_regs pointer
1402         call do_nmi
1403         jmp restore_all_notrace
1404         CFI_ENDPROC
1405
1406 nmi_stack_fixup:
1407         RING0_INT_FRAME
1408         FIX_STACK 12, nmi_stack_correct, 1
1409         jmp nmi_stack_correct
1410
1411 nmi_debug_stack_check:
1412         /* We have a RING0_INT_FRAME here */
1413         cmpw $__KERNEL_CS,16(%esp)
1414         jne nmi_stack_correct
1415         cmpl $debug,(%esp)
1416         jb nmi_stack_correct
1417         cmpl $debug_esp_fix_insn,(%esp)
1418         ja nmi_stack_correct
1419         FIX_STACK 24, nmi_stack_correct, 1
1420         jmp nmi_stack_correct
1421
1422 nmi_espfix_stack:
1423         /* We have a RING0_INT_FRAME here.
1424          *
1425          * create the pointer to lss back
1426          */
1427         pushl_cfi %ss
1428         pushl_cfi %esp
1429         addl $4, (%esp)
1430         /* copy the iret frame of 12 bytes */
1431         .rept 3
1432         pushl_cfi 16(%esp)
1433         .endr
1434         pushl_cfi %eax
1435         SAVE_ALL
1436         FIXUP_ESPFIX_STACK              # %eax == %esp
1437         xorl %edx,%edx                  # zero error code
1438         call do_nmi
1439         RESTORE_REGS
1440         lss 12+4(%esp), %esp            # back to espfix stack
1441         CFI_ADJUST_CFA_OFFSET -24
1442         jmp irq_return
1443         CFI_ENDPROC
1444 END(nmi)
1445
1446 ENTRY(int3)
1447         RING0_INT_FRAME
1448         ASM_CLAC
1449         pushl_cfi $-1                   # mark this as an int
1450         SAVE_ALL
1451         TRACE_IRQS_OFF
1452         xorl %edx,%edx          # zero error code
1453         movl %esp,%eax          # pt_regs pointer
1454         call do_int3
1455         jmp ret_from_exception
1456         CFI_ENDPROC
1457 END(int3)
1458
1459 ENTRY(general_protection)
1460         RING0_EC_FRAME
1461         pushl_cfi $do_general_protection
1462         jmp error_code
1463         CFI_ENDPROC
1464 END(general_protection)
1465
1466 #ifdef CONFIG_KVM_GUEST
1467 ENTRY(async_page_fault)
1468         RING0_EC_FRAME
1469         ASM_CLAC
1470         pushl_cfi $do_async_page_fault
1471         jmp error_code
1472         CFI_ENDPROC
1473 END(async_page_fault)
1474 #endif
1475
1476 /*
1477  * End of kprobes section
1478  */
1479         .popsection