arch/x86/kernel/head_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  *
   5  *  Enhanced CPU detection and feature setting code by Mike Jagdis
   6  *  and Martin Mares, November 1997.
   7  */
   8
   9 .text
  10 #include <linux/threads.h>
  11 #include <linux/init.h>
  12 #include <linux/linkage.h>
  13 #include <asm/segment.h>
  14 #include <asm/page_types.h>
  15 #include <asm/pgtable_types.h>
  16 #include <asm/cache.h>
  17 #include <asm/thread_info.h>
  18 #include <asm/asm-offsets.h>
  19 #include <asm/setup.h>
  20 #include <asm/processor-flags.h>
  21 #include <asm/msr-index.h>
  22 #include <asm/cpufeature.h>
  23 #include <asm/percpu.h>
  24
  25 /* Physical address */
  26 #define pa(X) ((X) - __PAGE_OFFSET)
  27
  28 /*
  29  * References to members of the new_cpu_data structure.
  30  */
  31
  32 #define X86             new_cpu_data+CPUINFO_x86
  33 #define X86_VENDOR      new_cpu_data+CPUINFO_x86_vendor
  34 #define X86_MODEL       new_cpu_data+CPUINFO_x86_model
  35 #define X86_MASK        new_cpu_data+CPUINFO_x86_mask
  36 #define X86_HARD_MATH   new_cpu_data+CPUINFO_hard_math
  37 #define X86_CPUID       new_cpu_data+CPUINFO_cpuid_level
  38 #define X86_CAPABILITY  new_cpu_data+CPUINFO_x86_capability
  39 #define X86_VENDOR_ID   new_cpu_data+CPUINFO_x86_vendor_id
  40
  41 /*
  42  * This is how much memory in addition to the memory covered up to
  43  * and including _end we need mapped initially.
  44  * We need:
  45  *     (KERNEL_IMAGE_SIZE/4096) / 1024 pages (worst case, non PAE)
  46  *     (KERNEL_IMAGE_SIZE/4096) / 512 + 4 pages (worst case for PAE)
  47  *
  48  * Modulo rounding, each megabyte assigned here requires a kilobyte of
  49  * memory, which is currently unreclaimed.
  50  *
  51  * This should be a multiple of a page.
  52  *
  53  * KERNEL_IMAGE_SIZE should be greater than pa(_end)
  54  * and small than max_low_pfn, otherwise will waste some page table entries
  55  */
  56
  57 #if PTRS_PER_PMD > 1
  58 #define PAGE_TABLE_SIZE(pages) (((pages) / PTRS_PER_PMD) + PTRS_PER_PGD)
  59 #else
  60 #define PAGE_TABLE_SIZE(pages) ((pages) / PTRS_PER_PGD)
  61 #endif
  62
  63 /* Number of possible pages in the lowmem region */
  64 LOWMEM_PAGES = (((1<<32) - __PAGE_OFFSET) >> PAGE_SHIFT)
  65
  66 /* Enough space to fit pagetables for the low memory linear map */
  67 MAPPING_BEYOND_END = PAGE_TABLE_SIZE(LOWMEM_PAGES) << PAGE_SHIFT
  68
  69 /*
  70  * Worst-case size of the kernel mapping we need to make:
  71  * a relocatable kernel can live anywhere in lowmem, so we need to be able
  72  * to map all of lowmem.
  73  */
  74 KERNEL_PAGES = LOWMEM_PAGES
  75
  76 INIT_MAP_SIZE = PAGE_TABLE_SIZE(KERNEL_PAGES) * PAGE_SIZE
  77 RESERVE_BRK(pagetables, INIT_MAP_SIZE)
  78
  79 /*
  80  * 32-bit kernel entrypoint; only used by the boot CPU.  On entry,
  81  * %esi points to the real-mode code as a 32-bit pointer.
  82  * CS and DS must be 4 GB flat segments, but we don't depend on
  83  * any particular GDT layout, because we load our own as soon as we
  84  * can.
  85  */
  86 __HEAD
  87 ENTRY(startup_32)
  88         movl pa(stack_start),%ecx
  89
  90         /* test KEEP_SEGMENTS flag to see if the bootloader is asking
  91                 us to not reload segments */
  92         testb $(1<<6), BP_loadflags(%esi)
  93         jnz 2f
  94
  95 /*
  96  * Set segments to known values.
  97  */
  98         lgdt pa(boot_gdt_descr)
  99         movl $(__BOOT_DS),%eax
 100         movl %eax,%ds
 101         movl %eax,%es
 102         movl %eax,%fs
 103         movl %eax,%gs
 104         movl %eax,%ss
 105 2:
 106         leal -__PAGE_OFFSET(%ecx),%esp
 107
 108 /*
 109  * Clear BSS first so that there are no surprises...
 110  */
 111         cld
 112         xorl %eax,%eax
 113         movl $pa(__bss_start),%edi
 114         movl $pa(__bss_stop),%ecx
 115         subl %edi,%ecx
 116         shrl $2,%ecx
 117         rep ; stosl
 118 /*
 119  * Copy bootup parameters out of the way.
 120  * Note: %esi still has the pointer to the real-mode data.
 121  * With the kexec as boot loader, parameter segment might be loaded beyond
 122  * kernel image and might not even be addressable by early boot page tables.
 123  * (kexec on panic case). Hence copy out the parameters before initializing
 124  * page tables.
 125  */
 126         movl $pa(boot_params),%edi
 127         movl $(PARAM_SIZE/4),%ecx
 128         cld
 129         rep
 130         movsl
 131         movl pa(boot_params) + NEW_CL_POINTER,%esi
 132         andl %esi,%esi
 133         jz 1f                   # No command line
 134         movl $pa(boot_command_line),%edi
 135         movl $(COMMAND_LINE_SIZE/4),%ecx
 136         rep
 137         movsl
 138 1:
 139
 140 #ifdef CONFIG_OLPC
 141         /* save OFW's pgdir table for later use when calling into OFW */
 142         movl %cr3, %eax
 143         movl %eax, pa(olpc_ofw_pgd)
 144 #endif
 145
 146 /*
 147  * Initialize page tables.  This creates a PDE and a set of page
 148  * tables, which are located immediately beyond __brk_base.  The variable
 149  * _brk_end is set up to point to the first "safe" location.
 150  * Mappings are created both at virtual address 0 (identity mapping)
 151  * and PAGE_OFFSET for up to _end.
 152  */
 153 #ifdef CONFIG_X86_PAE
 154
 155         /*
 156          * In PAE mode initial_page_table is statically defined to contain
 157          * enough entries to cover the VMSPLIT option (that is the top 1, 2 or 3
 158          * entries). The identity mapping is handled by pointing two PGD entries
 159          * to the first kernel PMD.
 160          *
 161          * Note the upper half of each PMD or PTE are always zero at this stage.
 162          */
 163
 164 #define KPMDS (((-__PAGE_OFFSET) >> 30) & 3) /* Number of kernel PMDs */
 165
 166         xorl %ebx,%ebx                          /* %ebx is kept at zero */
 167
 168         movl $pa(__brk_base), %edi
 169         movl $pa(initial_pg_pmd), %edx
 170         movl $PTE_IDENT_ATTR, %eax
 171 10:
 172         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PMD entry */
 173         movl %ecx,(%edx)                        /* Store PMD entry */
 174                                                 /* Upper half already zero */
 175         addl $8,%edx
 176         movl $512,%ecx
 177 11:
 178         stosl
 179         xchgl %eax,%ebx
 180         stosl
 181         xchgl %eax,%ebx
 182         addl $0x1000,%eax
 183         loop 11b
 184
 185         /*
 186          * End condition: we must map up to the end + MAPPING_BEYOND_END.
 187          */
 188         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
 189         cmpl %ebp,%eax
 190         jb 10b
 191 1:
 192         addl $__PAGE_OFFSET, %edi
 193         movl %edi, pa(_brk_end)
 194         shrl $12, %eax
 195         movl %eax, pa(max_pfn_mapped)
 196
 197         /* Do early initialization of the fixmap area */
 198         movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
 199         movl %eax,pa(initial_pg_pmd+0x1000*KPMDS-8)
 200 #else   /* Not PAE */
 201
 202 page_pde_offset = (__PAGE_OFFSET >> 20);
 203
 204         movl $pa(__brk_base), %edi
 205         movl $pa(initial_page_table), %edx
 206         movl $PTE_IDENT_ATTR, %eax
 207 10:
 208         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PDE entry */
 209         movl %ecx,(%edx)                        /* Store identity PDE entry */
 210         movl %ecx,page_pde_offset(%edx)         /* Store kernel PDE entry */
 211         addl $4,%edx
 212         movl $1024, %ecx
 213 11:
 214         stosl
 215         addl $0x1000,%eax
 216         loop 11b
 217         /*
 218          * End condition: we must map up to the end + MAPPING_BEYOND_END.
 219          */
 220         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
 221         cmpl %ebp,%eax
 222         jb 10b
 223         addl $__PAGE_OFFSET, %edi
 224         movl %edi, pa(_brk_end)
 225         shrl $12, %eax
 226         movl %eax, pa(max_pfn_mapped)
 227
 228         /* Do early initialization of the fixmap area */
 229         movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
 230         movl %eax,pa(initial_page_table+0xffc)
 231 #endif
 232
 233 #ifdef CONFIG_PARAVIRT
 234         /* This is can only trip for a broken bootloader... */
 235         cmpw $0x207, pa(boot_params + BP_version)
 236         jb default_entry
 237
 238         /* Paravirt-compatible boot parameters.  Look to see what architecture
 239                 we're booting under. */
 240         movl pa(boot_params + BP_hardware_subarch), %eax
 241         cmpl $num_subarch_entries, %eax
 242         jae bad_subarch
 243
 244         movl pa(subarch_entries)(,%eax,4), %eax
 245         subl $__PAGE_OFFSET, %eax
 246         jmp *%eax
 247
 248 bad_subarch:
 249 WEAK(lguest_entry)
 250 WEAK(xen_entry)
 251         /* Unknown implementation; there's really
 252            nothing we can do at this point. */
 253         ud2a
 254
 255         __INITDATA
 256
 257 subarch_entries:
 258         .long default_entry             /* normal x86/PC */
 259         .long lguest_entry              /* lguest hypervisor */
 260         .long xen_entry                 /* Xen hypervisor */
 261         .long default_entry             /* Moorestown MID */
 262 num_subarch_entries = (. - subarch_entries) / 4
 263 .previous
 264 #else
 265         jmp default_entry
 266 #endif /* CONFIG_PARAVIRT */
 267
 268 /*
 269  * Non-boot CPU entry point; entered from trampoline.S
 270  * We can't lgdt here, because lgdt itself uses a data segment, but
 271  * we know the trampoline has already loaded the boot_gdt for us.
 272  *
 273  * If cpu hotplug is not supported then this code can go in init section
 274  * which will be freed later
 275  */
 276 __CPUINIT
 277 ENTRY(startup_32_smp)
 278         cld
 279         movl $(__BOOT_DS),%eax
 280         movl %eax,%ds
 281         movl %eax,%es
 282         movl %eax,%fs
 283         movl %eax,%gs
 284         movl pa(stack_start),%ecx
 285         movl %eax,%ss
 286         leal -__PAGE_OFFSET(%ecx),%esp
 287
 288 default_entry:
 289
 290 /*
 291  *      New page tables may be in 4Mbyte page mode and may
 292  *      be using the global pages.
 293  *
 294  *      NOTE! If we are on a 486 we may have no cr4 at all!
 295  *      So we do not try to touch it unless we really have
 296  *      some bits in it to set.  This won't work if the BSP
 297  *      implements cr4 but this AP does not -- very unlikely
 298  *      but be warned!  The same applies to the pse feature
 299  *      if not equally supported. --macro
 300  *
 301  *      NOTE! We have to correct for the fact that we're
 302  *      not yet offset PAGE_OFFSET..
 303  */
 304 #define cr4_bits pa(mmu_cr4_features)
 305         movl cr4_bits,%edx
 306         andl %edx,%edx
 307         jz 6f
 308         movl %cr4,%eax          # Turn on paging options (PSE,PAE,..)
 309         orl %edx,%eax
 310         movl %eax,%cr4
 311
 312         testb $X86_CR4_PAE, %al         # check if PAE is enabled
 313         jz 6f
 314
 315         /* Check if extended functions are implemented */
 316         movl $0x80000000, %eax
 317         cpuid
 318         /* Value must be in the range 0x80000001 to 0x8000ffff */
 319         subl $0x80000001, %eax
 320         cmpl $(0x8000ffff-0x80000001), %eax
 321         ja 6f
 322
 323         /* Clear bogus XD_DISABLE bits */
 324         call verify_cpu
 325
 326         mov $0x80000001, %eax
 327         cpuid
 328         /* Execute Disable bit supported? */
 329         btl $(X86_FEATURE_NX & 31), %edx
 330         jnc 6f
 331
 332         /* Setup EFER (Extended Feature Enable Register) */
 333         movl $MSR_EFER, %ecx
 334         rdmsr
 335
 336         btsl $_EFER_NX, %eax
 337         /* Make changes effective */
 338         wrmsr
 339
 340 6:
 341
 342 /*
 343  * Enable paging
 344  */
 345         movl $pa(initial_page_table), %eax
 346         movl %eax,%cr3          /* set the page table pointer.. */
 347         movl %cr0,%eax
 348         orl  $X86_CR0_PG,%eax
 349         movl %eax,%cr0          /* ..and set paging (PG) bit */
 350         ljmp $__BOOT_CS,$1f     /* Clear prefetch and normalize %eip */
 351 1:
 352         /* Shift the stack pointer to a virtual address */
 353         addl $__PAGE_OFFSET, %esp
 354
 355 /*
 356  * Initialize eflags.  Some BIOS's leave bits like NT set.  This would
 357  * confuse the debugger if this code is traced.
 358  * XXX - best to initialize before switching to protected mode.
 359  */
 360         pushl $0
 361         popfl
 362
 363 #ifdef CONFIG_SMP
 364         cmpb $0, ready
 365         jnz checkCPUtype
 366 #endif /* CONFIG_SMP */
 367
 368 /*
 369  * start system 32-bit setup. We need to re-do some of the things done
 370  * in 16-bit mode for the "real" operations.
 371  */
 372         call setup_idt
 373
 374 checkCPUtype:
 375
 376         movl $-1,X86_CPUID              #  -1 for no CPUID initially
 377
 378 /* check if it is 486 or 386. */
 379 /*
 380  * XXX - this does a lot of unnecessary setup.  Alignment checks don't
 381  * apply at our cpl of 0 and the stack ought to be aligned already, and
 382  * we don't need to preserve eflags.
 383  */
 384
 385         movb $3,X86             # at least 386
 386         pushfl                  # push EFLAGS
 387         popl %eax               # get EFLAGS
 388         movl %eax,%ecx          # save original EFLAGS
 389         xorl $0x240000,%eax     # flip AC and ID bits in EFLAGS
 390         pushl %eax              # copy to EFLAGS
 391         popfl                   # set EFLAGS
 392         pushfl                  # get new EFLAGS
 393         popl %eax               # put it in eax
 394         xorl %ecx,%eax          # change in flags
 395         pushl %ecx              # restore original EFLAGS
 396         popfl
 397         testl $0x40000,%eax     # check if AC bit changed
 398         je is386
 399
 400         movb $4,X86             # at least 486
 401         testl $0x200000,%eax    # check if ID bit changed
 402         je is486
 403
 404         /* get vendor info */
 405         xorl %eax,%eax                  # call CPUID with 0 -> return vendor ID
 406         cpuid
 407         movl %eax,X86_CPUID             # save CPUID level
 408         movl %ebx,X86_VENDOR_ID         # lo 4 chars
 409         movl %edx,X86_VENDOR_ID+4       # next 4 chars
 410         movl %ecx,X86_VENDOR_ID+8       # last 4 chars
 411
 412         orl %eax,%eax                   # do we have processor info as well?
 413         je is486
 414
 415         movl $1,%eax            # Use the CPUID instruction to get CPU type
 416         cpuid
 417         movb %al,%cl            # save reg for future use
 418         andb $0x0f,%ah          # mask processor family
 419         movb %ah,X86
 420         andb $0xf0,%al          # mask model
 421         shrb $4,%al
 422         movb %al,X86_MODEL
 423         andb $0x0f,%cl          # mask mask revision
 424         movb %cl,X86_MASK
 425         movl %edx,X86_CAPABILITY
 426
 427 is486:  movl $0x50022,%ecx      # set AM, WP, NE and MP
 428         jmp 2f
 429
 430 is386:  movl $2,%ecx            # set MP
 431 2:      movl %cr0,%eax
 432         andl $0x80000011,%eax   # Save PG,PE,ET
 433         orl %ecx,%eax
 434         movl %eax,%cr0
 435
 436         call check_x87
 437         lgdt early_gdt_descr
 438         lidt idt_descr
 439         ljmp $(__KERNEL_CS),$1f
 440 1:      movl $(__KERNEL_DS),%eax        # reload all the segment registers
 441         movl %eax,%ss                   # after changing gdt.
 442
 443         movl $(__USER_DS),%eax          # DS/ES contains default USER segment
 444         movl %eax,%ds
 445         movl %eax,%es
 446
 447         movl $(__KERNEL_PERCPU), %eax
 448         movl %eax,%fs                   # set this cpu's percpu
 449
 450 #ifdef CONFIG_CC_STACKPROTECTOR
 451         /*
 452          * The linker can't handle this by relocation.  Manually set
 453          * base address in stack canary segment descriptor.
 454          */
 455         cmpb $0,ready
 456         jne 1f
 457         movl $gdt_page,%eax
 458         movl $stack_canary,%ecx
 459         movw %cx, 8 * GDT_ENTRY_STACK_CANARY + 2(%eax)
 460         shrl $16, %ecx
 461         movb %cl, 8 * GDT_ENTRY_STACK_CANARY + 4(%eax)
 462         movb %ch, 8 * GDT_ENTRY_STACK_CANARY + 7(%eax)
 463 1:
 464 #endif
 465         movl $(__KERNEL_STACK_CANARY),%eax
 466         movl %eax,%gs
 467
 468         xorl %eax,%eax                  # Clear LDT
 469         lldt %ax
 470
 471         cld                     # gcc2 wants the direction flag cleared at all times
 472         pushl $0                # fake return address for unwinder
 473         movb $1, ready
 474         jmp *(initial_code)
 475
 476 /*
 477  * We depend on ET to be correct. This checks for 287/387.
 478  */
 479 check_x87:
 480         movb $0,X86_HARD_MATH
 481         clts
 482         fninit
 483         fstsw %ax
 484         cmpb $0,%al
 485         je 1f
 486         movl %cr0,%eax          /* no coprocessor: have to set bits */
 487         xorl $4,%eax            /* set EM */
 488         movl %eax,%cr0
 489         ret
 490         ALIGN
 491 1:      movb $1,X86_HARD_MATH
 492         .byte 0xDB,0xE4         /* fsetpm for 287, ignored by 387 */
 493         ret
 494
 495 /*
 496  *  setup_idt
 497  *
 498  *  sets up a idt with 256 entries pointing to
 499  *  ignore_int, interrupt gates. It doesn't actually load
 500  *  idt - that can be done only after paging has been enabled
 501  *  and the kernel moved to PAGE_OFFSET. Interrupts
 502  *  are enabled elsewhere, when we can be relatively
 503  *  sure everything is ok.
 504  *
 505  *  Warning: %esi is live across this function.
 506  */
 507 setup_idt:
 508         lea ignore_int,%edx
 509         movl $(__KERNEL_CS << 16),%eax
 510         movw %dx,%ax            /* selector = 0x0010 = cs */
 511         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
 512
 513         lea idt_table,%edi
 514         mov $256,%ecx
 515 rp_sidt:
 516         movl %eax,(%edi)
 517         movl %edx,4(%edi)
 518         addl $8,%edi
 519         dec %ecx
 520         jne rp_sidt
 521
 522 .macro  set_early_handler handler,trapno
 523         lea \handler,%edx
 524         movl $(__KERNEL_CS << 16),%eax
 525         movw %dx,%ax
 526         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
 527         lea idt_table,%edi
 528         movl %eax,8*\trapno(%edi)
 529         movl %edx,8*\trapno+4(%edi)
 530 .endm
 531
 532         set_early_handler handler=early_divide_err,trapno=0
 533         set_early_handler handler=early_illegal_opcode,trapno=6
 534         set_early_handler handler=early_protection_fault,trapno=13
 535         set_early_handler handler=early_page_fault,trapno=14
 536
 537         ret
 538
 539 early_divide_err:
 540         xor %edx,%edx
 541         pushl $0        /* fake errcode */
 542         jmp early_fault
 543
 544 early_illegal_opcode:
 545         movl $6,%edx
 546         pushl $0        /* fake errcode */
 547         jmp early_fault
 548
 549 early_protection_fault:
 550         movl $13,%edx
 551         jmp early_fault
 552
 553 early_page_fault:
 554         movl $14,%edx
 555         jmp early_fault
 556
 557 early_fault:
 558         cld
 559 #ifdef CONFIG_PRINTK
 560         pusha
 561         movl $(__KERNEL_DS),%eax
 562         movl %eax,%ds
 563         movl %eax,%es
 564         cmpl $2,early_recursion_flag
 565         je hlt_loop
 566         incl early_recursion_flag
 567         movl %cr2,%eax
 568         pushl %eax
 569         pushl %edx              /* trapno */
 570         pushl $fault_msg
 571         call printk
 572 #endif
 573         call dump_stack
 574 hlt_loop:
 575         hlt
 576         jmp hlt_loop
 577
 578 /* This is the default interrupt "handler" :-) */
 579         ALIGN
 580 ignore_int:
 581         cld
 582 #ifdef CONFIG_PRINTK
 583         pushl %eax
 584         pushl %ecx
 585         pushl %edx
 586         pushl %es
 587         pushl %ds
 588         movl $(__KERNEL_DS),%eax
 589         movl %eax,%ds
 590         movl %eax,%es
 591         cmpl $2,early_recursion_flag
 592         je hlt_loop
 593         incl early_recursion_flag
 594         pushl 16(%esp)
 595         pushl 24(%esp)
 596         pushl 32(%esp)
 597         pushl 40(%esp)
 598         pushl $int_msg
 599         call printk
 600
 601         call dump_stack
 602
 603         addl $(5*4),%esp
 604         popl %ds
 605         popl %es
 606         popl %edx
 607         popl %ecx
 608         popl %eax
 609 #endif
 610         iret
 611
 612 #include "verify_cpu.S"
 613
 614         __REFDATA
 615 .align 4
 616 ENTRY(initial_code)
 617         .long i386_start_kernel
 618
 619 /*
 620  * BSS section
 621  */
 622 __PAGE_ALIGNED_BSS
 623         .align PAGE_SIZE
 624 #ifdef CONFIG_X86_PAE
 625 initial_pg_pmd:
 626         .fill 1024*KPMDS,4,0
 627 #else
 628 ENTRY(initial_page_table)
 629         .fill 1024,4,0
 630 #endif
 631 initial_pg_fixmap:
 632         .fill 1024,4,0
 633 ENTRY(empty_zero_page)
 634         .fill 4096,1,0
 635 ENTRY(swapper_pg_dir)
 636         .fill 1024,4,0
 637
 638 /*
 639  * This starts the data section.
 640  */
 641 #ifdef CONFIG_X86_PAE
 642 __PAGE_ALIGNED_DATA
 643         /* Page-aligned for the benefit of paravirt? */
 644         .align PAGE_SIZE
 645 ENTRY(initial_page_table)
 646         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0     /* low identity map */
 647 # if KPMDS == 3
 648         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 649         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
 650         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x2000),0
 651 # elif KPMDS == 2
 652         .long   0,0
 653         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 654         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
 655 # elif KPMDS == 1
 656         .long   0,0
 657         .long   0,0
 658         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 659 # else
 660 #  error "Kernel PMDs should be 1, 2 or 3"
 661 # endif
 662         .align PAGE_SIZE                /* needs to be page-sized too */
 663 #endif
 664
 665 .data
 666 .balign 4
 667 ENTRY(stack_start)
 668         .long init_thread_union+THREAD_SIZE
 669
 670 early_recursion_flag:
 671         .long 0
 672
 673 ready:  .byte 0
 674
 675 int_msg:
 676         .asciz "Unknown interrupt or fault at: %p %p %p\n"
 677
 678 fault_msg:
 679 /* fault info: */
 680         .ascii "BUG: Int %d: CR2 %p\n"
 681 /* pusha regs: */
 682         .ascii "     EDI %p  ESI %p  EBP %p  ESP %p\n"
 683         .ascii "     EBX %p  EDX %p  ECX %p  EAX %p\n"
 684 /* fault frame: */
 685         .ascii "     err %p  EIP %p   CS %p  flg %p\n"
 686         .ascii "Stack: %p %p %p %p %p %p %p %p\n"
 687         .ascii "       %p %p %p %p %p %p %p %p\n"
 688         .asciz "       %p %p %p %p %p %p %p %p\n"
 689
 690 #include "../../x86/xen/xen-head.S"
 691
 692 /*
 693  * The IDT and GDT 'descriptors' are a strange 48-bit object
 694  * only used by the lidt and lgdt instructions. They are not
 695  * like usual segment descriptors - they consist of a 16-bit
 696  * segment size, and 32-bit linear address value:
 697  */
 698
 699 .globl boot_gdt_descr
 700 .globl idt_descr
 701
 702         ALIGN
 703 # early boot GDT descriptor (must use 1:1 address mapping)
 704         .word 0                         # 32 bit align gdt_desc.address
 705 boot_gdt_descr:
 706         .word __BOOT_DS+7
 707         .long boot_gdt - __PAGE_OFFSET
 708
 709         .word 0                         # 32-bit align idt_desc.address
 710 idt_descr:
 711         .word IDT_ENTRIES*8-1           # idt contains 256 entries
 712         .long idt_table
 713
 714 # boot GDT descriptor (later on used by CPU#0):
 715         .word 0                         # 32 bit align gdt_desc.address
 716 ENTRY(early_gdt_descr)
 717         .word GDT_ENTRIES*8-1
 718         .long gdt_page                  /* Overwritten for secondary CPUs */
 719
 720 /*
 721  * The boot_gdt must mirror the equivalent in setup.S and is
 722  * used only for booting.
 723  */
 724         .align L1_CACHE_BYTES
 725 ENTRY(boot_gdt)
 726         .fill GDT_ENTRY_BOOT_CS,8,0
 727         .quad 0x00cf9a000000ffff        /* kernel 4GB code at 0x00000000 */
 728         .quad 0x00cf92000000ffff        /* kernel 4GB data at 0x00000000 */