acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        : # Linux 3.x
 138     elif test "$version" = 2 && test "$patchlevel" -ge 6; then
 139        : # Linux 2.6.x
 140     else
 141        if test "$KBUILD" = "$KSRC"; then
 142          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6 or later is required])
 143        else
 144          AC_ERROR([Linux kernel in build tree $KBUILD (source tree $KSRC) is version $kversion, but version 2.6 or later is required])
 145        fi
 146     fi
 147     if (test ! -e "$KBUILD"/include/linux/version.h && \
 148         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 149        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 150         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 151         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 152     fi
 153     OVS_CHECK_LINUX_COMPAT
 154   fi
 155   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 156 ])
 157
 158 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 159 dnl
 160 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 161 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 162 dnl <REGEX> translated to uppercase.
 163 AC_DEFUN([OVS_GREP_IFELSE], [
 164   AC_MSG_CHECKING([whether $2 matches in $1])
 165   if test -f $1; then
 166     grep '$2' $1 >/dev/null 2>&1
 167     status=$?
 168     case $status in
 169       0)
 170         AC_MSG_RESULT([yes])
 171         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 172         ;;
 173       1)
 174         AC_MSG_RESULT([no])
 175         $4
 176         ;;
 177       *)
 178         AC_MSG_ERROR([grep exited with status $status])
 179         ;;
 180     esac
 181   else
 182     AC_MSG_RESULT([file not found])
 183     $4
 184   fi
 185 ])
 186
 187 dnl OVS_DEFINE(NAME)
 188 dnl
 189 dnl Defines NAME to 1 in kcompat.h.
 190 AC_DEFUN([OVS_DEFINE], [
 191   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 192 ])
 193
 194 AC_DEFUN([OVS_CHECK_LOG2_H], [
 195   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 196   if test -e $KSRC/include/linux/log2.h; then
 197     AC_MSG_RESULT([yes])
 198     OVS_DEFINE([HAVE_LOG2_H])
 199   else
 200     AC_MSG_RESULT([no])
 201   fi
 202 ])
 203
 204 dnl OVS_CHECK_LINUX_COMPAT
 205 dnl
 206 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 207 dnl the directory in $KBUILD.
 208 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 209   rm -f datapath/linux/kcompat.h.new
 210   mkdir -p datapath/linux
 211   : > datapath/linux/kcompat.h.new
 212
 213   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 214                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 215
 216   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 217
 218   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 219
 220   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 221
 222   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 223
 224   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 225   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 226   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 227   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 228
 229   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 230                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 231                                    [rcu_read_lock_held])])
 232
 233   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 234   # is necessary because some versions of this header remove the
 235   # member but retain the kerneldoc comment that describes it (which
 236   # starts with @).  The brackets must be doubled because of m4
 237   # quoting rules.
 238   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 239                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 240   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [raw],
 241                   [OVS_DEFINE([HAVE_MAC_RAW])])
 242   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 243                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 244   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 245                   [skb_copy_from_linear_data_offset])
 246   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 247                   [skb_reset_tail_pointer])
 248   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 249   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 250                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 251   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 252                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 253   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 254                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 255   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 256   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 257   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 258
 259   OVS_GREP_IFELSE([$KSRC/include/linux/string.h], [kmemdup], [],
 260                   [OVS_GREP_IFELSE([$KSRC/include/linux/slab.h], [kmemdup])])
 261
 262   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 263                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 264   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 265                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 266   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 267                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 268
 269   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 270   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 271
 272   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [NLA_NUL_STRING])
 273   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 274   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 275   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 276   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 277   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 278
 279   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 280                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 281
 282   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 283                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 284
 285   OVS_CHECK_LOG2_H
 286
 287   if cmp -s datapath/linux/kcompat.h.new \
 288             datapath/linux/kcompat.h >/dev/null 2>&1; then
 289     rm datapath/linux/kcompat.h.new
 290   else
 291     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 292   fi
 293 ])
 294
 295 dnl Checks for net/if_packet.h.
 296 AC_DEFUN([OVS_CHECK_IF_PACKET],
 297   [AC_CHECK_HEADER([net/if_packet.h],
 298                    [HAVE_IF_PACKET=yes],
 299                    [HAVE_IF_PACKET=no])
 300    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 301    if test "$HAVE_IF_PACKET" = yes; then
 302       AC_DEFINE([HAVE_IF_PACKET], [1],
 303                 [Define to 1 if net/if_packet.h is available.])
 304    fi])
 305
 306 dnl Checks for net/if_dl.h.
 307 AC_DEFUN([OVS_CHECK_IF_DL],
 308   [AC_CHECK_HEADER([net/if_dl.h],
 309                    [HAVE_IF_DL=yes],
 310                    [HAVE_IF_DL=no])
 311    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 312    if test "$HAVE_IF_DL" = yes; then
 313       AC_DEFINE([HAVE_IF_DL], [1],
 314                 [Define to 1 if net/if_dl.h is available.])
 315    fi])
 316
 317 dnl Checks for buggy strtok_r.
 318 dnl
 319 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 320 dnl with optimization that can cause segfaults:
 321 dnl
 322 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 323 AC_DEFUN([OVS_CHECK_STRTOK_R],
 324   [AC_CACHE_CHECK(
 325      [whether strtok_r macro segfaults on some inputs],
 326      [ovs_cv_strtok_r_bug],
 327      [AC_RUN_IFELSE(
 328         [AC_LANG_PROGRAM([#include <stdio.h>
 329                           #include <string.h>
 330                          ],
 331                          [[char string[] = ":::";
 332                            char *save_ptr = (char *) 0xc0ffee;
 333                            char *token1, *token2;
 334                            token1 = strtok_r(string, ":", &save_ptr);
 335                            token2 = strtok_r(NULL, ":", &save_ptr);
 336                            freopen ("/dev/null", "w", stdout);
 337                            printf ("%s %s\n", token1, token2);
 338                            return 0;
 339                           ]])],
 340         [ovs_cv_strtok_r_bug=no],
 341         [ovs_cv_strtok_r_bug=yes],
 342         [ovs_cv_strtok_r_bug=yes])])
 343    if test $ovs_cv_strtok_r_bug = yes; then
 344      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 345                [Define if strtok_r macro segfaults on some inputs])
 346    fi
 347 ])
 348
 349 dnl ----------------------------------------------------------------------
 350 dnl These macros are from GNU PSPP, with the following original license:
 351 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 352 dnl This file is free software; the Free Software Foundation
 353 dnl gives unlimited permission to copy and/or distribute it,
 354 dnl with or without modifications, as long as this notice is preserved.
 355
 356 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 357 dnl Check whether the given C compiler OPTION is accepted.
 358 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 359 AC_DEFUN([OVS_CHECK_CC_OPTION],
 360 [
 361   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 362   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 363     [ovs_save_CFLAGS="$CFLAGS"
 364      CFLAGS="$CFLAGS $1"
 365      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 366      CFLAGS="$ovs_save_CFLAGS"])
 367   if test $ovs_cv_name = yes; then
 368     m4_if([$2], [], [:], [$2])
 369   else
 370     m4_if([$3], [], [:], [$3])
 371   fi
 372 ])
 373
 374 dnl OVS_ENABLE_OPTION([OPTION])
 375 dnl Check whether the given C compiler OPTION is accepted.
 376 dnl If so, add it to WARNING_FLAGS.
 377 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 378 AC_DEFUN([OVS_ENABLE_OPTION],
 379   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 380    AC_SUBST([WARNING_FLAGS])])
 381
 382 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 383 dnl Check whether the given C compiler OPTION is accepted.
 384 dnl If so, enable the given Automake CONDITIONAL.
 385
 386 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 387 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 388   [OVS_CHECK_CC_OPTION(
 389     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 390    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 391 dnl ----------------------------------------------------------------------
 392
 393 dnl Check for too-old XenServer.
 394 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 395   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 396     [if test -e /etc/redhat-release; then
 397        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 398      fi
 399      if test -z "$ovs_cv_xsversion"; then
 400        ovs_cv_xsversion=none
 401      fi])
 402   case $ovs_cv_xsversion in
 403     none)
 404       ;;
 405
 406     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 407     [[6-9]]* |                           dnl XenServer 6 or later
 408     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 409     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 410     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 411     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 412       ;;
 413
 414     *)
 415       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 416       ;;
 417   esac])
 418
 419 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 420 dnl
 421 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 422 dnl Runs 'if-true' if so, 'if-false' otherwise.
 423 AC_DEFUN([OVS_CHECK_MAKE_IF],
 424   [AC_CACHE_CHECK(
 425      [whether ${MAKE-make} has GNU make \$(if) extension],
 426      [ovs_cv_gnu_make_if],
 427      [cat <<'EOF' > conftest.mk
 428 conftest.out:
 429         echo $(if x,y,z) > conftest.out
 430 .PHONY: all
 431 EOF
 432       rm -f conftest.out
 433       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 434       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 435       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 436       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 437       result=`cat conftest.out`
 438       rm -f conftest.mk conftest.out
 439       if test "X$result" = "Xy"; then
 440         ovs_cv_gnu_make_if=yes
 441       else
 442         ovs_cv_gnu_make_if=no
 443       fi])])
 444
 445 dnl OVS_CHECK_GNU_MAKE
 446 dnl
 447 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 448 dnl only work with GNU make).
 449 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 450   [AC_CACHE_CHECK(
 451      [whether ${MAKE-make} is GNU make],
 452      [ovs_cv_gnu_make],
 453      [rm -f conftest.out
 454       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 455       ${MAKE-make} --version >conftest.out 2>&1
 456       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 457       result=`cat conftest.out`
 458       rm -f conftest.mk conftest.out
 459
 460       case $result in # (
 461         GNU*) ovs_cv_gnu_make=yes ;; # (
 462         *) ovs_cv_gnu_make=no ;;
 463       esac])
 464    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 465
 466 dnl OVS_CHECK_SPARSE_TARGET
 467 dnl
 468 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 469 dnl target for which the code is being built.  This helps it out.
 470 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 471   [AC_CACHE_CHECK(
 472     [target hint for cgcc],
 473     [ac_cv_sparse_target],
 474     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 475        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 476        [x86_64-*], [ac_cv_sparse_target=x86_64],
 477        [ac_cv_sparse_target=other])])
 478    AS_CASE([$ac_cv_sparse_target],
 479      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 480      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 481      [SPARSEFLAGS= CGCCFLAGS=])
 482    AC_SUBST([SPARSEFLAGS])
 483    AC_SUBST([CGCCFLAGS])])
 484
 485 dnl OVS_ENABLE_SPARSE
 486 AC_DEFUN([OVS_ENABLE_SPARSE],
 487   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 488    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 489    : ${SPARSE=sparse}
 490    AC_SUBST([SPARSE])
 491    AC_CONFIG_COMMANDS_PRE(
 492      [if test $ovs_cv_gnu_make_if = yes; then
 493         CC='$(if $(C),REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS)" cgcc $(CGCCFLAGS),'"$CC"')'
 494       fi])])