arch/x86/kernel/head_64.S

   1 /*
   2  *  linux/arch/x86_64/kernel/head.S -- start in 32bit and switch to 64bit
   3  *
   4  *  Copyright (C) 2000 Andrea Arcangeli <andrea@suse.de> SuSE
   5  *  Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
   6  *  Copyright (C) 2000 Karsten Keil <kkeil@suse.de>
   7  *  Copyright (C) 2001,2002 Andi Kleen <ak@suse.de>
   8  *  Copyright (C) 2005 Eric Biederman <ebiederm@xmission.com>
   9  */
  10
  11
  12 #include <linux/linkage.h>
  13 #include <linux/threads.h>
  14 #include <linux/init.h>
  15 #include <asm/desc.h>
  16 #include <asm/segment.h>
  17 #include <asm/pgtable.h>
  18 #include <asm/page.h>
  19 #include <asm/msr.h>
  20 #include <asm/cache.h>
  21 #include <asm/processor-flags.h>
  22 #include <asm/percpu.h>
  23
  24 #ifdef CONFIG_PARAVIRT
  25 #include <asm/asm-offsets.h>
  26 #include <asm/paravirt.h>
  27 #else
  28 #define GET_CR2_INTO_RCX movq %cr2, %rcx
  29 #endif
  30
  31 /* we are not able to switch in one step to the final KERNEL ADRESS SPACE
  32  * because we need identity-mapped pages.
  33  *
  34  */
  35
  36 #define pud_index(x)    (((x) >> PUD_SHIFT) & (PTRS_PER_PUD-1))
  37
  38 L4_PAGE_OFFSET = pgd_index(__PAGE_OFFSET)
  39 L3_PAGE_OFFSET = pud_index(__PAGE_OFFSET)
  40 L4_START_KERNEL = pgd_index(__START_KERNEL_map)
  41 L3_START_KERNEL = pud_index(__START_KERNEL_map)
  42
  43         .text
  44         .section .text.head
  45         .code64
  46         .globl startup_64
  47 startup_64:
  48
  49         /*
  50          * At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 1,
  51          * and someone has loaded an identity mapped page table
  52          * for us.  These identity mapped page tables map all of the
  53          * kernel pages and possibly all of memory.
  54          *
  55          * %esi holds a physical pointer to real_mode_data.
  56          *
  57          * We come here either directly from a 64bit bootloader, or from
  58          * arch/x86_64/boot/compressed/head.S.
  59          *
  60          * We only come here initially at boot nothing else comes here.
  61          *
  62          * Since we may be loaded at an address different from what we were
  63          * compiled to run at we first fixup the physical addresses in our page
  64          * tables and then reload them.
  65          */
  66
  67         /* Compute the delta between the address I am compiled to run at and the
  68          * address I am actually running at.
  69          */
  70         leaq    _text(%rip), %rbp
  71         subq    $_text - __START_KERNEL_map, %rbp
  72
  73         /* Is the address not 2M aligned? */
  74         movq    %rbp, %rax
  75         andl    $~PMD_PAGE_MASK, %eax
  76         testl   %eax, %eax
  77         jnz     bad_address
  78
  79         /* Is the address too large? */
  80         leaq    _text(%rip), %rdx
  81         movq    $PGDIR_SIZE, %rax
  82         cmpq    %rax, %rdx
  83         jae     bad_address
  84
  85         /* Fixup the physical addresses in the page table
  86          */
  87         addq    %rbp, init_level4_pgt + 0(%rip)
  88         addq    %rbp, init_level4_pgt + (L4_PAGE_OFFSET*8)(%rip)
  89         addq    %rbp, init_level4_pgt + (L4_START_KERNEL*8)(%rip)
  90
  91         addq    %rbp, level3_ident_pgt + 0(%rip)
  92
  93         addq    %rbp, level3_kernel_pgt + (510*8)(%rip)
  94         addq    %rbp, level3_kernel_pgt + (511*8)(%rip)
  95
  96         addq    %rbp, level2_fixmap_pgt + (506*8)(%rip)
  97
  98         /* Add an Identity mapping if I am above 1G */
  99         leaq    _text(%rip), %rdi
 100         andq    $PMD_PAGE_MASK, %rdi
 101
 102         movq    %rdi, %rax
 103         shrq    $PUD_SHIFT, %rax
 104         andq    $(PTRS_PER_PUD - 1), %rax
 105         jz      ident_complete
 106
 107         leaq    (level2_spare_pgt - __START_KERNEL_map + _KERNPG_TABLE)(%rbp), %rdx
 108         leaq    level3_ident_pgt(%rip), %rbx
 109         movq    %rdx, 0(%rbx, %rax, 8)
 110
 111         movq    %rdi, %rax
 112         shrq    $PMD_SHIFT, %rax
 113         andq    $(PTRS_PER_PMD - 1), %rax
 114         leaq    __PAGE_KERNEL_IDENT_LARGE_EXEC(%rdi), %rdx
 115         leaq    level2_spare_pgt(%rip), %rbx
 116         movq    %rdx, 0(%rbx, %rax, 8)
 117 ident_complete:
 118
 119         /*
 120          * Fixup the kernel text+data virtual addresses. Note that
 121          * we might write invalid pmds, when the kernel is relocated
 122          * cleanup_highmap() fixes this up along with the mappings
 123          * beyond _end.
 124          */
 125
 126         leaq    level2_kernel_pgt(%rip), %rdi
 127         leaq    4096(%rdi), %r8
 128         /* See if it is a valid page table entry */
 129 1:      testq   $1, 0(%rdi)
 130         jz      2f
 131         addq    %rbp, 0(%rdi)
 132         /* Go to the next page */
 133 2:      addq    $8, %rdi
 134         cmp     %r8, %rdi
 135         jne     1b
 136
 137         /* Fixup phys_base */
 138         addq    %rbp, phys_base(%rip)
 139
 140 #ifdef CONFIG_X86_TRAMPOLINE
 141         addq    %rbp, trampoline_level4_pgt + 0(%rip)
 142         addq    %rbp, trampoline_level4_pgt + (511*8)(%rip)
 143 #endif
 144
 145         /* Due to ENTRY(), sometimes the empty space gets filled with
 146          * zeros. Better take a jmp than relying on empty space being
 147          * filled with 0x90 (nop)
 148          */
 149         jmp secondary_startup_64
 150 ENTRY(secondary_startup_64)
 151         /*
 152          * At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 1,
 153          * and someone has loaded a mapped page table.
 154          *
 155          * %esi holds a physical pointer to real_mode_data.
 156          *
 157          * We come here either from startup_64 (using physical addresses)
 158          * or from trampoline.S (using virtual addresses).
 159          *
 160          * Using virtual addresses from trampoline.S removes the need
 161          * to have any identity mapped pages in the kernel page table
 162          * after the boot processor executes this code.
 163          */
 164
 165         /* Enable PAE mode and PGE */
 166         movl    $(X86_CR4_PAE | X86_CR4_PGE), %eax
 167         movq    %rax, %cr4
 168
 169         /* Setup early boot stage 4 level pagetables. */
 170         movq    $(init_level4_pgt - __START_KERNEL_map), %rax
 171         addq    phys_base(%rip), %rax
 172         movq    %rax, %cr3
 173
 174         /* Ensure I am executing from virtual addresses */
 175         movq    $1f, %rax
 176         jmp     *%rax
 177 1:
 178
 179         /* Check if nx is implemented */
 180         movl    $0x80000001, %eax
 181         cpuid
 182         movl    %edx,%edi
 183
 184         /* Setup EFER (Extended Feature Enable Register) */
 185         movl    $MSR_EFER, %ecx
 186         rdmsr
 187         btsl    $_EFER_SCE, %eax        /* Enable System Call */
 188         btl     $20,%edi                /* No Execute supported? */
 189         jnc     1f
 190         btsl    $_EFER_NX, %eax
 191 1:      wrmsr                           /* Make changes effective */
 192
 193         /* Setup cr0 */
 194 #define CR0_STATE       (X86_CR0_PE | X86_CR0_MP | X86_CR0_ET | \
 195                          X86_CR0_NE | X86_CR0_WP | X86_CR0_AM | \
 196                          X86_CR0_PG)
 197         movl    $CR0_STATE, %eax
 198         /* Make changes effective */
 199         movq    %rax, %cr0
 200
 201         /* Setup a boot time stack */
 202         movq stack_start(%rip),%rsp
 203
 204         /* zero EFLAGS after setting rsp */
 205         pushq $0
 206         popfq
 207
 208 #ifdef CONFIG_SMP
 209         /*
 210          * early_gdt_base should point to the gdt_page in static percpu init
 211          * data area.  Computing this requires two symbols - __per_cpu_load
 212          * and per_cpu__gdt_page.  As linker can't do no such relocation, do
 213          * it by hand.  As early_gdt_descr is manipulated by C code for
 214          * secondary CPUs, this should be done only once for the boot CPU
 215          * when early_gdt_descr_base contains zero.
 216          */
 217         movq    early_gdt_descr_base(%rip), %rax
 218         testq   %rax, %rax
 219         jnz     1f
 220         movq    $__per_cpu_load, %rax
 221         addq    $per_cpu__gdt_page, %rax
 222         movq    %rax, early_gdt_descr_base(%rip)
 223 1:
 224 #endif
 225         /*
 226          * We must switch to a new descriptor in kernel space for the GDT
 227          * because soon the kernel won't have access anymore to the userspace
 228          * addresses where we're currently running on. We have to do that here
 229          * because in 32bit we couldn't load a 64bit linear address.
 230          */
 231         lgdt    early_gdt_descr(%rip)
 232
 233         /* set up data segments. actually 0 would do too */
 234         movl $__KERNEL_DS,%eax
 235         movl %eax,%ds
 236         movl %eax,%ss
 237         movl %eax,%es
 238
 239         /*
 240          * We don't really need to load %fs or %gs, but load them anyway
 241          * to kill any stale realmode selectors.  This allows execution
 242          * under VT hardware.
 243          */
 244         movl %eax,%fs
 245         movl %eax,%gs
 246
 247         /* Set up %gs.
 248          *
 249          * On SMP, %gs should point to the per-cpu area.  For initial
 250          * boot, make %gs point to the init data section.  For a
 251          * secondary CPU,initial_gs should be set to its pda address
 252          * before the CPU runs this code.
 253          *
 254          * On UP, initial_gs points to PER_CPU_VAR(__pda) and doesn't
 255          * change.
 256          */
 257         movl    $MSR_GS_BASE,%ecx
 258         movq    initial_gs(%rip),%rax
 259         movq    %rax,%rdx
 260         shrq    $32,%rdx
 261         wrmsr
 262
 263         /* esi is pointer to real mode structure with interesting info.
 264            pass it to C */
 265         movl    %esi, %edi
 266
 267         /* Finally jump to run C code and to be on real kernel address
 268          * Since we are running on identity-mapped space we have to jump
 269          * to the full 64bit address, this is only possible as indirect
 270          * jump.  In addition we need to ensure %cs is set so we make this
 271          * a far return.
 272          */
 273         movq    initial_code(%rip),%rax
 274         pushq   $0              # fake return address to stop unwinder
 275         pushq   $__KERNEL_CS    # set correct cs
 276         pushq   %rax            # target address in negative space
 277         lretq
 278
 279         /* SMP bootup changes these two */
 280         __REFDATA
 281         .align  8
 282         ENTRY(initial_code)
 283         .quad   x86_64_start_kernel
 284         ENTRY(initial_gs)
 285 #ifdef CONFIG_SMP
 286         .quad   __per_cpu_load
 287 #else
 288         .quad   PER_CPU_VAR(__pda)
 289 #endif
 290         __FINITDATA
 291
 292         ENTRY(stack_start)
 293         .quad  init_thread_union+THREAD_SIZE-8
 294         .word  0
 295
 296 bad_address:
 297         jmp bad_address
 298
 299         .section ".init.text","ax"
 300 #ifdef CONFIG_EARLY_PRINTK
 301         .globl early_idt_handlers
 302 early_idt_handlers:
 303         i = 0
 304         .rept NUM_EXCEPTION_VECTORS
 305         movl $i, %esi
 306         jmp early_idt_handler
 307         i = i + 1
 308         .endr
 309 #endif
 310
 311 ENTRY(early_idt_handler)
 312 #ifdef CONFIG_EARLY_PRINTK
 313         cmpl $2,early_recursion_flag(%rip)
 314         jz  1f
 315         incl early_recursion_flag(%rip)
 316         GET_CR2_INTO_RCX
 317         movq %rcx,%r9
 318         xorl %r8d,%r8d          # zero for error code
 319         movl %esi,%ecx          # get vector number
 320         # Test %ecx against mask of vectors that push error code.
 321         cmpl $31,%ecx
 322         ja 0f
 323         movl $1,%eax
 324         salq %cl,%rax
 325         testl $0x27d00,%eax
 326         je 0f
 327         popq %r8                # get error code
 328 0:      movq 0(%rsp),%rcx       # get ip
 329         movq 8(%rsp),%rdx       # get cs
 330         xorl %eax,%eax
 331         leaq early_idt_msg(%rip),%rdi
 332         call early_printk
 333         cmpl $2,early_recursion_flag(%rip)
 334         jz  1f
 335         call dump_stack
 336 #ifdef CONFIG_KALLSYMS
 337         leaq early_idt_ripmsg(%rip),%rdi
 338         movq 0(%rsp),%rsi       # get rip again
 339         call __print_symbol
 340 #endif
 341 #endif /* EARLY_PRINTK */
 342 1:      hlt
 343         jmp 1b
 344
 345 #ifdef CONFIG_EARLY_PRINTK
 346 early_recursion_flag:
 347         .long 0
 348
 349 early_idt_msg:
 350         .asciz "PANIC: early exception %02lx rip %lx:%lx error %lx cr2 %lx\n"
 351 early_idt_ripmsg:
 352         .asciz "RIP %s\n"
 353 #endif /* CONFIG_EARLY_PRINTK */
 354         .previous
 355
 356 .balign PAGE_SIZE
 357
 358 #define NEXT_PAGE(name) \
 359         .balign PAGE_SIZE; \
 360 ENTRY(name)
 361
 362 /* Automate the creation of 1 to 1 mapping pmd entries */
 363 #define PMDS(START, PERM, COUNT)                        \
 364         i = 0 ;                                         \
 365         .rept (COUNT) ;                                 \
 366         .quad   (START) + (i << PMD_SHIFT) + (PERM) ;   \
 367         i = i + 1 ;                                     \
 368         .endr
 369
 370         /*
 371          * This default setting generates an ident mapping at address 0x100000
 372          * and a mapping for the kernel that precisely maps virtual address
 373          * 0xffffffff80000000 to physical address 0x000000. (always using
 374          * 2Mbyte large pages provided by PAE mode)
 375          */
 376 NEXT_PAGE(init_level4_pgt)
 377         .quad   level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
 378         .org    init_level4_pgt + L4_PAGE_OFFSET*8, 0
 379         .quad   level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
 380         .org    init_level4_pgt + L4_START_KERNEL*8, 0
 381         /* (2^48-(2*1024*1024*1024))/(2^39) = 511 */
 382         .quad   level3_kernel_pgt - __START_KERNEL_map + _PAGE_TABLE
 383
 384 NEXT_PAGE(level3_ident_pgt)
 385         .quad   level2_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
 386         .fill   511,8,0
 387
 388 NEXT_PAGE(level3_kernel_pgt)
 389         .fill   L3_START_KERNEL,8,0
 390         /* (2^48-(2*1024*1024*1024)-((2^39)*511))/(2^30) = 510 */
 391         .quad   level2_kernel_pgt - __START_KERNEL_map + _KERNPG_TABLE
 392         .quad   level2_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE
 393
 394 NEXT_PAGE(level2_fixmap_pgt)
 395         .fill   506,8,0
 396         .quad   level1_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE
 397         /* 8MB reserved for vsyscalls + a 2MB hole = 4 + 1 entries */
 398         .fill   5,8,0
 399
 400 NEXT_PAGE(level1_fixmap_pgt)
 401         .fill   512,8,0
 402
 403 NEXT_PAGE(level2_ident_pgt)
 404         /* Since I easily can, map the first 1G.
 405          * Don't set NX because code runs from these pages.
 406          */
 407         PMDS(0, __PAGE_KERNEL_IDENT_LARGE_EXEC, PTRS_PER_PMD)
 408
 409 NEXT_PAGE(level2_kernel_pgt)
 410         /*
 411          * 512 MB kernel mapping. We spend a full page on this pagetable
 412          * anyway.
 413          *
 414          * The kernel code+data+bss must not be bigger than that.
 415          *
 416          * (NOTE: at +512MB starts the module area, see MODULES_VADDR.
 417          *  If you want to increase this then increase MODULES_VADDR
 418          *  too.)
 419          */
 420         PMDS(0, __PAGE_KERNEL_LARGE_EXEC,
 421                 KERNEL_IMAGE_SIZE/PMD_SIZE)
 422
 423 NEXT_PAGE(level2_spare_pgt)
 424         .fill   512, 8, 0
 425
 426 #undef PMDS
 427 #undef NEXT_PAGE
 428
 429         .data
 430         .align 16
 431         .globl early_gdt_descr
 432 early_gdt_descr:
 433         .word   GDT_ENTRIES*8-1
 434 #ifdef CONFIG_SMP
 435 early_gdt_descr_base:
 436         .quad   0x0000000000000000
 437 #else
 438         .quad   per_cpu__gdt_page
 439 #endif
 440
 441 ENTRY(phys_base)
 442         /* This must match the first entry in level2_kernel_pgt */
 443         .quad   0x0000000000000000
 444
 445 #include "../../x86/xen/xen-head.S"
 446
 447         .section .bss, "aw", @nobits
 448         .align L1_CACHE_BYTES
 449 ENTRY(idt_table)
 450         .skip 256 * 16
 451
 452         .section .bss.page_aligned, "aw", @nobits
 453         .align PAGE_SIZE
 454 ENTRY(empty_zero_page)
 455         .skip PAGE_SIZE