acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        if test "$version" = 3 && test "$patchlevel" -le 14; then
 138           : # Linux 3.x
 139        else
 140          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 3.14.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     else
 143        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 144          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 145        else
 146          : # Linux 2.6.x
 147        fi
 148     fi
 149     if (test ! -e "$KBUILD"/include/linux/version.h && \
 150         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 151        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 152         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 153         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 154     fi
 155     OVS_CHECK_LINUX_COMPAT
 156   fi
 157   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 158 ])
 159
 160 dnl OVS_CHECK_DPDK
 161 dnl
 162 dnl Configure DPDK source tree
 163 AC_DEFUN([OVS_CHECK_DPDK], [
 164   AC_ARG_WITH([dpdk],
 165               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 166                               [Specify the DPDK build directory])])
 167
 168   if test X"$with_dpdk" != X; then
 169     RTE_SDK=$with_dpdk
 170
 171     DPDK_INCLUDE=$RTE_SDK/include
 172     DPDK_LIB_DIR=$RTE_SDK/lib
 173     DPDK_LIBS="$DPDK_LIB_DIR/libintel_dpdk.a"
 174
 175     LIBS="$DPDK_LIBS $LIBS"
 176     CPPFLAGS="-I$DPDK_INCLUDE $CPPFLAGS"
 177
 178     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 179   else
 180     RTE_SDK=
 181   fi
 182
 183   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 184 ])
 185
 186 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 187 dnl
 188 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 189 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 190 dnl <REGEX> translated to uppercase.
 191 AC_DEFUN([OVS_GREP_IFELSE], [
 192   AC_MSG_CHECKING([whether $2 matches in $1])
 193   if test -f $1; then
 194     grep '$2' $1 >/dev/null 2>&1
 195     status=$?
 196     case $status in
 197       0)
 198         AC_MSG_RESULT([yes])
 199         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 200         ;;
 201       1)
 202         AC_MSG_RESULT([no])
 203         $4
 204         ;;
 205       *)
 206         AC_MSG_ERROR([grep exited with status $status])
 207         ;;
 208     esac
 209   else
 210     AC_MSG_RESULT([file not found])
 211     $4
 212   fi
 213 ])
 214
 215 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 216 dnl
 217 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 218 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 219 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 220 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 221 dnl translated to uppercase.
 222 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 223   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 224   if test -f $1; then
 225     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3'
 226     status=$?
 227     case $status in
 228       0)
 229         AC_MSG_RESULT([yes])
 230         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 231         ;;
 232       1)
 233         AC_MSG_RESULT([no])
 234         $5
 235         ;;
 236       *)
 237         AC_MSG_ERROR([grep exited with status $status])
 238         ;;
 239     esac
 240   else
 241     AC_MSG_RESULT([file not found])
 242     $5
 243   fi
 244 ])
 245
 246 dnl OVS_DEFINE(NAME)
 247 dnl
 248 dnl Defines NAME to 1 in kcompat.h.
 249 AC_DEFUN([OVS_DEFINE], [
 250   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 251 ])
 252
 253 AC_DEFUN([OVS_CHECK_LOG2_H], [
 254   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 255   if test -e $KSRC/include/linux/log2.h; then
 256     AC_MSG_RESULT([yes])
 257     OVS_DEFINE([HAVE_LOG2_H])
 258   else
 259     AC_MSG_RESULT([no])
 260   fi
 261 ])
 262
 263 dnl OVS_CHECK_LINUX_COMPAT
 264 dnl
 265 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 266 dnl the directory in $KBUILD.
 267 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 268   rm -f datapath/linux/kcompat.h.new
 269   mkdir -p datapath/linux
 270   : > datapath/linux/kcompat.h.new
 271
 272   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 273                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 274
 275   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 276   OVS_GREP_IFELSE([$KSRC/include/linux/hash.h], [fast_hash_ops])
 277
 278   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 279   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 280
 281   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 282
 283   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 284   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 285                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 286
 287   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 288   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 289   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 290   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 291   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 292   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 293   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 294
 295   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 296
 297   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 298                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 299                                    [rcu_read_lock_held])])
 300   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 301
 302   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 303   # is necessary because some versions of this header remove the
 304   # member but retain the kerneldoc comment that describes it (which
 305   # starts with @).  The brackets must be doubled because of m4
 306   # quoting rules.
 307   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 308                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 309   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 310   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 311                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 312   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 313                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 314   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 315                   [skb_copy_from_linear_data_offset])
 316   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 317                   [skb_reset_tail_pointer])
 318   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 319   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 320                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 321   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 322                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 323   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 324                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 325   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 326   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 327   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 328   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 329   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 330   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 331   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 332   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 333   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 334   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 335                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 336   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [l4_rxhash])
 337
 338   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 339                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 340   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 341                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 342   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 343                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 344
 345   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 346   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 347
 348   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 349   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 350   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*genl_family],
 351                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 352
 353   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 354                         [genl_multicast_group], [id])
 355
 356   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 357   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 358   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [iptunnel_xmit.*net],
 359                   [OVS_DEFINE([HAVE_IPTUNNEL_XMIT_NET])])
 360   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [iptunnel_xmit.*sock],
 361                   [OVS_DEFINE([HAVE_IPTUNNEL_XMIT_SOCK])])
 362
 363   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 364   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 365   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 366   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 367   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 368   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 369   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_xmit_skb])
 370   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_xmit_skb.*net],
 371                   [OVS_DEFINE([HAVE_VXLAN_XMIT_SKB_NET])])
 372
 373   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 374                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 375                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 376
 377   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 378
 379   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 380                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 381
 382   OVS_GREP_IFELSE([$KSRC/include/linux/percpu.h], [this_cpu_ptr])
 383
 384   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 385
 386   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 387                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 388
 389   OVS_CHECK_LOG2_H
 390
 391   if cmp -s datapath/linux/kcompat.h.new \
 392             datapath/linux/kcompat.h >/dev/null 2>&1; then
 393     rm datapath/linux/kcompat.h.new
 394   else
 395     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 396   fi
 397 ])
 398
 399 dnl Checks for net/if_packet.h.
 400 AC_DEFUN([OVS_CHECK_IF_PACKET],
 401   [AC_CHECK_HEADER([net/if_packet.h],
 402                    [HAVE_IF_PACKET=yes],
 403                    [HAVE_IF_PACKET=no])
 404    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 405    if test "$HAVE_IF_PACKET" = yes; then
 406       AC_DEFINE([HAVE_IF_PACKET], [1],
 407                 [Define to 1 if net/if_packet.h is available.])
 408    fi])
 409
 410 dnl Checks for net/if_dl.h.
 411 dnl
 412 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 413 dnl or NetBSD.)
 414 AC_DEFUN([OVS_CHECK_IF_DL],
 415   [AC_CHECK_HEADER([net/if_dl.h],
 416                    [HAVE_IF_DL=yes],
 417                    [HAVE_IF_DL=no])
 418    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 419    if test "$HAVE_IF_DL" = yes; then
 420       AC_DEFINE([HAVE_IF_DL], [1],
 421                 [Define to 1 if net/if_dl.h is available.])
 422
 423       # On these platforms we use libpcap to access network devices.
 424       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 425    fi])
 426
 427 dnl Checks for buggy strtok_r.
 428 dnl
 429 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 430 dnl with optimization that can cause segfaults:
 431 dnl
 432 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 433 AC_DEFUN([OVS_CHECK_STRTOK_R],
 434   [AC_CACHE_CHECK(
 435      [whether strtok_r macro segfaults on some inputs],
 436      [ovs_cv_strtok_r_bug],
 437      [AC_RUN_IFELSE(
 438         [AC_LANG_PROGRAM([#include <stdio.h>
 439                           #include <string.h>
 440                          ],
 441                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 442                            /* Assume bug is present, because relatively minor
 443                               changes in compiler settings (e.g. optimization
 444                               level) can make it crop up. */
 445                            return 1;
 446                            #else
 447                            char string[] = ":::";
 448                            char *save_ptr = (char *) 0xc0ffee;
 449                            char *token1, *token2;
 450                            token1 = strtok_r(string, ":", &save_ptr);
 451                            token2 = strtok_r(NULL, ":", &save_ptr);
 452                            freopen ("/dev/null", "w", stdout);
 453                            printf ("%s %s\n", token1, token2);
 454                            return 0;
 455                            #endif
 456                           ]])],
 457         [ovs_cv_strtok_r_bug=no],
 458         [ovs_cv_strtok_r_bug=yes],
 459         [ovs_cv_strtok_r_bug=yes])])
 460    if test $ovs_cv_strtok_r_bug = yes; then
 461      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 462                [Define if strtok_r macro segfaults on some inputs])
 463    fi
 464 ])
 465
 466 dnl ----------------------------------------------------------------------
 467 dnl These macros are from GNU PSPP, with the following original license:
 468 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 469 dnl This file is free software; the Free Software Foundation
 470 dnl gives unlimited permission to copy and/or distribute it,
 471 dnl with or without modifications, as long as this notice is preserved.
 472
 473 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 474   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 475   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 476     [ovs_save_CFLAGS="$CFLAGS"
 477      dnl Include -Werror in the compiler options, because without -Werror
 478      dnl clang's GCC-compatible compiler driver does not return a failure
 479      dnl exit status even though it complains about options it does not
 480      dnl understand.
 481      CFLAGS="$CFLAGS $WERROR $1"
 482      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 483      CFLAGS="$ovs_save_CFLAGS"])
 484   if test $ovs_cv_name = yes; then
 485     m4_if([$2], [], [:], [$2])
 486   else
 487     m4_if([$3], [], [:], [$3])
 488   fi
 489 ])
 490
 491 dnl OVS_CHECK_WERROR
 492 dnl
 493 dnl Check whether the C compiler accepts -Werror.
 494 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 495 AC_DEFUN([OVS_CHECK_WERROR],
 496   [WERROR=
 497    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 498
 499 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 500 dnl Check whether the given C compiler OPTION is accepted.
 501 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 502 AC_DEFUN([OVS_CHECK_CC_OPTION],
 503   [AC_REQUIRE([OVS_CHECK_WERROR])
 504    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 505
 506 dnl OVS_ENABLE_OPTION([OPTION])
 507 dnl Check whether the given C compiler OPTION is accepted.
 508 dnl If so, add it to WARNING_FLAGS.
 509 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 510 AC_DEFUN([OVS_ENABLE_OPTION],
 511   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 512    AC_SUBST([WARNING_FLAGS])])
 513
 514 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 515 dnl Check whether the given C compiler OPTION is accepted.
 516 dnl If so, enable the given Automake CONDITIONAL.
 517
 518 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 519 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 520   [OVS_CHECK_CC_OPTION(
 521     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 522    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 523 dnl ----------------------------------------------------------------------
 524
 525 dnl Check for too-old XenServer.
 526 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 527   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 528     [if test -e /etc/redhat-release; then
 529        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 530      fi
 531      if test -z "$ovs_cv_xsversion"; then
 532        ovs_cv_xsversion=none
 533      fi])
 534   case $ovs_cv_xsversion in
 535     none)
 536       ;;
 537
 538     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 539     [[6-9]]* |                           dnl XenServer 6 or later
 540     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 541     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 542     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 543     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 544       ;;
 545
 546     *)
 547       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 548       ;;
 549   esac])
 550
 551 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 552 dnl
 553 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 554 dnl Runs 'if-true' if so, 'if-false' otherwise.
 555 AC_DEFUN([OVS_CHECK_MAKE_IF],
 556   [AC_CACHE_CHECK(
 557      [whether ${MAKE-make} has GNU make \$(if) extension],
 558      [ovs_cv_gnu_make_if],
 559      [cat <<'EOF' > conftest.mk
 560 conftest.out:
 561         echo $(if x,y,z) > conftest.out
 562 .PHONY: all
 563 EOF
 564       rm -f conftest.out
 565       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 566       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 567       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 568       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 569       result=`cat conftest.out`
 570       rm -f conftest.mk conftest.out
 571       if test "X$result" = "Xy"; then
 572         ovs_cv_gnu_make_if=yes
 573       else
 574         ovs_cv_gnu_make_if=no
 575       fi])])
 576
 577 dnl OVS_CHECK_GNU_MAKE
 578 dnl
 579 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 580 dnl only work with GNU make).
 581 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 582   [AC_CACHE_CHECK(
 583      [whether ${MAKE-make} is GNU make],
 584      [ovs_cv_gnu_make],
 585      [rm -f conftest.out
 586       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 587       ${MAKE-make} --version >conftest.out 2>&1
 588       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 589       result=`cat conftest.out`
 590       rm -f conftest.mk conftest.out
 591
 592       case $result in # (
 593         GNU*) ovs_cv_gnu_make=yes ;; # (
 594         *) ovs_cv_gnu_make=no ;;
 595       esac])
 596    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 597
 598 dnl OVS_CHECK_SPARSE_TARGET
 599 dnl
 600 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 601 dnl target for which the code is being built.  This helps it out.
 602 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 603   [AC_CACHE_CHECK(
 604     [target hint for cgcc],
 605     [ac_cv_sparse_target],
 606     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 607        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 608        [x86_64-*], [ac_cv_sparse_target=x86_64],
 609        [ac_cv_sparse_target=other])])
 610    AS_CASE([$ac_cv_sparse_target],
 611      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 612      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 613      [SPARSEFLAGS= CGCCFLAGS=])
 614    AC_SUBST([SPARSEFLAGS])
 615    AC_SUBST([CGCCFLAGS])])
 616
 617 dnl OVS_SPARSE_EXTRA_INCLUDES
 618 dnl
 619 dnl The cgcc script from "sparse" does not search gcc's default
 620 dnl search path. Get the default search path from GCC and pass
 621 dnl them to sparse.
 622 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 623     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 624            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 625
 626 dnl OVS_ENABLE_SPARSE
 627 AC_DEFUN([OVS_ENABLE_SPARSE],
 628   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 629    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 630    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 631    : ${SPARSE=sparse}
 632    AC_SUBST([SPARSE])
 633    AC_CONFIG_COMMANDS_PRE(
 634      [if test $ovs_cv_gnu_make_if = yes; then
 635         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 636       fi])])
 637
 638 dnl OVS_PTHREAD_SET_NAME
 639 dnl
 640 dnl This checks for three known variants of pthreads functions for setting
 641 dnl the name of the current thread:
 642 dnl
 643 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 644 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 645 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 646 dnl
 647 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 648 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 649 dnl provide to it.
 650 dnl
 651 dnl This macro defines:
 652 dnl
 653 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 654 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 655 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 656 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 657   [AC_CHECK_FUNCS([pthread_set_name_np])
 658    if test $ac_cv_func_pthread_set_name_np != yes; then
 659      AC_CACHE_CHECK(
 660        [for pthread_setname_np() variant],
 661        [ovs_cv_pthread_setname_np],
 662        [AC_LINK_IFELSE(
 663          [AC_LANG_PROGRAM([#include <pthread.h>
 664   ], [pthread_setname_np(pthread_self(), "name");])],
 665          [ovs_cv_pthread_setname_np=glibc],
 666          [AC_LINK_IFELSE(
 667            [AC_LANG_PROGRAM([#include <pthread.h>
 668 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 669            [ovs_cv_pthread_setname_np=netbsd],
 670            [ovs_cv_pthread_setname_np=none])])])
 671      case $ovs_cv_pthread_setname_np in # (
 672        glibc)
 673           AC_DEFINE(
 674             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 675             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 676           ;; # (
 677        netbsd)
 678           AC_DEFINE(
 679             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 680             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 681           ;;
 682      esac
 683    fi])
 684
 685 dnl OVS_CHECK_LINUX_HOST.
 686 dnl
 687 dnl Checks whether we're building for a Linux host, based on the presence of
 688 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 689 dnl LINUX based on the result.
 690 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 691   [AC_CACHE_CHECK(
 692      [whether __linux__ is defined],
 693      [ovs_cv_linux],
 694      [AC_COMPILE_IFELSE(
 695         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 696         [ovs_cv_linux=true],
 697         [ovs_cv_linux=false])])
 698    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])