acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        if test "$version" = 3 && test "$patchlevel" -le 11; then
 138           : # Linux 3.x
 139        else
 140          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 3.11.x is not supported])
 141        fi
 142     else
 143        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 144          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 145        else
 146          : # Linux 2.6.x
 147        fi
 148     fi
 149     if (test ! -e "$KBUILD"/include/linux/version.h && \
 150         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 151        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 152         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 153         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 154     fi
 155     OVS_CHECK_LINUX_COMPAT
 156   fi
 157   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 158 ])
 159
 160 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 161 dnl
 162 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 163 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 164 dnl <REGEX> translated to uppercase.
 165 AC_DEFUN([OVS_GREP_IFELSE], [
 166   AC_MSG_CHECKING([whether $2 matches in $1])
 167   if test -f $1; then
 168     grep '$2' $1 >/dev/null 2>&1
 169     status=$?
 170     case $status in
 171       0)
 172         AC_MSG_RESULT([yes])
 173         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 174         ;;
 175       1)
 176         AC_MSG_RESULT([no])
 177         $4
 178         ;;
 179       *)
 180         AC_MSG_ERROR([grep exited with status $status])
 181         ;;
 182     esac
 183   else
 184     AC_MSG_RESULT([file not found])
 185     $4
 186   fi
 187 ])
 188
 189 dnl OVS_DEFINE(NAME)
 190 dnl
 191 dnl Defines NAME to 1 in kcompat.h.
 192 AC_DEFUN([OVS_DEFINE], [
 193   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 194 ])
 195
 196 AC_DEFUN([OVS_CHECK_LOG2_H], [
 197   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 198   if test -e $KSRC/include/linux/log2.h; then
 199     AC_MSG_RESULT([yes])
 200     OVS_DEFINE([HAVE_LOG2_H])
 201   else
 202     AC_MSG_RESULT([no])
 203   fi
 204 ])
 205
 206 dnl OVS_CHECK_LINUX_COMPAT
 207 dnl
 208 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 209 dnl the directory in $KBUILD.
 210 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 211   rm -f datapath/linux/kcompat.h.new
 212   mkdir -p datapath/linux
 213   : > datapath/linux/kcompat.h.new
 214
 215   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 216                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 217
 218   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 219
 220   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 221
 222   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 223
 224   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 225
 226   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 227   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 228   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 229   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 230   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 231   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 232
 233   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 234                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 235                                    [rcu_read_lock_held])])
 236   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 237
 238   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 239   # is necessary because some versions of this header remove the
 240   # member but retain the kerneldoc comment that describes it (which
 241   # starts with @).  The brackets must be doubled because of m4
 242   # quoting rules.
 243   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 244                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 245   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 246   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 247                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 248   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 249                   [skb_copy_from_linear_data_offset])
 250   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 251                   [skb_reset_tail_pointer])
 252   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 253   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 254                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 255   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 256                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 257   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 258                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 259   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 260   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 261   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 262   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 263   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 264   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 265   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 266
 267   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 268                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 269   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 270                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 271   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 272                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 273
 274   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 275   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 276
 277   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 278   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 279   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 280   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 281   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 282   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 283   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 284
 285   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 286
 287   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 288                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 289
 290   OVS_GREP_IFELSE([$KSRC/include/linux/percpu.h], [this_cpu_ptr])
 291
 292   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 293                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 294
 295   OVS_CHECK_LOG2_H
 296
 297   if cmp -s datapath/linux/kcompat.h.new \
 298             datapath/linux/kcompat.h >/dev/null 2>&1; then
 299     rm datapath/linux/kcompat.h.new
 300   else
 301     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 302   fi
 303 ])
 304
 305 dnl Checks for net/if_packet.h.
 306 AC_DEFUN([OVS_CHECK_IF_PACKET],
 307   [AC_CHECK_HEADER([net/if_packet.h],
 308                    [HAVE_IF_PACKET=yes],
 309                    [HAVE_IF_PACKET=no])
 310    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 311    if test "$HAVE_IF_PACKET" = yes; then
 312       AC_DEFINE([HAVE_IF_PACKET], [1],
 313                 [Define to 1 if net/if_packet.h is available.])
 314    fi])
 315
 316 dnl Checks for net/if_dl.h.
 317 dnl
 318 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 319 dnl or NetBSD.)
 320 AC_DEFUN([OVS_CHECK_IF_DL],
 321   [AC_CHECK_HEADER([net/if_dl.h],
 322                    [HAVE_IF_DL=yes],
 323                    [HAVE_IF_DL=no])
 324    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 325    if test "$HAVE_IF_DL" = yes; then
 326       AC_DEFINE([HAVE_IF_DL], [1],
 327                 [Define to 1 if net/if_dl.h is available.])
 328
 329       # On these platforms we use libpcap to access network devices.
 330       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 331    fi])
 332
 333 dnl Checks for buggy strtok_r.
 334 dnl
 335 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 336 dnl with optimization that can cause segfaults:
 337 dnl
 338 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 339 AC_DEFUN([OVS_CHECK_STRTOK_R],
 340   [AC_CACHE_CHECK(
 341      [whether strtok_r macro segfaults on some inputs],
 342      [ovs_cv_strtok_r_bug],
 343      [AC_RUN_IFELSE(
 344         [AC_LANG_PROGRAM([#include <stdio.h>
 345                           #include <string.h>
 346                          ],
 347                          [[char string[] = ":::";
 348                            char *save_ptr = (char *) 0xc0ffee;
 349                            char *token1, *token2;
 350                            token1 = strtok_r(string, ":", &save_ptr);
 351                            token2 = strtok_r(NULL, ":", &save_ptr);
 352                            freopen ("/dev/null", "w", stdout);
 353                            printf ("%s %s\n", token1, token2);
 354                            return 0;
 355                           ]])],
 356         [ovs_cv_strtok_r_bug=no],
 357         [ovs_cv_strtok_r_bug=yes],
 358         [ovs_cv_strtok_r_bug=yes])])
 359    if test $ovs_cv_strtok_r_bug = yes; then
 360      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 361                [Define if strtok_r macro segfaults on some inputs])
 362    fi
 363 ])
 364
 365 dnl ----------------------------------------------------------------------
 366 dnl These macros are from GNU PSPP, with the following original license:
 367 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 368 dnl This file is free software; the Free Software Foundation
 369 dnl gives unlimited permission to copy and/or distribute it,
 370 dnl with or without modifications, as long as this notice is preserved.
 371
 372 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 373   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 374   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 375     [ovs_save_CFLAGS="$CFLAGS"
 376      dnl Include -Werror in the compiler options, because without -Werror
 377      dnl clang's GCC-compatible compiler driver does not return a failure
 378      dnl exit status even though it complains about options it does not
 379      dnl understand.
 380      CFLAGS="$CFLAGS $WERROR $1"
 381      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 382      CFLAGS="$ovs_save_CFLAGS"])
 383   if test $ovs_cv_name = yes; then
 384     m4_if([$2], [], [:], [$2])
 385   else
 386     m4_if([$3], [], [:], [$3])
 387   fi
 388 ])
 389
 390 dnl OVS_CHECK_WERROR
 391 dnl
 392 dnl Check whether the C compiler accepts -Werror.
 393 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 394 AC_DEFUN([OVS_CHECK_WERROR],
 395   [WERROR=
 396    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 397
 398 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 399 dnl Check whether the given C compiler OPTION is accepted.
 400 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 401 AC_DEFUN([OVS_CHECK_CC_OPTION],
 402   [AC_REQUIRE([OVS_CHECK_WERROR])
 403    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 404
 405 dnl OVS_ENABLE_OPTION([OPTION])
 406 dnl Check whether the given C compiler OPTION is accepted.
 407 dnl If so, add it to WARNING_FLAGS.
 408 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 409 AC_DEFUN([OVS_ENABLE_OPTION],
 410   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 411    AC_SUBST([WARNING_FLAGS])])
 412
 413 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 414 dnl Check whether the given C compiler OPTION is accepted.
 415 dnl If so, enable the given Automake CONDITIONAL.
 416
 417 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 418 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 419   [OVS_CHECK_CC_OPTION(
 420     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 421    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 422 dnl ----------------------------------------------------------------------
 423
 424 dnl Check for too-old XenServer.
 425 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 426   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 427     [if test -e /etc/redhat-release; then
 428        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 429      fi
 430      if test -z "$ovs_cv_xsversion"; then
 431        ovs_cv_xsversion=none
 432      fi])
 433   case $ovs_cv_xsversion in
 434     none)
 435       ;;
 436
 437     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 438     [[6-9]]* |                           dnl XenServer 6 or later
 439     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 440     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 441     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 442     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 443       ;;
 444
 445     *)
 446       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 447       ;;
 448   esac])
 449
 450 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 451 dnl
 452 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 453 dnl Runs 'if-true' if so, 'if-false' otherwise.
 454 AC_DEFUN([OVS_CHECK_MAKE_IF],
 455   [AC_CACHE_CHECK(
 456      [whether ${MAKE-make} has GNU make \$(if) extension],
 457      [ovs_cv_gnu_make_if],
 458      [cat <<'EOF' > conftest.mk
 459 conftest.out:
 460         echo $(if x,y,z) > conftest.out
 461 .PHONY: all
 462 EOF
 463       rm -f conftest.out
 464       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 465       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 466       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 467       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 468       result=`cat conftest.out`
 469       rm -f conftest.mk conftest.out
 470       if test "X$result" = "Xy"; then
 471         ovs_cv_gnu_make_if=yes
 472       else
 473         ovs_cv_gnu_make_if=no
 474       fi])])
 475
 476 dnl OVS_CHECK_GNU_MAKE
 477 dnl
 478 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 479 dnl only work with GNU make).
 480 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 481   [AC_CACHE_CHECK(
 482      [whether ${MAKE-make} is GNU make],
 483      [ovs_cv_gnu_make],
 484      [rm -f conftest.out
 485       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 486       ${MAKE-make} --version >conftest.out 2>&1
 487       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 488       result=`cat conftest.out`
 489       rm -f conftest.mk conftest.out
 490
 491       case $result in # (
 492         GNU*) ovs_cv_gnu_make=yes ;; # (
 493         *) ovs_cv_gnu_make=no ;;
 494       esac])
 495    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 496
 497 dnl OVS_CHECK_SPARSE_TARGET
 498 dnl
 499 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 500 dnl target for which the code is being built.  This helps it out.
 501 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 502   [AC_CACHE_CHECK(
 503     [target hint for cgcc],
 504     [ac_cv_sparse_target],
 505     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 506        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 507        [x86_64-*], [ac_cv_sparse_target=x86_64],
 508        [ac_cv_sparse_target=other])])
 509    AS_CASE([$ac_cv_sparse_target],
 510      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 511      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 512      [SPARSEFLAGS= CGCCFLAGS=])
 513    AC_SUBST([SPARSEFLAGS])
 514    AC_SUBST([CGCCFLAGS])])
 515
 516 dnl OVS_SPARSE_EXTRA_INCLUDES
 517 dnl
 518 dnl The cgcc script from "sparse" does not search gcc's default
 519 dnl search path. Get the default search path from GCC and pass
 520 dnl them to sparse.
 521 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 522     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 523            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 524
 525 dnl OVS_ENABLE_SPARSE
 526 AC_DEFUN([OVS_ENABLE_SPARSE],
 527   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 528    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 529    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 530    : ${SPARSE=sparse}
 531    AC_SUBST([SPARSE])
 532    AC_CONFIG_COMMANDS_PRE(
 533      [if test $ovs_cv_gnu_make_if = yes; then
 534         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 535       fi])])
 536
 537 dnl OVS_PTHREAD_SET_NAME
 538 dnl
 539 dnl This checks for three known variants of pthreads functions for setting
 540 dnl the name of the current thread:
 541 dnl
 542 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 543 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 544 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 545 dnl
 546 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 547 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 548 dnl provide to it.
 549 dnl
 550 dnl This macro defines:
 551 dnl
 552 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 553 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 554 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 555 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 556   [AC_CHECK_FUNCS([pthread_set_name_np])
 557    if test $ac_cv_func_pthread_set_name_np != yes; then
 558      AC_CACHE_CHECK(
 559        [for pthread_setname_np() variant],
 560        [ovs_cv_pthread_setname_np],
 561        [AC_LINK_IFELSE(
 562          [AC_LANG_PROGRAM([#include <pthread.h>
 563   ], [pthread_setname_np(pthread_self(), "name");])],
 564          [ovs_cv_pthread_setname_np=glibc],
 565          [AC_LINK_IFELSE(
 566            [AC_LANG_PROGRAM([#include <pthread.h>
 567 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 568            [ovs_cv_pthread_setname_np=netbsd],
 569            [ovs_cv_pthread_setname_np=none])])])
 570      case $ovs_cv_pthread_setname_np in # (
 571        glibc)
 572           AC_DEFINE(
 573             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 574             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 575           ;; # (
 576        netbsd)
 577           AC_DEFINE(
 578             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 579             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 580           ;;
 581      esac
 582    fi])