tests/system-common-macros.at

   1 # DEL_NAMESPACES(ns [, ns ... ])
   2 #
   3 # Delete namespaces from the running OS
   4 m4_define([DEL_NAMESPACES],
   5    [m4_foreach([ns], [$@],
   6                [ip netns del ns
   7 ])
   8    ]
   9 )
  10
  11 # ADD_NAMESPACES(ns [, ns ... ])
  12 #
  13 # Add new namespaces, if ns exists, the old one
  14 # will be remove before new ones are installed.
  15 m4_define([ADD_NAMESPACES],
  16    [m4_foreach([ns], [$@],
  17                [DEL_NAMESPACES(ns)
  18                 AT_CHECK([ip netns add ns])
  19                 ON_EXIT(DEL_NAMESPACES(ns))
  20                ])
  21    ]
  22 )
  23
  24 # NS_EXEC([namespace], [command])
  25 #
  26 # Execute 'command' in 'namespace'
  27 m4_define([NS_EXEC],
  28     [ip netns exec $1 sh << NS_EXEC_HEREDOC
  29 $2
  30 NS_EXEC_HEREDOC])
  31
  32 # NS_CHECK_EXEC([namespace], [command], other_params...)
  33 #
  34 # Wrapper for AT_CHECK that executes 'command' inside 'namespace'.
  35 # 'other_params' as passed as they are to AT_CHECK.
  36 m4_define([NS_CHECK_EXEC],
  37     [ AT_CHECK([NS_EXEC([$1], [$2])], m4_shift(m4_shift($@))) ]
  38 )
  39
  40 # ADD_VETH([port], [namespace], [ovs-br], [ip_addr])
  41 #
  42 # Add a pair of veth ports. 'port' will be added to name space 'namespace',
  43 # and "ovs-'port'" will be added to ovs bridge 'ovs-br'.
  44 #
  45 # The 'port' in 'namespace' will be brought up with static IP address
  46 # with 'ip_addr' in CIDR notation.
  47 #
  48 # The existing 'port' or 'ovs-port' will be removed before new ones are added.
  49 #
  50 m4_define([ADD_VETH],
  51     [ AT_CHECK([ip link add $1 type veth peer name ovs-$1])
  52       AT_CHECK([ip link set $1 netns $2])
  53       AT_CHECK([ip link set dev ovs-$1 up])
  54       AT_CHECK([ovs-vsctl add-port $3 ovs-$1])
  55       NS_CHECK_EXEC([$2], [ip addr add $4 dev $1])
  56       NS_CHECK_EXEC([$2], [ip link set dev $1 up])
  57       ON_EXIT([ip link del ovs-$1])
  58     ]
  59 )
  60
  61 # ADD_VLAN([port], [namespace], [vlan-id], [ip-addr])
  62 #
  63 # Add a VLAN device named 'port' within 'namespace'. It will be configured
  64 # with the ID 'vlan-id' and the address 'ip-addr'.
  65 m4_define([ADD_VLAN],
  66     [ NS_CHECK_EXEC([$2], [ip link add link $1 name $1.$3 type vlan id $3])
  67       NS_CHECK_EXEC([$2], [ip link set dev $1.$3 up])
  68       NS_CHECK_EXEC([$2], [ip addr add dev $1.$3 $4])
  69     ]
  70 )