tests/kmod-macros.at

   1 # OVS_KMOD_VSWITCHD_START([vsctl-args], [vsctl-output], [=override])
   2 #
   3 # Creates a database and starts ovsdb-server, starts ovs-vswitchd
   4 # connected to that database, calls ovs-vsctl to create a bridge named
   5 # br0 with predictable settings, passing 'vsctl-args' as additional
   6 # commands to ovs-vsctl.  If 'vsctl-args' causes ovs-vsctl to provide
   7 # output (e.g. because it includes "create" commands) then 'vsctl-output'
   8 # specifies the expected output after filtering through uuidfilt.pl.
   9 #
  10 m4_define([OVS_KMOD_VSWITCHD_START],
  11   [ AT_CHECK([modprobe openvswitch])
  12     ON_EXIT([modprobe -r openvswitch])
  13    _OVS_VSWITCHD_START([])
  14    dnl Add bridges, ports, etc.
  15    AT_CHECK([ovs-vsctl -- add-br br0 -- set bridge br0 protocols=[[OpenFlow10,OpenFlow11,OpenFlow12,OpenFlow13,OpenFlow14,OpenFlow15]] fail-mode=secure -- $1 m4_if([$2], [], [], [| ${PERL} $srcdir/uuidfilt.pl])], [0], [$2])
  16 ])
  17 #
  18 #
  19 # OVS_KMOD_VSWITCHD_STOP([WHITELIST], [extra_cmds])
  20 #
  21 # Gracefully stops ovs-vswitchd and ovsdb-server, checking their log files
  22 # for messages with severity WARN or higher and signaling an error if any
  23 # is present.  The optional WHITELIST may contain shell-quoted "sed"
  24 # commands to delete any warnings that are actually expected, e.g.:
  25 #
  26 #   OVS_KMOD_VSWITCHD_STOP(["/expected error/d"])
  27 #
  28 # 'extra_cmds' are shell commands to be executed afte OVS_VSWITCHD_STOP() is
  29 # invoked. They can be used to perform additional cleanups such as name space
  30 # removal.
  31 m4_define([OVS_KMOD_VSWITCHD_STOP],
  32   [AT_CHECK([ovs-vsctl del-br br0])
  33    OVS_VSWITCHD_STOP([$1])
  34    AT_CHECK([:; $2])
  35    AT_CHECK([modprobe -r openvswitch])
  36   ])
  37
  38 # DEL_NAMESPACES(ns [, ns ... ])
  39 #
  40 # Delete namespaces from the running OS
  41 m4_define([DEL_NAMESPACES],
  42    [m4_foreach([ns], [$@],
  43                [ip netns del ns
  44 ])
  45    ]
  46 )
  47 #
  48 # ADD_NAMESPACES(ns [, ns ... ])
  49 #
  50 # Add new namespaces, if ns exists, the old one
  51 # will be remove before new ones are installed.
  52 m4_define([ADD_NAMESPACES],
  53    [m4_foreach([ns], [$@],
  54                [DEL_NAMESPACES(ns)
  55                 AT_CHECK([ip netns add ns])
  56                 ON_EXIT(DEL_NAMESPACES(ns))
  57                ])
  58    ]
  59 )
  60
  61 # ADD_VETH([port], [namespace], [ovs-br], [ip_addr])
  62 #
  63 # Add a pair of veth ports. 'port' will be added to name space 'namespace',
  64 # and "ovs-'port'" will be added to ovs bridge 'ovs-br'.
  65 #
  66 # The 'port' in 'namespace' will be brought up with static IP address
  67 # with 'ip_addr' in CIDR notation.
  68 #
  69 # The existing 'port' or 'ovs-port' will be removed before new ones are added.
  70 #
  71 m4_define([ADD_VETH],
  72     [ AT_CHECK([ip link add $1 type veth peer name ovs-$1])
  73       AT_CHECK([ip link set $1 netns $2])
  74       AT_CHECK([ovs-vsctl add-port $3 ovs-$1])
  75       AT_CHECK([ip link set dev ovs-$1 up])
  76       AT_CHECK([ip netns exec $2 ip addr add $4 dev $1])
  77       AT_CHECK([ip netns exec $2 ip link set dev $1 up])
  78     ]
  79 )