m4/openvswitch.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl Checks for --enable-coverage and updates CFLAGS and LDFLAGS appropriately.
  18 AC_DEFUN([OVS_CHECK_COVERAGE],
  19   [AC_REQUIRE([AC_PROG_CC])
  20    AC_ARG_ENABLE(
  21      [coverage],
  22      [AC_HELP_STRING([--enable-coverage],
  23                      [Enable gcov coverage tool.])],
  24      [case "${enableval}" in
  25         (yes) coverage=true ;;
  26         (no)  coverage=false ;;
  27         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-coverage]) ;;
  28       esac],
  29      [coverage=false])
  30    if $coverage; then
  31      CFLAGS="$CFLAGS -O0 --coverage"
  32      LDFLAGS="$LDFLAGS --coverage"
  33    fi])
  34
  35 dnl Checks for --enable-ndebug and defines NDEBUG if it is specified.
  36 AC_DEFUN([OVS_CHECK_NDEBUG],
  37   [AC_ARG_ENABLE(
  38      [ndebug],
  39      [AC_HELP_STRING([--enable-ndebug],
  40                      [Disable debugging features for max performance])],
  41      [case "${enableval}" in
  42         (yes) ndebug=true ;;
  43         (no)  ndebug=false ;;
  44         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-ndebug]) ;;
  45       esac],
  46      [ndebug=false])
  47    AM_CONDITIONAL([NDEBUG], [test x$ndebug = xtrue])])
  48
  49 dnl Checks for ESX.
  50 AC_DEFUN([OVS_CHECK_ESX],
  51   [AC_CHECK_HEADER([vmware.h],
  52                    [ESX=yes],
  53                    [ESX=no])
  54    AM_CONDITIONAL([ESX], [test "$ESX" = yes])
  55    if test "$ESX" = yes; then
  56       AC_DEFINE([ESX], [1], [Define to 1 if building on ESX.])
  57    fi])
  58
  59 dnl Checks for WINDOWS.
  60 AC_DEFUN([OVS_CHECK_WIN32],
  61   [AC_CHECK_HEADER([windows.h],
  62                    [WIN32=yes],
  63                    [WIN32=no])
  64    AM_CONDITIONAL([WIN32], [test "$WIN32" = yes])
  65    if test "$WIN32" = yes; then
  66       AC_DEFINE([WIN32], [1], [Define to 1 if building on WIN32.])
  67    fi])
  68
  69 dnl Checks for Netlink support.
  70 AC_DEFUN([OVS_CHECK_NETLINK],
  71   [AC_CHECK_HEADER([linux/netlink.h],
  72                    [HAVE_NETLINK=yes],
  73                    [HAVE_NETLINK=no],
  74                    [#include <sys/socket.h>
  75    #include <linux/types.h>
  76    ])
  77    AM_CONDITIONAL([HAVE_NETLINK], [test "$HAVE_NETLINK" = yes])
  78    if test "$HAVE_NETLINK" = yes; then
  79       AC_DEFINE([HAVE_NETLINK], [1],
  80                 [Define to 1 if Netlink protocol is available.])
  81    fi])
  82
  83 dnl Checks for OpenSSL.
  84 AC_DEFUN([OVS_CHECK_OPENSSL],
  85   [AC_ARG_ENABLE(
  86      [ssl],
  87      [AC_HELP_STRING([--disable-ssl], [Disable OpenSSL support])],
  88      [case "${enableval}" in
  89         (yes) ssl=true ;;
  90         (no)  ssl=false ;;
  91         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-ssl]) ;;
  92       esac],
  93      [ssl=check])
  94
  95    if test "$ssl" != false; then
  96        AX_CHECK_OPENSSL(
  97          [HAVE_OPENSSL=yes],
  98          [HAVE_OPENSSL=no
  99           if test "$ssl" = check; then
 100             AC_MSG_WARN([Cannot find openssl:
 101
 102 $SSL_PKG_ERRORS
 103
 104 OpenFlow connections over SSL will not be supported.
 105 (You may use --disable-ssl to suppress this warning.)])
 106           else
 107             AC_MSG_ERROR([Cannot find openssl (use --disable-ssl to configure without SSL support)])
 108           fi])
 109    else
 110        HAVE_OPENSSL=no
 111    fi
 112    AC_SUBST([HAVE_OPENSSL])
 113    AM_CONDITIONAL([HAVE_OPENSSL], [test "$HAVE_OPENSSL" = yes])
 114    if test "$HAVE_OPENSSL" = yes; then
 115       AC_DEFINE([HAVE_OPENSSL], [1], [Define to 1 if OpenSSL is installed.])
 116    fi])
 117
 118 dnl Checks for libraries needed by lib/socket-util.c.
 119 AC_DEFUN([OVS_CHECK_SOCKET_LIBS],
 120   [AC_CHECK_LIB([socket], [connect])
 121    AC_SEARCH_LIBS([gethostbyname], [resolv])])
 122
 123 dnl Checks for the directory in which to store the PKI.
 124 AC_DEFUN([OVS_CHECK_PKIDIR],
 125   [AC_ARG_WITH(
 126      [pkidir],
 127      AC_HELP_STRING([--with-pkidir=DIR],
 128                     [PKI hierarchy directory [[LOCALSTATEDIR/lib/openvswitch/pki]]]),
 129      [PKIDIR=$withval],
 130      [PKIDIR='${localstatedir}/lib/openvswitch/pki'])
 131    AC_SUBST([PKIDIR])])
 132
 133 dnl Checks for the directory in which to store pidfiles.
 134 AC_DEFUN([OVS_CHECK_RUNDIR],
 135   [AC_ARG_WITH(
 136      [rundir],
 137      AC_HELP_STRING([--with-rundir=DIR],
 138                     [directory used for pidfiles
 139                     [[LOCALSTATEDIR/run/openvswitch]]]),
 140      [RUNDIR=$withval],
 141      [RUNDIR='${localstatedir}/run/openvswitch'])
 142    AC_SUBST([RUNDIR])])
 143
 144 dnl Checks for the directory in which to store logs.
 145 AC_DEFUN([OVS_CHECK_LOGDIR],
 146   [AC_ARG_WITH(
 147      [logdir],
 148      AC_HELP_STRING([--with-logdir=DIR],
 149                     [directory used for logs [[LOCALSTATEDIR/log/PACKAGE]]]),
 150      [LOGDIR=$withval],
 151      [LOGDIR='${localstatedir}/log/${PACKAGE}'])
 152    AC_SUBST([LOGDIR])])
 153
 154 dnl Checks for the directory in which to store the Open vSwitch database.
 155 AC_DEFUN([OVS_CHECK_DBDIR],
 156   [AC_ARG_WITH(
 157      [dbdir],
 158      AC_HELP_STRING([--with-dbdir=DIR],
 159                     [directory used for conf.db [[SYSCONFDIR/PACKAGE]]]),
 160      [DBDIR=$withval],
 161      [DBDIR='${sysconfdir}/${PACKAGE}'])
 162    AC_SUBST([DBDIR])])
 163
 164 dnl Defines HAVE_BACKTRACE if backtrace() is found.
 165 AC_DEFUN([OVS_CHECK_BACKTRACE],
 166   [AC_SEARCH_LIBS([backtrace], [execinfo ubacktrace],
 167                   [AC_DEFINE([HAVE_BACKTRACE], [1],
 168                              [Define to 1 if you have backtrace(3).])])])
 169
 170 dnl Checks for __malloc_hook, etc., supported by glibc.
 171 AC_DEFUN([OVS_CHECK_MALLOC_HOOKS],
 172   [AC_CACHE_CHECK(
 173     [whether libc supports hooks for malloc and related functions],
 174     [ovs_cv_malloc_hooks],
 175     [AC_COMPILE_IFELSE(
 176       [AC_LANG_PROGRAM(
 177          [#include <malloc.h>
 178          ],
 179          [(void) __malloc_hook;
 180           (void) __realloc_hook;
 181           (void) __free_hook;])],
 182       [ovs_cv_malloc_hooks=yes],
 183       [ovs_cv_malloc_hooks=no])])
 184    if test $ovs_cv_malloc_hooks = yes; then
 185      AC_DEFINE([HAVE_MALLOC_HOOKS], [1],
 186                [Define to 1 if you have __malloc_hook, __realloc_hook, and
 187                 __free_hook in <malloc.h>.])
 188    fi])
 189
 190 dnl Checks for valgrind/valgrind.h.
 191 AC_DEFUN([OVS_CHECK_VALGRIND],
 192   [AC_CHECK_HEADERS([valgrind/valgrind.h])])
 193
 194 dnl Checks for Python 2.x, x >= 4.
 195 AC_DEFUN([OVS_CHECK_PYTHON],
 196   [AC_CACHE_CHECK(
 197      [for Python 2.x for x >= 4],
 198      [ovs_cv_python],
 199      [if test -n "$PYTHON"; then
 200         ovs_cv_python=$PYTHON
 201       else
 202         ovs_cv_python=no
 203         for binary in python python2.4 python2.5; do
 204           ovs_save_IFS=$IFS; IFS=$PATH_SEPARATOR
 205           for dir in $PATH; do
 206             IFS=$ovs_save_IFS
 207             test -z "$dir" && dir=.
 208             if test -x "$dir"/"$binary" && "$dir"/"$binary" -c 'import sys
 209 if sys.hexversion >= 0x02040000 and sys.hexversion < 0x03000000:
 210     sys.exit(0)
 211 else:
 212     sys.exit(1)'; then
 213               ovs_cv_python=$dir/$binary
 214               break 2
 215             fi
 216           done
 217         done
 218       fi])
 219    AC_SUBST([HAVE_PYTHON])
 220    AM_MISSING_PROG([PYTHON], [python])
 221    if test $ovs_cv_python != no; then
 222      PYTHON=$ovs_cv_python
 223      HAVE_PYTHON=yes
 224    else
 225      HAVE_PYTHON=no
 226    fi
 227    AM_CONDITIONAL([HAVE_PYTHON], [test "$HAVE_PYTHON" = yes])])
 228
 229 dnl Checks for dot.
 230 AC_DEFUN([OVS_CHECK_DOT],
 231   [AC_CACHE_CHECK(
 232     [for dot],
 233     [ovs_cv_dot],
 234     [dnl "dot" writes -V output to stderr:
 235      if (dot -V) 2>&1 | grep '^dot - [[gG]]raphviz version' >/dev/null 2>&1; then
 236        ovs_cv_dot=yes
 237      else
 238        ovs_cv_dot=no
 239      fi])
 240    AM_CONDITIONAL([HAVE_DOT], [test "$ovs_cv_dot" = yes])])
 241
 242 dnl Checks whether $PYTHON supports the module given as $1
 243 AC_DEFUN([OVS_CHECK_PYTHON_MODULE],
 244   [AC_REQUIRE([OVS_CHECK_PYTHON])
 245    AC_CACHE_CHECK(
 246      [for $1 Python module],
 247      [ovs_cv_py_[]AS_TR_SH([$1])],
 248      [ovs_cv_py_[]AS_TR_SH([$1])=no
 249       if test $HAVE_PYTHON = yes; then
 250         AS_ECHO(["running $PYTHON -c 'import $1
 251 import sys
 252 sys.exit(0)'..."]) >&AS_MESSAGE_LOG_FD 2>&1
 253         if $PYTHON -c 'import $1
 254 import sys
 255 sys.exit(0)' >&AS_MESSAGE_LOG_FD 2>&1; then
 256           ovs_cv_py_[]AS_TR_SH([$1])=yes
 257         fi
 258       fi])])
 259
 260 dnl Checks for missing python modules at build time
 261 AC_DEFUN([OVS_CHECK_PYTHON_COMPAT],
 262   [OVS_CHECK_PYTHON_MODULE([uuid])
 263    if test $ovs_cv_py_uuid = yes; then
 264      INCLUDE_PYTHON_COMPAT=no
 265    else
 266      INCLUDE_PYTHON_COMPAT=yes
 267    fi
 268    AC_MSG_CHECKING([whether to add python/compat to PYTHONPATH])
 269    AC_MSG_RESULT([$INCLUDE_PYTHON_COMPAT])
 270    AM_CONDITIONAL([INCLUDE_PYTHON_COMPAT], [test $INCLUDE_PYTHON_COMPAT = yes])])
 271
 272 dnl Checks for groff.
 273 AC_DEFUN([OVS_CHECK_GROFF],
 274   [AC_CACHE_CHECK(
 275     [for groff],
 276     [ovs_cv_groff],
 277     [if (groff -v) >/dev/null 2>&1; then
 278        ovs_cv_groff=yes
 279      else
 280        ovs_cv_groff=no
 281      fi])
 282    AM_CONDITIONAL([HAVE_GROFF], [test "$ovs_cv_groff" = yes])])
 283
 284 dnl Checks for thread-local storage support.
 285 dnl
 286 dnl Checks whether the compiler and linker support the C11
 287 dnl thread_local macro from <threads.h>, and if so defines
 288 dnl HAVE_THREAD_LOCAL.  If not, checks whether the compiler and linker
 289 dnl support the GCC __thread extension, and if so defines
 290 dnl HAVE___THREAD.
 291 AC_DEFUN([OVS_CHECK_TLS],
 292   [AC_CACHE_CHECK(
 293      [whether $CC has <threads.h> that supports thread_local],
 294      [ovs_cv_thread_local],
 295      [AC_LINK_IFELSE(
 296         [AC_LANG_PROGRAM([#include <threads.h>
 297 static thread_local int var;], [return var;])],
 298         [ovs_cv_thread_local=yes],
 299         [ovs_cv_thread_local=no])])
 300    if test $ovs_cv_thread_local = yes; then
 301      AC_DEFINE([HAVE_THREAD_LOCAL], [1],
 302                [Define to 1 if the C compiler and linker supports the C11
 303                 thread_local matcro defined in <threads.h>.])
 304    else
 305      AC_CACHE_CHECK(
 306        [whether $CC supports __thread],
 307        [ovs_cv___thread],
 308        [AC_LINK_IFELSE(
 309           [AC_LANG_PROGRAM([static __thread int var;], [return var;])],
 310           [ovs_cv___thread=yes],
 311           [ovs_cv___thread=no])])
 312      if test $ovs_cv___thread = yes; then
 313        AC_DEFINE([HAVE___THREAD], [1],
 314                  [Define to 1 if the C compiler and linker supports the
 315                   GCC __thread extenions.])
 316      fi
 317    fi])
 318
 319 dnl OVS_CHECK_ATOMIC_LIBS
 320 dnl
 321 dnl Check to see if -latomic is need for GCC atomic built-ins.
 322 AC_DEFUN([OVS_CHECK_ATOMIC_LIBS],
 323    [AC_SEARCH_LIBS([__atomic_load_8], [atomic])])
 324
 325 dnl OVS_CHECK_GCC4_ATOMICS
 326 dnl
 327 dnl Checks whether the compiler and linker support GCC 4.0+ atomic built-ins.
 328 dnl A compile-time only check is not enough because the compiler defers
 329 dnl unimplemented built-ins to libgcc, which sometimes also lacks
 330 dnl implementations.
 331 AC_DEFUN([OVS_CHECK_GCC4_ATOMICS],
 332   [AC_CACHE_CHECK(
 333      [whether $CC supports GCC 4.0+ atomic built-ins],
 334      [ovs_cv_gcc4_atomics],
 335      [AC_LINK_IFELSE(
 336         [AC_LANG_PROGRAM([[#include <stdlib.h>
 337
 338 #define ovs_assert(expr) if (!(expr)) abort();
 339 #define TEST_ATOMIC_TYPE(TYPE)                  \
 340     {                                           \
 341         TYPE x = 1;                             \
 342         TYPE orig;                              \
 343                                                 \
 344         __sync_synchronize();                   \
 345         ovs_assert(x == 1);                     \
 346                                                 \
 347         __sync_synchronize();                   \
 348         x = 3;                                  \
 349         __sync_synchronize();                   \
 350         ovs_assert(x == 3);                     \
 351                                                 \
 352         orig = __sync_fetch_and_add(&x, 1);     \
 353         ovs_assert(orig == 3);                  \
 354         __sync_synchronize();                   \
 355         ovs_assert(x == 4);                     \
 356                                                 \
 357         orig = __sync_fetch_and_sub(&x, 2);     \
 358         ovs_assert(orig == 4);                  \
 359         __sync_synchronize();                   \
 360         ovs_assert(x == 2);                     \
 361                                                 \
 362         orig = __sync_fetch_and_or(&x, 6);      \
 363         ovs_assert(orig == 2);                  \
 364         __sync_synchronize();                   \
 365         ovs_assert(x == 6);                     \
 366                                                 \
 367         orig = __sync_fetch_and_and(&x, 10);    \
 368         ovs_assert(orig == 6);                  \
 369         __sync_synchronize();                   \
 370         ovs_assert(x == 2);                     \
 371                                                 \
 372         orig = __sync_fetch_and_xor(&x, 10);    \
 373         ovs_assert(orig == 2);                  \
 374         __sync_synchronize();                   \
 375         ovs_assert(x == 8);                     \
 376     }]], [dnl
 377 TEST_ATOMIC_TYPE(char);
 378 TEST_ATOMIC_TYPE(unsigned char);
 379 TEST_ATOMIC_TYPE(signed char);
 380 TEST_ATOMIC_TYPE(short);
 381 TEST_ATOMIC_TYPE(unsigned short);
 382 TEST_ATOMIC_TYPE(int);
 383 TEST_ATOMIC_TYPE(unsigned int);
 384 TEST_ATOMIC_TYPE(long int);
 385 TEST_ATOMIC_TYPE(unsigned long int);
 386 TEST_ATOMIC_TYPE(long long int);
 387 TEST_ATOMIC_TYPE(unsigned long long int);
 388 ])],
 389         [ovs_cv_gcc4_atomics=yes],
 390         [ovs_cv_gcc4_atomics=no])])
 391    if test $ovs_cv_gcc4_atomics = yes; then
 392      AC_DEFINE([HAVE_GCC4_ATOMICS], [1],
 393                [Define to 1 if the C compiler and linker supports the GCC 4.0+
 394                 atomic built-ins.])
 395    fi])
 396
 397 dnl OVS_CHECK_ATOMIC_ALWAYS_LOCK_FREE(SIZE)
 398 dnl
 399 dnl Checks __atomic_always_lock_free(SIZE, 0)
 400 AC_DEFUN([OVS_CHECK_ATOMIC_ALWAYS_LOCK_FREE],
 401   [AC_CACHE_CHECK(
 402     [value of __atomic_always_lock_free($1)],
 403     [ovs_cv_atomic_always_lock_free_$1],
 404     [AC_COMPUTE_INT(
 405         [ovs_cv_atomic_always_lock_free_$1],
 406         [__atomic_always_lock_free($1, 0)],
 407         [],
 408         [ovs_cv_atomic_always_lock_free_$1=unsupported])])
 409    if test ovs_cv_atomic_always_lock_free_$1 != unsupported; then
 410      AC_DEFINE_UNQUOTED(
 411        [ATOMIC_ALWAYS_LOCK_FREE_$1B],
 412        [$ovs_cv_atomic_always_lock_free_$1],
 413        [If the C compiler is GCC 4.7 or later, define to the return value of
 414         __atomic_always_lock_free($1, 0).  If the C compiler is not GCC or is
 415         an older version of GCC, the value does not matter.])
 416    fi])
 417
 418 dnl OVS_CHECK_POSIX_AIO
 419 AC_DEFUN([OVS_CHECK_POSIX_AIO],
 420   [AC_SEARCH_LIBS([aio_write], [rt])
 421    AM_CONDITIONAL([HAVE_POSIX_AIO], [test "$ac_cv_search_aio_write" != no])])
 422
 423 dnl OVS_CHECK_INCLUDE_NEXT
 424 AC_DEFUN([OVS_CHECK_INCLUDE_NEXT],
 425   [AC_REQUIRE([gl_CHECK_NEXT_HEADERS])
 426    gl_CHECK_NEXT_HEADERS([$1])])