acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         CFLAGS="$CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 3; then
 137        if test "$version" = 3 && test "$patchlevel" -le 14; then
 138           : # Linux 3.x
 139        else
 140          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 3.14.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     else
 143        if test "$version" -le 1 || test "$patchlevel" -le 5 || test "$sublevel" -le 31; then
 144          AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 2.6.32 or later is required])
 145        else
 146          : # Linux 2.6.x
 147        fi
 148     fi
 149     if (test ! -e "$KBUILD"/include/linux/version.h && \
 150         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 151        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 152         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 153         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 154     fi
 155     OVS_CHECK_LINUX_COMPAT
 156   fi
 157   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 158 ])
 159
 160 dnl OVS_CHECK_DPDK
 161 dnl
 162 dnl Configure DPDK source tree
 163 AC_DEFUN([OVS_CHECK_DPDK], [
 164   AC_ARG_WITH([dpdk],
 165               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 166                               [Specify the DPDK build directory])])
 167
 168   if test X"$with_dpdk" != X; then
 169     RTE_SDK=$with_dpdk
 170
 171     DPDK_INCLUDE=$RTE_SDK/include
 172     DPDK_LIB_DIR=$RTE_SDK/lib
 173     DPDK_LIBS="$DPDK_LIB_DIR/libintel_dpdk.a"
 174
 175     LIBS="$DPDK_LIBS $LIBS"
 176     CPPFLAGS="-I$DPDK_INCLUDE $CPPFLAGS"
 177
 178     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 179   else
 180     RTE_SDK=
 181   fi
 182
 183   AM_CONDITIONAL([DPDK_NETDEV], test -n "$RTE_SDK")
 184 ])
 185
 186 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 187 dnl
 188 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 189 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 190 dnl <REGEX> translated to uppercase.
 191 AC_DEFUN([OVS_GREP_IFELSE], [
 192   AC_MSG_CHECKING([whether $2 matches in $1])
 193   if test -f $1; then
 194     grep '$2' $1 >/dev/null 2>&1
 195     status=$?
 196     case $status in
 197       0)
 198         AC_MSG_RESULT([yes])
 199         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 200         ;;
 201       1)
 202         AC_MSG_RESULT([no])
 203         $4
 204         ;;
 205       *)
 206         AC_MSG_ERROR([grep exited with status $status])
 207         ;;
 208     esac
 209   else
 210     AC_MSG_RESULT([file not found])
 211     $4
 212   fi
 213 ])
 214
 215 dnl OVS_DEFINE(NAME)
 216 dnl
 217 dnl Defines NAME to 1 in kcompat.h.
 218 AC_DEFUN([OVS_DEFINE], [
 219   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 220 ])
 221
 222 AC_DEFUN([OVS_CHECK_LOG2_H], [
 223   AC_MSG_CHECKING([for $KSRC/include/linux/log2.h])
 224   if test -e $KSRC/include/linux/log2.h; then
 225     AC_MSG_RESULT([yes])
 226     OVS_DEFINE([HAVE_LOG2_H])
 227   else
 228     AC_MSG_RESULT([no])
 229   fi
 230 ])
 231
 232 dnl OVS_CHECK_LINUX_COMPAT
 233 dnl
 234 dnl Runs various Autoconf checks on the Linux 2.6 kernel source in
 235 dnl the directory in $KBUILD.
 236 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 237   rm -f datapath/linux/kcompat.h.new
 238   mkdir -p datapath/linux
 239   : > datapath/linux/kcompat.h.new
 240
 241   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 242                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 243
 244   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 245   OVS_GREP_IFELSE([$KSRC/include/linux/hash.h], [fast_hash_ops])
 246
 247   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 248   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 249
 250   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 251
 252   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 253   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 254                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 255
 256   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 257   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 258   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 259   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 260   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 261   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 262   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats])
 263
 264   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 265
 266   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 267                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 268                                    [rcu_read_lock_held])])
 269   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 270
 271   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 272   # is necessary because some versions of this header remove the
 273   # member but retain the kerneldoc comment that describes it (which
 274   # starts with @).  The brackets must be doubled because of m4
 275   # quoting rules.
 276   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 277                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 278   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 279   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 280                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 281   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 282                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 283   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 284                   [skb_copy_from_linear_data_offset])
 285   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 286                   [skb_reset_tail_pointer])
 287   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 288   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 289                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 290   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 291                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 292   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 293                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 294   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 295   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 296   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 297   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 298   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 299   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 300   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 301   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 302   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 303   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 304                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 305   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [l4_rxhash])
 306
 307   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 308                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 309   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 310                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 311   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 312                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 313
 314   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 315   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 316
 317   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 318   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 319   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 320   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 321   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [iptunnel_xmit.*net],
 322                   [OVS_DEFINE([HAVE_IPTUNNEL_XMIT_NET])])
 323   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 324   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 325   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 326   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 327   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 328   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 329   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [vxlan_xmit_skb])
 330
 331   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 332
 333   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 334                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 335
 336   OVS_GREP_IFELSE([$KSRC/include/linux/percpu.h], [this_cpu_ptr])
 337
 338   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 339
 340   OVS_GREP_IFELSE([$KSRC/include/linux/openvswitch.h], [openvswitch_handle_frame_hook],
 341                   [OVS_DEFINE([HAVE_RHEL_OVS_HOOK])])
 342
 343   OVS_CHECK_LOG2_H
 344
 345   if cmp -s datapath/linux/kcompat.h.new \
 346             datapath/linux/kcompat.h >/dev/null 2>&1; then
 347     rm datapath/linux/kcompat.h.new
 348   else
 349     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 350   fi
 351 ])
 352
 353 dnl Checks for net/if_packet.h.
 354 AC_DEFUN([OVS_CHECK_IF_PACKET],
 355   [AC_CHECK_HEADER([net/if_packet.h],
 356                    [HAVE_IF_PACKET=yes],
 357                    [HAVE_IF_PACKET=no])
 358    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 359    if test "$HAVE_IF_PACKET" = yes; then
 360       AC_DEFINE([HAVE_IF_PACKET], [1],
 361                 [Define to 1 if net/if_packet.h is available.])
 362    fi])
 363
 364 dnl Checks for net/if_dl.h.
 365 dnl
 366 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 367 dnl or NetBSD.)
 368 AC_DEFUN([OVS_CHECK_IF_DL],
 369   [AC_CHECK_HEADER([net/if_dl.h],
 370                    [HAVE_IF_DL=yes],
 371                    [HAVE_IF_DL=no])
 372    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 373    if test "$HAVE_IF_DL" = yes; then
 374       AC_DEFINE([HAVE_IF_DL], [1],
 375                 [Define to 1 if net/if_dl.h is available.])
 376
 377       # On these platforms we use libpcap to access network devices.
 378       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 379    fi])
 380
 381 dnl Checks for buggy strtok_r.
 382 dnl
 383 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 384 dnl with optimization that can cause segfaults:
 385 dnl
 386 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 387 AC_DEFUN([OVS_CHECK_STRTOK_R],
 388   [AC_CACHE_CHECK(
 389      [whether strtok_r macro segfaults on some inputs],
 390      [ovs_cv_strtok_r_bug],
 391      [AC_RUN_IFELSE(
 392         [AC_LANG_PROGRAM([#include <stdio.h>
 393                           #include <string.h>
 394                          ],
 395                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 396                            /* Assume bug is present, because relatively minor
 397                               changes in compiler settings (e.g. optimization
 398                               level) can make it crop up. */
 399                            return 1;
 400                            #else
 401                            char string[] = ":::";
 402                            char *save_ptr = (char *) 0xc0ffee;
 403                            char *token1, *token2;
 404                            token1 = strtok_r(string, ":", &save_ptr);
 405                            token2 = strtok_r(NULL, ":", &save_ptr);
 406                            freopen ("/dev/null", "w", stdout);
 407                            printf ("%s %s\n", token1, token2);
 408                            return 0;
 409                            #endif
 410                           ]])],
 411         [ovs_cv_strtok_r_bug=no],
 412         [ovs_cv_strtok_r_bug=yes],
 413         [ovs_cv_strtok_r_bug=yes])])
 414    if test $ovs_cv_strtok_r_bug = yes; then
 415      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 416                [Define if strtok_r macro segfaults on some inputs])
 417    fi
 418 ])
 419
 420 dnl ----------------------------------------------------------------------
 421 dnl These macros are from GNU PSPP, with the following original license:
 422 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 423 dnl This file is free software; the Free Software Foundation
 424 dnl gives unlimited permission to copy and/or distribute it,
 425 dnl with or without modifications, as long as this notice is preserved.
 426
 427 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 428   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-], [_])])dnl
 429   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 430     [ovs_save_CFLAGS="$CFLAGS"
 431      dnl Include -Werror in the compiler options, because without -Werror
 432      dnl clang's GCC-compatible compiler driver does not return a failure
 433      dnl exit status even though it complains about options it does not
 434      dnl understand.
 435      CFLAGS="$CFLAGS $WERROR $1"
 436      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [ovs_cv_name[]=yes], [ovs_cv_name[]=no])
 437      CFLAGS="$ovs_save_CFLAGS"])
 438   if test $ovs_cv_name = yes; then
 439     m4_if([$2], [], [:], [$2])
 440   else
 441     m4_if([$3], [], [:], [$3])
 442   fi
 443 ])
 444
 445 dnl OVS_CHECK_WERROR
 446 dnl
 447 dnl Check whether the C compiler accepts -Werror.
 448 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 449 AC_DEFUN([OVS_CHECK_WERROR],
 450   [WERROR=
 451    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 452
 453 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 454 dnl Check whether the given C compiler OPTION is accepted.
 455 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 456 AC_DEFUN([OVS_CHECK_CC_OPTION],
 457   [AC_REQUIRE([OVS_CHECK_WERROR])
 458    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 459
 460 dnl OVS_ENABLE_OPTION([OPTION])
 461 dnl Check whether the given C compiler OPTION is accepted.
 462 dnl If so, add it to WARNING_FLAGS.
 463 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 464 AC_DEFUN([OVS_ENABLE_OPTION],
 465   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 466    AC_SUBST([WARNING_FLAGS])])
 467
 468 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 469 dnl Check whether the given C compiler OPTION is accepted.
 470 dnl If so, enable the given Automake CONDITIONAL.
 471
 472 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 473 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 474   [OVS_CHECK_CC_OPTION(
 475     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 476    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 477 dnl ----------------------------------------------------------------------
 478
 479 dnl Check for too-old XenServer.
 480 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 481   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 482     [if test -e /etc/redhat-release; then
 483        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 484      fi
 485      if test -z "$ovs_cv_xsversion"; then
 486        ovs_cv_xsversion=none
 487      fi])
 488   case $ovs_cv_xsversion in
 489     none)
 490       ;;
 491
 492     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 493     [[6-9]]* |                           dnl XenServer 6 or later
 494     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 495     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 496     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 497     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 498       ;;
 499
 500     *)
 501       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 502       ;;
 503   esac])
 504
 505 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 506 dnl
 507 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 508 dnl Runs 'if-true' if so, 'if-false' otherwise.
 509 AC_DEFUN([OVS_CHECK_MAKE_IF],
 510   [AC_CACHE_CHECK(
 511      [whether ${MAKE-make} has GNU make \$(if) extension],
 512      [ovs_cv_gnu_make_if],
 513      [cat <<'EOF' > conftest.mk
 514 conftest.out:
 515         echo $(if x,y,z) > conftest.out
 516 .PHONY: all
 517 EOF
 518       rm -f conftest.out
 519       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 520       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 521       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 522       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 523       result=`cat conftest.out`
 524       rm -f conftest.mk conftest.out
 525       if test "X$result" = "Xy"; then
 526         ovs_cv_gnu_make_if=yes
 527       else
 528         ovs_cv_gnu_make_if=no
 529       fi])])
 530
 531 dnl OVS_CHECK_GNU_MAKE
 532 dnl
 533 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 534 dnl only work with GNU make).
 535 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 536   [AC_CACHE_CHECK(
 537      [whether ${MAKE-make} is GNU make],
 538      [ovs_cv_gnu_make],
 539      [rm -f conftest.out
 540       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 541       ${MAKE-make} --version >conftest.out 2>&1
 542       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 543       result=`cat conftest.out`
 544       rm -f conftest.mk conftest.out
 545
 546       case $result in # (
 547         GNU*) ovs_cv_gnu_make=yes ;; # (
 548         *) ovs_cv_gnu_make=no ;;
 549       esac])
 550    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 551
 552 dnl OVS_CHECK_SPARSE_TARGET
 553 dnl
 554 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 555 dnl target for which the code is being built.  This helps it out.
 556 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 557   [AC_CACHE_CHECK(
 558     [target hint for cgcc],
 559     [ac_cv_sparse_target],
 560     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 561        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 562        [x86_64-*], [ac_cv_sparse_target=x86_64],
 563        [ac_cv_sparse_target=other])])
 564    AS_CASE([$ac_cv_sparse_target],
 565      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 566      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 567      [SPARSEFLAGS= CGCCFLAGS=])
 568    AC_SUBST([SPARSEFLAGS])
 569    AC_SUBST([CGCCFLAGS])])
 570
 571 dnl OVS_SPARSE_EXTRA_INCLUDES
 572 dnl
 573 dnl The cgcc script from "sparse" does not search gcc's default
 574 dnl search path. Get the default search path from GCC and pass
 575 dnl them to sparse.
 576 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 577     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 578            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 579
 580 dnl OVS_ENABLE_SPARSE
 581 AC_DEFUN([OVS_ENABLE_SPARSE],
 582   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 583    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 584    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 585    : ${SPARSE=sparse}
 586    AC_SUBST([SPARSE])
 587    AC_CONFIG_COMMANDS_PRE(
 588      [if test $ovs_cv_gnu_make_if = yes; then
 589         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 590       fi])])
 591
 592 dnl OVS_PTHREAD_SET_NAME
 593 dnl
 594 dnl This checks for three known variants of pthreads functions for setting
 595 dnl the name of the current thread:
 596 dnl
 597 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 598 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 599 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 600 dnl
 601 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 602 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 603 dnl provide to it.
 604 dnl
 605 dnl This macro defines:
 606 dnl
 607 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 608 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 609 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 610 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 611   [AC_CHECK_FUNCS([pthread_set_name_np])
 612    if test $ac_cv_func_pthread_set_name_np != yes; then
 613      AC_CACHE_CHECK(
 614        [for pthread_setname_np() variant],
 615        [ovs_cv_pthread_setname_np],
 616        [AC_LINK_IFELSE(
 617          [AC_LANG_PROGRAM([#include <pthread.h>
 618   ], [pthread_setname_np(pthread_self(), "name");])],
 619          [ovs_cv_pthread_setname_np=glibc],
 620          [AC_LINK_IFELSE(
 621            [AC_LANG_PROGRAM([#include <pthread.h>
 622 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 623            [ovs_cv_pthread_setname_np=netbsd],
 624            [ovs_cv_pthread_setname_np=none])])])
 625      case $ovs_cv_pthread_setname_np in # (
 626        glibc)
 627           AC_DEFINE(
 628             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 629             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 630           ;; # (
 631        netbsd)
 632           AC_DEFINE(
 633             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 634             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 635           ;;
 636      esac
 637    fi])
 638
 639 dnl OVS_CHECK_LINUX_HOST.
 640 dnl
 641 dnl Checks whether we're building for a Linux host, based on the presence of
 642 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 643 dnl LINUX based on the result.
 644 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 645   [AC_CACHE_CHECK(
 646      [whether __linux__ is defined],
 647      [ovs_cv_linux],
 648      [AC_COMPILE_IFELSE(
 649         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 650         [ovs_cv_linux=true],
 651         [ovs_cv_linux=false])])
 652    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])