arch/arm64/kernel/entry.S

   1 /*
   2  * Low-level exception handling code
   3  *
   4  * Copyright (C) 2012 ARM Ltd.
   5  * Authors:     Catalin Marinas <catalin.marinas@arm.com>
   6  *              Will Deacon <will.deacon@arm.com>
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19  */
  20
  21 #include <linux/init.h>
  22 #include <linux/linkage.h>
  23
  24 #include <asm/alternative.h>
  25 #include <asm/assembler.h>
  26 #include <asm/asm-offsets.h>
  27 #include <asm/cpufeature.h>
  28 #include <asm/errno.h>
  29 #include <asm/esr.h>
  30 #include <asm/irq.h>
  31 #include <asm/thread_info.h>
  32 #include <asm/unistd.h>
  33
  34 /*
  35  * Context tracking subsystem.  Used to instrument transitions
  36  * between user and kernel mode.
  37  */
  38         .macro ct_user_exit, syscall = 0
  39 #ifdef CONFIG_CONTEXT_TRACKING
  40         bl      context_tracking_user_exit
  41         .if \syscall == 1
  42         /*
  43          * Save/restore needed during syscalls.  Restore syscall arguments from
  44          * the values already saved on stack during kernel_entry.
  45          */
  46         ldp     x0, x1, [sp]
  47         ldp     x2, x3, [sp, #S_X2]
  48         ldp     x4, x5, [sp, #S_X4]
  49         ldp     x6, x7, [sp, #S_X6]
  50         .endif
  51 #endif
  52         .endm
  53
  54         .macro ct_user_enter
  55 #ifdef CONFIG_CONTEXT_TRACKING
  56         bl      context_tracking_user_enter
  57 #endif
  58         .endm
  59
  60 /*
  61  * Bad Abort numbers
  62  *-----------------
  63  */
  64 #define BAD_SYNC        0
  65 #define BAD_IRQ         1
  66 #define BAD_FIQ         2
  67 #define BAD_ERROR       3
  68
  69         .macro  kernel_entry, el, regsize = 64
  70         sub     sp, sp, #S_FRAME_SIZE
  71         .if     \regsize == 32
  72         mov     w0, w0                          // zero upper 32 bits of x0
  73         .endif
  74         stp     x0, x1, [sp, #16 * 0]
  75         stp     x2, x3, [sp, #16 * 1]
  76         stp     x4, x5, [sp, #16 * 2]
  77         stp     x6, x7, [sp, #16 * 3]
  78         stp     x8, x9, [sp, #16 * 4]
  79         stp     x10, x11, [sp, #16 * 5]
  80         stp     x12, x13, [sp, #16 * 6]
  81         stp     x14, x15, [sp, #16 * 7]
  82         stp     x16, x17, [sp, #16 * 8]
  83         stp     x18, x19, [sp, #16 * 9]
  84         stp     x20, x21, [sp, #16 * 10]
  85         stp     x22, x23, [sp, #16 * 11]
  86         stp     x24, x25, [sp, #16 * 12]
  87         stp     x26, x27, [sp, #16 * 13]
  88         stp     x28, x29, [sp, #16 * 14]
  89
  90         .if     \el == 0
  91         mrs     x21, sp_el0
  92         mov     tsk, sp
  93         and     tsk, tsk, #~(THREAD_SIZE - 1)   // Ensure MDSCR_EL1.SS is clear,
  94         ldr     x19, [tsk, #TI_FLAGS]           // since we can unmask debug
  95         disable_step_tsk x19, x20               // exceptions when scheduling.
  96         .else
  97         add     x21, sp, #S_FRAME_SIZE
  98         .endif
  99         mrs     x22, elr_el1
 100         mrs     x23, spsr_el1
 101         stp     lr, x21, [sp, #S_LR]
 102         stp     x22, x23, [sp, #S_PC]
 103
 104         /*
 105          * Set syscallno to -1 by default (overridden later if real syscall).
 106          */
 107         .if     \el == 0
 108         mvn     x21, xzr
 109         str     x21, [sp, #S_SYSCALLNO]
 110         .endif
 111
 112         /*
 113          * Set sp_el0 to current thread_info.
 114          */
 115         .if     \el == 0
 116         msr     sp_el0, tsk
 117         .endif
 118
 119         /*
 120          * Registers that may be useful after this macro is invoked:
 121          *
 122          * x21 - aborted SP
 123          * x22 - aborted PC
 124          * x23 - aborted PSTATE
 125         */
 126         .endm
 127
 128         .macro  kernel_exit, el
 129         ldp     x21, x22, [sp, #S_PC]           // load ELR, SPSR
 130         .if     \el == 0
 131         ct_user_enter
 132         ldr     x23, [sp, #S_SP]                // load return stack pointer
 133         msr     sp_el0, x23
 134 #ifdef CONFIG_ARM64_ERRATUM_845719
 135 alternative_if_not ARM64_WORKAROUND_845719
 136         nop
 137         nop
 138 #ifdef CONFIG_PID_IN_CONTEXTIDR
 139         nop
 140 #endif
 141 alternative_else
 142         tbz     x22, #4, 1f
 143 #ifdef CONFIG_PID_IN_CONTEXTIDR
 144         mrs     x29, contextidr_el1
 145         msr     contextidr_el1, x29
 146 #else
 147         msr contextidr_el1, xzr
 148 #endif
 149 1:
 150 alternative_endif
 151 #endif
 152         .endif
 153         msr     elr_el1, x21                    // set up the return data
 154         msr     spsr_el1, x22
 155         ldp     x0, x1, [sp, #16 * 0]
 156         ldp     x2, x3, [sp, #16 * 1]
 157         ldp     x4, x5, [sp, #16 * 2]
 158         ldp     x6, x7, [sp, #16 * 3]
 159         ldp     x8, x9, [sp, #16 * 4]
 160         ldp     x10, x11, [sp, #16 * 5]
 161         ldp     x12, x13, [sp, #16 * 6]
 162         ldp     x14, x15, [sp, #16 * 7]
 163         ldp     x16, x17, [sp, #16 * 8]
 164         ldp     x18, x19, [sp, #16 * 9]
 165         ldp     x20, x21, [sp, #16 * 10]
 166         ldp     x22, x23, [sp, #16 * 11]
 167         ldp     x24, x25, [sp, #16 * 12]
 168         ldp     x26, x27, [sp, #16 * 13]
 169         ldp     x28, x29, [sp, #16 * 14]
 170         ldr     lr, [sp, #S_LR]
 171         add     sp, sp, #S_FRAME_SIZE           // restore sp
 172         eret                                    // return to kernel
 173         .endm
 174
 175         .macro  get_thread_info, rd
 176         mrs     \rd, sp_el0
 177         .endm
 178
 179         .macro  irq_stack_entry, dummy_lr
 180         mov     x19, sp                 // preserve the original sp
 181
 182         adr_l   x25, irq_stack
 183         mrs     x26, tpidr_el1
 184         add     x25, x25, x26
 185
 186         /*
 187          * Check the lowest address on irq_stack for the irq_count value,
 188          * incremented by do_softirq_own_stack if we have re-enabled irqs
 189          * while on the irq_stack.
 190          */
 191         ldr     x26, [x25]
 192         cbnz    x26, 9998f              // recursive use?
 193
 194         /* switch to the irq stack */
 195         mov     x26, #IRQ_STACK_START_SP
 196         add     x26, x25, x26
 197         mov     sp, x26
 198
 199         /* Add a dummy stack frame */
 200         stp     x29, \dummy_lr, [sp, #-16]!           // dummy stack frame
 201         mov     x29, sp
 202         stp     x19, xzr, [sp, #-16]!
 203
 204 9998:
 205         .endm
 206
 207         /*
 208          * x19 should be preserved between irq_stack_entry and
 209          * irq_stack_exit.
 210          */
 211         .macro  irq_stack_exit
 212         mov     sp, x19
 213         .endm
 214
 215 /*
 216  * These are the registers used in the syscall handler, and allow us to
 217  * have in theory up to 7 arguments to a function - x0 to x6.
 218  *
 219  * x7 is reserved for the system call number in 32-bit mode.
 220  */
 221 sc_nr   .req    x25             // number of system calls
 222 scno    .req    x26             // syscall number
 223 stbl    .req    x27             // syscall table pointer
 224 tsk     .req    x28             // current thread_info
 225
 226 /*
 227  * Interrupt handling.
 228  */
 229         .macro  irq_handler
 230         ldr_l   x1, handle_arch_irq
 231         mov     x0, sp
 232         irq_stack_entry x22
 233         blr     x1
 234         irq_stack_exit
 235         .endm
 236
 237         .text
 238
 239 /*
 240  * Exception vectors.
 241  */
 242
 243         .align  11
 244 ENTRY(vectors)
 245         ventry  el1_sync_invalid                // Synchronous EL1t
 246         ventry  el1_irq_invalid                 // IRQ EL1t
 247         ventry  el1_fiq_invalid                 // FIQ EL1t
 248         ventry  el1_error_invalid               // Error EL1t
 249
 250         ventry  el1_sync                        // Synchronous EL1h
 251         ventry  el1_irq                         // IRQ EL1h
 252         ventry  el1_fiq_invalid                 // FIQ EL1h
 253         ventry  el1_error_invalid               // Error EL1h
 254
 255         ventry  el0_sync                        // Synchronous 64-bit EL0
 256         ventry  el0_irq                         // IRQ 64-bit EL0
 257         ventry  el0_fiq_invalid                 // FIQ 64-bit EL0
 258         ventry  el0_error_invalid               // Error 64-bit EL0
 259
 260 #ifdef CONFIG_COMPAT
 261         ventry  el0_sync_compat                 // Synchronous 32-bit EL0
 262         ventry  el0_irq_compat                  // IRQ 32-bit EL0
 263         ventry  el0_fiq_invalid_compat          // FIQ 32-bit EL0
 264         ventry  el0_error_invalid_compat        // Error 32-bit EL0
 265 #else
 266         ventry  el0_sync_invalid                // Synchronous 32-bit EL0
 267         ventry  el0_irq_invalid                 // IRQ 32-bit EL0
 268         ventry  el0_fiq_invalid                 // FIQ 32-bit EL0
 269         ventry  el0_error_invalid               // Error 32-bit EL0
 270 #endif
 271 END(vectors)
 272
 273 /*
 274  * Invalid mode handlers
 275  */
 276         .macro  inv_entry, el, reason, regsize = 64
 277         kernel_entry el, \regsize
 278         mov     x0, sp
 279         mov     x1, #\reason
 280         mrs     x2, esr_el1
 281         b       bad_mode
 282         .endm
 283
 284 el0_sync_invalid:
 285         inv_entry 0, BAD_SYNC
 286 ENDPROC(el0_sync_invalid)
 287
 288 el0_irq_invalid:
 289         inv_entry 0, BAD_IRQ
 290 ENDPROC(el0_irq_invalid)
 291
 292 el0_fiq_invalid:
 293         inv_entry 0, BAD_FIQ
 294 ENDPROC(el0_fiq_invalid)
 295
 296 el0_error_invalid:
 297         inv_entry 0, BAD_ERROR
 298 ENDPROC(el0_error_invalid)
 299
 300 #ifdef CONFIG_COMPAT
 301 el0_fiq_invalid_compat:
 302         inv_entry 0, BAD_FIQ, 32
 303 ENDPROC(el0_fiq_invalid_compat)
 304
 305 el0_error_invalid_compat:
 306         inv_entry 0, BAD_ERROR, 32
 307 ENDPROC(el0_error_invalid_compat)
 308 #endif
 309
 310 el1_sync_invalid:
 311         inv_entry 1, BAD_SYNC
 312 ENDPROC(el1_sync_invalid)
 313
 314 el1_irq_invalid:
 315         inv_entry 1, BAD_IRQ
 316 ENDPROC(el1_irq_invalid)
 317
 318 el1_fiq_invalid:
 319         inv_entry 1, BAD_FIQ
 320 ENDPROC(el1_fiq_invalid)
 321
 322 el1_error_invalid:
 323         inv_entry 1, BAD_ERROR
 324 ENDPROC(el1_error_invalid)
 325
 326 /*
 327  * EL1 mode handlers.
 328  */
 329         .align  6
 330 el1_sync:
 331         kernel_entry 1
 332         mrs     x1, esr_el1                     // read the syndrome register
 333         lsr     x24, x1, #ESR_ELx_EC_SHIFT      // exception class
 334         cmp     x24, #ESR_ELx_EC_DABT_CUR       // data abort in EL1
 335         b.eq    el1_da
 336         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 337         b.eq    el1_undef
 338         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 339         b.eq    el1_sp_pc
 340         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 341         b.eq    el1_sp_pc
 342         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL1
 343         b.eq    el1_undef
 344         cmp     x24, #ESR_ELx_EC_BREAKPT_CUR    // debug exception in EL1
 345         b.ge    el1_dbg
 346         b       el1_inv
 347 el1_da:
 348         /*
 349          * Data abort handling
 350          */
 351         mrs     x0, far_el1
 352         enable_dbg
 353         // re-enable interrupts if they were enabled in the aborted context
 354         tbnz    x23, #7, 1f                     // PSR_I_BIT
 355         enable_irq
 356 1:
 357         mov     x2, sp                          // struct pt_regs
 358         bl      do_mem_abort
 359
 360         // disable interrupts before pulling preserved data off the stack
 361         disable_irq
 362         kernel_exit 1
 363 el1_sp_pc:
 364         /*
 365          * Stack or PC alignment exception handling
 366          */
 367         mrs     x0, far_el1
 368         enable_dbg
 369         mov     x2, sp
 370         b       do_sp_pc_abort
 371 el1_undef:
 372         /*
 373          * Undefined instruction
 374          */
 375         enable_dbg
 376         mov     x0, sp
 377         b       do_undefinstr
 378 el1_dbg:
 379         /*
 380          * Debug exception handling
 381          */
 382         cmp     x24, #ESR_ELx_EC_BRK64          // if BRK64
 383         cinc    x24, x24, eq                    // set bit '0'
 384         tbz     x24, #0, el1_inv                // EL1 only
 385         mrs     x0, far_el1
 386         mov     x2, sp                          // struct pt_regs
 387         bl      do_debug_exception
 388         kernel_exit 1
 389 el1_inv:
 390         // TODO: add support for undefined instructions in kernel mode
 391         enable_dbg
 392         mov     x0, sp
 393         mov     x2, x1
 394         mov     x1, #BAD_SYNC
 395         b       bad_mode
 396 ENDPROC(el1_sync)
 397
 398         .align  6
 399 el1_irq:
 400         kernel_entry 1
 401         enable_dbg
 402 #ifdef CONFIG_TRACE_IRQFLAGS
 403         bl      trace_hardirqs_off
 404 #endif
 405
 406         irq_handler
 407
 408 #ifdef CONFIG_PREEMPT
 409         get_thread_info tsk
 410         ldr     w24, [tsk, #TI_PREEMPT]         // get preempt count
 411         cbnz    w24, 1f                         // preempt count != 0
 412         ldr     x0, [tsk, #TI_FLAGS]            // get flags
 413         tbz     x0, #TIF_NEED_RESCHED, 1f       // needs rescheduling?
 414         bl      el1_preempt
 415 1:
 416 #endif
 417 #ifdef CONFIG_TRACE_IRQFLAGS
 418         bl      trace_hardirqs_on
 419 #endif
 420         kernel_exit 1
 421 ENDPROC(el1_irq)
 422
 423 #ifdef CONFIG_PREEMPT
 424 el1_preempt:
 425         mov     x24, lr
 426 1:      bl      preempt_schedule_irq            // irq en/disable is done inside
 427         ldr     x0, [tsk, #TI_FLAGS]            // get new tasks TI_FLAGS
 428         tbnz    x0, #TIF_NEED_RESCHED, 1b       // needs rescheduling?
 429         ret     x24
 430 #endif
 431
 432 /*
 433  * EL0 mode handlers.
 434  */
 435         .align  6
 436 el0_sync:
 437         kernel_entry 0
 438         mrs     x25, esr_el1                    // read the syndrome register
 439         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 440         cmp     x24, #ESR_ELx_EC_SVC64          // SVC in 64-bit state
 441         b.eq    el0_svc
 442         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 443         b.eq    el0_da
 444         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 445         b.eq    el0_ia
 446         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 447         b.eq    el0_fpsimd_acc
 448         cmp     x24, #ESR_ELx_EC_FP_EXC64       // FP/ASIMD exception
 449         b.eq    el0_fpsimd_exc
 450         cmp     x24, #ESR_ELx_EC_SYS64          // configurable trap
 451         b.eq    el0_undef
 452         cmp     x24, #ESR_ELx_EC_SP_ALIGN       // stack alignment exception
 453         b.eq    el0_sp_pc
 454         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 455         b.eq    el0_sp_pc
 456         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 457         b.eq    el0_undef
 458         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 459         b.ge    el0_dbg
 460         b       el0_inv
 461
 462 #ifdef CONFIG_COMPAT
 463         .align  6
 464 el0_sync_compat:
 465         kernel_entry 0, 32
 466         mrs     x25, esr_el1                    // read the syndrome register
 467         lsr     x24, x25, #ESR_ELx_EC_SHIFT     // exception class
 468         cmp     x24, #ESR_ELx_EC_SVC32          // SVC in 32-bit state
 469         b.eq    el0_svc_compat
 470         cmp     x24, #ESR_ELx_EC_DABT_LOW       // data abort in EL0
 471         b.eq    el0_da
 472         cmp     x24, #ESR_ELx_EC_IABT_LOW       // instruction abort in EL0
 473         b.eq    el0_ia
 474         cmp     x24, #ESR_ELx_EC_FP_ASIMD       // FP/ASIMD access
 475         b.eq    el0_fpsimd_acc
 476         cmp     x24, #ESR_ELx_EC_FP_EXC32       // FP/ASIMD exception
 477         b.eq    el0_fpsimd_exc
 478         cmp     x24, #ESR_ELx_EC_PC_ALIGN       // pc alignment exception
 479         b.eq    el0_sp_pc
 480         cmp     x24, #ESR_ELx_EC_UNKNOWN        // unknown exception in EL0
 481         b.eq    el0_undef
 482         cmp     x24, #ESR_ELx_EC_CP15_32        // CP15 MRC/MCR trap
 483         b.eq    el0_undef
 484         cmp     x24, #ESR_ELx_EC_CP15_64        // CP15 MRRC/MCRR trap
 485         b.eq    el0_undef
 486         cmp     x24, #ESR_ELx_EC_CP14_MR        // CP14 MRC/MCR trap
 487         b.eq    el0_undef
 488         cmp     x24, #ESR_ELx_EC_CP14_LS        // CP14 LDC/STC trap
 489         b.eq    el0_undef
 490         cmp     x24, #ESR_ELx_EC_CP14_64        // CP14 MRRC/MCRR trap
 491         b.eq    el0_undef
 492         cmp     x24, #ESR_ELx_EC_BREAKPT_LOW    // debug exception in EL0
 493         b.ge    el0_dbg
 494         b       el0_inv
 495 el0_svc_compat:
 496         /*
 497          * AArch32 syscall handling
 498          */
 499         adrp    stbl, compat_sys_call_table     // load compat syscall table pointer
 500         uxtw    scno, w7                        // syscall number in w7 (r7)
 501         mov     sc_nr, #__NR_compat_syscalls
 502         b       el0_svc_naked
 503
 504         .align  6
 505 el0_irq_compat:
 506         kernel_entry 0, 32
 507         b       el0_irq_naked
 508 #endif
 509
 510 el0_da:
 511         /*
 512          * Data abort handling
 513          */
 514         mrs     x26, far_el1
 515         // enable interrupts before calling the main handler
 516         enable_dbg_and_irq
 517         ct_user_exit
 518         bic     x0, x26, #(0xff << 56)
 519         mov     x1, x25
 520         mov     x2, sp
 521         bl      do_mem_abort
 522         b       ret_to_user
 523 el0_ia:
 524         /*
 525          * Instruction abort handling
 526          */
 527         mrs     x26, far_el1
 528         // enable interrupts before calling the main handler
 529         enable_dbg_and_irq
 530         ct_user_exit
 531         mov     x0, x26
 532         orr     x1, x25, #1 << 24               // use reserved ISS bit for instruction aborts
 533         mov     x2, sp
 534         bl      do_mem_abort
 535         b       ret_to_user
 536 el0_fpsimd_acc:
 537         /*
 538          * Floating Point or Advanced SIMD access
 539          */
 540         enable_dbg
 541         ct_user_exit
 542         mov     x0, x25
 543         mov     x1, sp
 544         bl      do_fpsimd_acc
 545         b       ret_to_user
 546 el0_fpsimd_exc:
 547         /*
 548          * Floating Point or Advanced SIMD exception
 549          */
 550         enable_dbg
 551         ct_user_exit
 552         mov     x0, x25
 553         mov     x1, sp
 554         bl      do_fpsimd_exc
 555         b       ret_to_user
 556 el0_sp_pc:
 557         /*
 558          * Stack or PC alignment exception handling
 559          */
 560         mrs     x26, far_el1
 561         // enable interrupts before calling the main handler
 562         enable_dbg_and_irq
 563         ct_user_exit
 564         mov     x0, x26
 565         mov     x1, x25
 566         mov     x2, sp
 567         bl      do_sp_pc_abort
 568         b       ret_to_user
 569 el0_undef:
 570         /*
 571          * Undefined instruction
 572          */
 573         // enable interrupts before calling the main handler
 574         enable_dbg_and_irq
 575         ct_user_exit
 576         mov     x0, sp
 577         bl      do_undefinstr
 578         b       ret_to_user
 579 el0_dbg:
 580         /*
 581          * Debug exception handling
 582          */
 583         tbnz    x24, #0, el0_inv                // EL0 only
 584         mrs     x0, far_el1
 585         mov     x1, x25
 586         mov     x2, sp
 587         bl      do_debug_exception
 588         enable_dbg
 589         ct_user_exit
 590         b       ret_to_user
 591 el0_inv:
 592         enable_dbg
 593         ct_user_exit
 594         mov     x0, sp
 595         mov     x1, #BAD_SYNC
 596         mov     x2, x25
 597         bl      bad_mode
 598         b       ret_to_user
 599 ENDPROC(el0_sync)
 600
 601         .align  6
 602 el0_irq:
 603         kernel_entry 0
 604 el0_irq_naked:
 605         enable_dbg
 606 #ifdef CONFIG_TRACE_IRQFLAGS
 607         bl      trace_hardirqs_off
 608 #endif
 609
 610         ct_user_exit
 611         irq_handler
 612
 613 #ifdef CONFIG_TRACE_IRQFLAGS
 614         bl      trace_hardirqs_on
 615 #endif
 616         b       ret_to_user
 617 ENDPROC(el0_irq)
 618
 619 /*
 620  * Register switch for AArch64. The callee-saved registers need to be saved
 621  * and restored. On entry:
 622  *   x0 = previous task_struct (must be preserved across the switch)
 623  *   x1 = next task_struct
 624  * Previous and next are guaranteed not to be the same.
 625  *
 626  */
 627 ENTRY(cpu_switch_to)
 628         mov     x10, #THREAD_CPU_CONTEXT
 629         add     x8, x0, x10
 630         mov     x9, sp
 631         stp     x19, x20, [x8], #16             // store callee-saved registers
 632         stp     x21, x22, [x8], #16
 633         stp     x23, x24, [x8], #16
 634         stp     x25, x26, [x8], #16
 635         stp     x27, x28, [x8], #16
 636         stp     x29, x9, [x8], #16
 637         str     lr, [x8]
 638         add     x8, x1, x10
 639         ldp     x19, x20, [x8], #16             // restore callee-saved registers
 640         ldp     x21, x22, [x8], #16
 641         ldp     x23, x24, [x8], #16
 642         ldp     x25, x26, [x8], #16
 643         ldp     x27, x28, [x8], #16
 644         ldp     x29, x9, [x8], #16
 645         ldr     lr, [x8]
 646         mov     sp, x9
 647         and     x9, x9, #~(THREAD_SIZE - 1)
 648         msr     sp_el0, x9
 649         ret
 650 ENDPROC(cpu_switch_to)
 651
 652 /*
 653  * This is the fast syscall return path.  We do as little as possible here,
 654  * and this includes saving x0 back into the kernel stack.
 655  */
 656 ret_fast_syscall:
 657         disable_irq                             // disable interrupts
 658         str     x0, [sp, #S_X0]                 // returned x0
 659         ldr     x1, [tsk, #TI_FLAGS]            // re-check for syscall tracing
 660         and     x2, x1, #_TIF_SYSCALL_WORK
 661         cbnz    x2, ret_fast_syscall_trace
 662         and     x2, x1, #_TIF_WORK_MASK
 663         cbnz    x2, work_pending
 664         enable_step_tsk x1, x2
 665         kernel_exit 0
 666 ret_fast_syscall_trace:
 667         enable_irq                              // enable interrupts
 668         b       __sys_trace_return_skipped      // we already saved x0
 669
 670 /*
 671  * Ok, we need to do extra processing, enter the slow path.
 672  */
 673 work_pending:
 674         tbnz    x1, #TIF_NEED_RESCHED, work_resched
 675         /* TIF_SIGPENDING, TIF_NOTIFY_RESUME or TIF_FOREIGN_FPSTATE case */
 676         ldr     x2, [sp, #S_PSTATE]
 677         mov     x0, sp                          // 'regs'
 678         tst     x2, #PSR_MODE_MASK              // user mode regs?
 679         b.ne    no_work_pending                 // returning to kernel
 680         enable_irq                              // enable interrupts for do_notify_resume()
 681         bl      do_notify_resume
 682         b       ret_to_user
 683 work_resched:
 684 #ifdef CONFIG_TRACE_IRQFLAGS
 685         bl      trace_hardirqs_off              // the IRQs are off here, inform the tracing code
 686 #endif
 687         bl      schedule
 688
 689 /*
 690  * "slow" syscall return path.
 691  */
 692 ret_to_user:
 693         disable_irq                             // disable interrupts
 694         ldr     x1, [tsk, #TI_FLAGS]
 695         and     x2, x1, #_TIF_WORK_MASK
 696         cbnz    x2, work_pending
 697         enable_step_tsk x1, x2
 698 no_work_pending:
 699         kernel_exit 0
 700 ENDPROC(ret_to_user)
 701
 702 /*
 703  * This is how we return from a fork.
 704  */
 705 ENTRY(ret_from_fork)
 706         bl      schedule_tail
 707         cbz     x19, 1f                         // not a kernel thread
 708         mov     x0, x20
 709         blr     x19
 710 1:      get_thread_info tsk
 711         b       ret_to_user
 712 ENDPROC(ret_from_fork)
 713
 714 /*
 715  * SVC handler.
 716  */
 717         .align  6
 718 el0_svc:
 719         adrp    stbl, sys_call_table            // load syscall table pointer
 720         uxtw    scno, w8                        // syscall number in w8
 721         mov     sc_nr, #__NR_syscalls
 722 el0_svc_naked:                                  // compat entry point
 723         stp     x0, scno, [sp, #S_ORIG_X0]      // save the original x0 and syscall number
 724         enable_dbg_and_irq
 725         ct_user_exit 1
 726
 727         ldr     x16, [tsk, #TI_FLAGS]           // check for syscall hooks
 728         tst     x16, #_TIF_SYSCALL_WORK
 729         b.ne    __sys_trace
 730         cmp     scno, sc_nr                     // check upper syscall limit
 731         b.hs    ni_sys
 732         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 733         blr     x16                             // call sys_* routine
 734         b       ret_fast_syscall
 735 ni_sys:
 736         mov     x0, sp
 737         bl      do_ni_syscall
 738         b       ret_fast_syscall
 739 ENDPROC(el0_svc)
 740
 741         /*
 742          * This is the really slow path.  We're going to be doing context
 743          * switches, and waiting for our parent to respond.
 744          */
 745 __sys_trace:
 746         mov     w0, #-1                         // set default errno for
 747         cmp     scno, x0                        // user-issued syscall(-1)
 748         b.ne    1f
 749         mov     x0, #-ENOSYS
 750         str     x0, [sp, #S_X0]
 751 1:      mov     x0, sp
 752         bl      syscall_trace_enter
 753         cmp     w0, #-1                         // skip the syscall?
 754         b.eq    __sys_trace_return_skipped
 755         uxtw    scno, w0                        // syscall number (possibly new)
 756         mov     x1, sp                          // pointer to regs
 757         cmp     scno, sc_nr                     // check upper syscall limit
 758         b.hs    __ni_sys_trace
 759         ldp     x0, x1, [sp]                    // restore the syscall args
 760         ldp     x2, x3, [sp, #S_X2]
 761         ldp     x4, x5, [sp, #S_X4]
 762         ldp     x6, x7, [sp, #S_X6]
 763         ldr     x16, [stbl, scno, lsl #3]       // address in the syscall table
 764         blr     x16                             // call sys_* routine
 765
 766 __sys_trace_return:
 767         str     x0, [sp, #S_X0]                 // save returned x0
 768 __sys_trace_return_skipped:
 769         mov     x0, sp
 770         bl      syscall_trace_exit
 771         b       ret_to_user
 772
 773 __ni_sys_trace:
 774         mov     x0, sp
 775         bl      do_ni_syscall
 776         b       __sys_trace_return
 777
 778 /*
 779  * Special system call wrappers.
 780  */
 781 ENTRY(sys_rt_sigreturn_wrapper)
 782         mov     x0, sp
 783         b       sys_rt_sigreturn
 784 ENDPROC(sys_rt_sigreturn_wrapper)