acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        : # Linux 3.x
 138     elif test "$version" = 2 && test "$patchlevel" -ge 6; then
 139        : # Linux 2.6.x
 140     else
 141        if test "$KBUILD" = "$KSRC"; then
 142          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6 or later is required])
 143        else
 144          AC_ERROR([Linux kernel in build tree $KBUILD (source tree $KSRC) is version $kversion, but version 2.6 or later is required])
 145        fi
 146     fi
 147     if (test ! -e "$KBUILD"/include/linux/version.h && \
 148         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 149        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 150         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 151         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 152     fi
 153     OVS_CHECK_LINUX_COMPAT
 154   fi
 155   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 156 ])
 157
 158 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 159 dnl
 160 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 161 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 162 dnl <REGEX> translated to uppercase.
 163 AC_DEFUN([OVS_GREP_IFELSE], [
 164   AC_MSG_CHECKING([whether $2 matches in $1])
 165   if test -f $1; then
 166     grep '$2' $1 >/dev/null 2>&1
 167     status=$?
 168     case $status in
 169       0)
 170         AC_MSG_RESULT([yes])
 171         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 172         ;;
 173       1)
 174         AC_MSG_RESULT([no])
 175         $4
 176         ;;
 177       *)
 178         AC_MSG_ERROR([grep exited with status $status])
 179         ;;
 180     esac
 181   else
 182     AC_MSG_RESULT([file not found])
 183     $4
 184   fi
 185 ])
 186
 187 dnl OVS_DEFINE(NAME)
 188 dnl
 189 dnl Defines NAME to 1 in kcompat.h.
 190 AC_DEFUN([OVS_DEFINE], [
 191   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 192 ])
 193
 194 AC_DEFUN([OVS_CHECK_LOG2_H], [
 195   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 196   if test -e $KSRC/include/linux/log2.h; then
 197     AC_MSG_RESULT([yes])
 198     OVS_DEFINE([HAVE_LOG2_H])
 199   else
 200     AC_MSG_RESULT([no])
 201   fi
 202 ])
 203
 204 dnl OVS_CHECK_LINUX_COMPAT
 205 dnl
 206 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 207 dnl the directory in $KBUILD.
 208 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 209   rm -f datapath/linux/kcompat.h.new
 210   mkdir -p datapath/linux
 211   : > datapath/linux/kcompat.h.new
 212
 213   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 214                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 215
 216   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 217
 218   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 219
 220   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 221
 222   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 223
 224   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 225   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 226   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 227
 228   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 229                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 230                                    [rcu_read_lock_held])])
 231
 232   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 233   # is necessary because some versions of this header remove the
 234   # member but retain the kerneldoc comment that describes it (which
 235   # starts with @).  The brackets must be doubled because of m4
 236   # quoting rules.
 237   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 238                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 239   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [raw],
 240                   [OVS_DEFINE([HAVE_MAC_RAW])])
 241   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 242                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 243   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 244                   [skb_copy_from_linear_data_offset])
 245   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 246                   [skb_reset_tail_pointer])
 247   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 248   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 249                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 250   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 251                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 252   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 253                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 254   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 255   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 256   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 257
 258   OVS_GREP_IFELSE([$KSRC/include/linux/string.h], [kmemdup], [],
 259                   [OVS_GREP_IFELSE([$KSRC/include/linux/slab.h], [kmemdup])])
 260
 261   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 262                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 263   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 264                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 265
 266   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 267   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 268
 269   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [NLA_NUL_STRING])
 270   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 271   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 272
 273   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 274                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 275
 276   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 277                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 278
 279   OVS_CHECK_LOG2_H
 280
 281   if cmp -s datapath/linux/kcompat.h.new \
 282             datapath/linux/kcompat.h >/dev/null 2>&1; then
 283     rm datapath/linux/kcompat.h.new
 284   else
 285     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 286   fi
 287 ])
 288
 289 dnl Checks for net/if_packet.h.
 290 AC_DEFUN([OVS_CHECK_IF_PACKET],
 291   [AC_CHECK_HEADER([net/if_packet.h],
 292                    [HAVE_IF_PACKET=yes],
 293                    [HAVE_IF_PACKET=no])
 294    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 295    if test "$HAVE_IF_PACKET" = yes; then
 296       AC_DEFINE([HAVE_IF_PACKET], [1],
 297                 [Define to 1 if net/if_packet.h is available.])
 298    fi])
 299
 300 dnl Checks for net/if_dl.h.
 301 AC_DEFUN([OVS_CHECK_IF_DL],
 302   [AC_CHECK_HEADER([net/if_dl.h],
 303                    [HAVE_IF_DL=yes],
 304                    [HAVE_IF_DL=no])
 305    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 306    if test "$HAVE_IF_DL" = yes; then
 307       AC_DEFINE([HAVE_IF_DL], [1],
 308                 [Define to 1 if net/if_dl.h is available.])
 309    fi])
 310
 311 dnl Checks for buggy strtok_r.
 312 dnl
 313 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 314 dnl with optimization that can cause segfaults:
 315 dnl
 316 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 317 AC_DEFUN([OVS_CHECK_STRTOK_R],
 318   [AC_CACHE_CHECK(
 319      [whether strtok_r macro segfaults on some inputs],
 320      [ovs_cv_strtok_r_bug],
 321      [AC_RUN_IFELSE(
 322         [AC_LANG_PROGRAM([#include <stdio.h>
 323                           #include <string.h>
 324                          ],
 325                          [[char string[] = ":::";
 326                            char *save_ptr = (char *) 0xc0ffee;
 327                            char *token1, *token2;
 328                            token1 = strtok_r(string, ":", &save_ptr);
 329                            token2 = strtok_r(NULL, ":", &save_ptr);
 330                            freopen ("/dev/null", "w", stdout);
 331                            printf ("%s %s\n", token1, token2);
 332                            return 0;
 333                           ]])],
 334         [ovs_cv_strtok_r_bug=no],
 335         [ovs_cv_strtok_r_bug=yes],
 336         [ovs_cv_strtok_r_bug=yes])])
 337    if test $ovs_cv_strtok_r_bug = yes; then
 338      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 339                [Define if strtok_r macro segfaults on some inputs])
 340    fi
 341 ])
 342
 343 dnl ----------------------------------------------------------------------
 344 dnl These macros are from GNU PSPP, with the following original license:
 345 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 346 dnl This file is free software; the Free Software Foundation
 347 dnl gives unlimited permission to copy and/or distribute it,
 348 dnl with or without modifications, as long as this notice is preserved.
 349
 350 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 351 dnl Check whether the given C compiler OPTION is accepted.
 352 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 353 AC_DEFUN([OVS_CHECK_CC_OPTION],
 354 [
 355   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 356   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 357     [ovs_save_CFLAGS="$CFLAGS"
 358      CFLAGS="$CFLAGS $1"
 359      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 360      CFLAGS="$ovs_save_CFLAGS"])
 361   if test $ovs_cv_name = yes; then
 362     m4_if([$2], [], [:], [$2])
 363   else
 364     m4_if([$3], [], [:], [$3])
 365   fi
 366 ])
 367
 368 dnl OVS_ENABLE_OPTION([OPTION])
 369 dnl Check whether the given C compiler OPTION is accepted.
 370 dnl If so, add it to WARNING_FLAGS.
 371 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 372 AC_DEFUN([OVS_ENABLE_OPTION],
 373   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 374    AC_SUBST([WARNING_FLAGS])])
 375
 376 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 377 dnl Check whether the given C compiler OPTION is accepted.
 378 dnl If so, enable the given Automake CONDITIONAL.
 379
 380 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 381 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 382   [OVS_CHECK_CC_OPTION(
 383     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 384    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 385 dnl ----------------------------------------------------------------------
 386
 387 dnl Check for too-old XenServer.
 388 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 389   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 390     [if test -e /etc/redhat-release; then
 391        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 392      fi
 393      if test -z "$ovs_cv_xsversion"; then
 394        ovs_cv_xsversion=none
 395      fi])
 396   case $ovs_cv_xsversion in
 397     none)
 398       ;;
 399
 400     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 401     [[6-9]]* |                           dnl XenServer 6 or later
 402     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 403     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 404     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 405     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 406       ;;
 407
 408     *)
 409       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 410       ;;
 411   esac])
 412
 413 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 414 dnl
 415 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 416 dnl Runs 'if-true' if so, 'if-false' otherwise.
 417 AC_DEFUN([OVS_CHECK_MAKE_IF],
 418   [AC_CACHE_CHECK(
 419      [whether ${MAKE-make} has GNU make \$(if) extension],
 420      [ovs_cv_gnu_make_if],
 421      [cat <<'EOF' > conftest.mk
 422 conftest.out:
 423         echo $(if x,y,z) > conftest.out
 424 .PHONY: all
 425 EOF
 426       rm -f conftest.out
 427       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 428       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 429       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 430       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 431       result=`cat conftest.out`
 432       rm -f conftest.mk conftest.out
 433       if test "X$result" = "Xy"; then
 434         ovs_cv_gnu_make_if=yes
 435       else
 436         ovs_cv_gnu_make_if=no
 437       fi])])
 438
 439 dnl OVS_CHECK_GNU_MAKE
 440 dnl
 441 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 442 dnl only work with GNU make).
 443 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 444   [AC_CACHE_CHECK(
 445      [whether ${MAKE-make} is GNU make],
 446      [ovs_cv_gnu_make],
 447      [rm -f conftest.out
 448       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 449       ${MAKE-make} --version >conftest.out 2>&1
 450       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 451       result=`cat conftest.out`
 452       rm -f conftest.mk conftest.out
 453
 454       case $result in # (
 455         GNU*) ovs_cv_gnu_make=yes ;; # (
 456         *) ovs_cv_gnu_make=no ;;
 457       esac])
 458    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 459
 460 dnl OVS_CHECK_SPARSE_TARGET
 461 dnl
 462 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 463 dnl target for which the code is being built.  This helps it out.
 464 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 465   [AC_CACHE_CHECK(
 466     [target hint for cgcc],
 467     [ac_cv_sparse_target],
 468     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 469        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 470        [x86_64-*], [ac_cv_sparse_target=x86_64],
 471        [ac_cv_sparse_target=other])])
 472    AS_CASE([$ac_cv_sparse_target],
 473      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 474      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 475      [SPARSEFLAGS= CGCCFLAGS=])
 476    AC_SUBST([SPARSEFLAGS])
 477    AC_SUBST([CGCCFLAGS])])
 478
 479 dnl OVS_ENABLE_SPARSE
 480 AC_DEFUN([OVS_ENABLE_SPARSE],
 481   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 482    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 483    : ${SPARSE=sparse}
 484    AC_SUBST([SPARSE])
 485    AC_CONFIG_COMMANDS_PRE(
 486      [if test $ovs_cv_gnu_make_if = yes; then
 487         CC='$(if $(C),REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS)" cgcc $(CGCCFLAGS),'"$CC"')'
 488       fi])])