acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 4; then
 137        if test "$version" = 4 && test "$patchlevel" -le 6; then
 138           : # Linux 4.x
 139        else
 140           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.6.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 143        : # Linux 3.x
 144     else
 145        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 146     fi
 147     if (test ! -e "$KBUILD"/include/linux/version.h && \
 148         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 149        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 150         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 151         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 152     fi
 153     OVS_CHECK_LINUX_COMPAT
 154   fi
 155   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 156 ])
 157
 158 dnl OVS_CHECK_DPDK
 159 dnl
 160 dnl Configure DPDK source tree
 161 AC_DEFUN([OVS_CHECK_DPDK], [
 162   AC_ARG_WITH([dpdk],
 163               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 164                               [Specify the DPDK build directory])],
 165               [have_dpdk=true])
 166
 167   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 168   if test "$have_dpdk" != true || test "$with_dpdk" = no; then
 169     AC_MSG_RESULT([no])
 170     DPDKLIB_FOUND=false
 171   else
 172     AC_MSG_RESULT([yes])
 173     case "$with_dpdk" in
 174       yes)
 175         DPDK_AUTO_DISCOVER="true"
 176         DPDK_INCLUDE="/usr/local/include/dpdk -I/usr/include/dpdk"
 177         ;;
 178       *)
 179         DPDK_AUTO_DISCOVER="false"
 180         DPDK_INCLUDE="$with_dpdk/include"
 181         # If 'with_dpdk' is passed install directory, point to headers
 182         # installed in $DESTDIR/$prefix/include/dpdk
 183         AC_CHECK_FILE([$DPDK_INCLUDE/rte_config.h], [],
 184                       [AC_CHECK_FILE([$DPDK_INCLUDE/dpdk/rte_config.h],
 185                                      [DPDK_INCLUDE=$DPDK_INCLUDE/dpdk], [])])
 186         DPDK_LIB_DIR="$with_dpdk/lib"
 187         ;;
 188     esac
 189
 190     DPDK_LIB="-ldpdk"
 191     DPDK_EXTRA_LIB=""
 192
 193     ovs_save_CFLAGS="$CFLAGS"
 194     ovs_save_LDFLAGS="$LDFLAGS"
 195     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 196     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 197       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 198     fi
 199
 200     AC_COMPILE_IFELSE([
 201       AC_LANG_PROGRAM(
 202         [
 203           #include <rte_config.h>
 204 #if !RTE_LIBRTE_VHOST_USER
 205 #error
 206 #endif
 207         ], [])
 208       ], [],
 209       [AC_DEFINE([VHOST_CUSE], [1], [DPDK vhost-cuse support enabled, vhost-user disabled.])
 210        DPDK_EXTRA_LIB="-lfuse"])
 211
 212     AC_SEARCH_LIBS([get_mempolicy],[numa],[],[AC_MSG_ERROR([unable to find libnuma, install the dependency package])])
 213
 214     # On some systems we have to add -ldl to link with dpdk
 215     #
 216     # This code, at first, tries to link without -ldl (""),
 217     # then adds it and tries again.
 218     # Before each attempt the search cache must be unset,
 219     # otherwise autoconf will stick with the old result
 220
 221     DPDKLIB_FOUND=false
 222     save_LIBS=$LIBS
 223     for extras in "" "-ldl"; do
 224         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB -lnuma"
 225         AC_LINK_IFELSE(
 226            [AC_LANG_PROGRAM([#include <rte_config.h>
 227                              #include <rte_eal.h>],
 228                             [int rte_argc; char ** rte_argv;
 229                              rte_eal_init(rte_argc, rte_argv);])],
 230            [DPDKLIB_FOUND=true])
 231         if $DPDKLIB_FOUND; then
 232             break
 233         fi
 234     done
 235
 236     # If linking unsuccessful
 237     if test "$DPDKLIB_FOUND" = "false" ; then
 238       if $DPDK_AUTO_DISCOVER; then
 239         AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
 240       else
 241         AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 242       fi
 243     fi
 244     CFLAGS="$ovs_save_CFLAGS"
 245     LDFLAGS="$ovs_save_LDFLAGS"
 246     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 247       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 248     fi
 249     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE"
 250     OVS_ENABLE_OPTION([-mssse3])
 251
 252     # DPDK pmd drivers are not linked unless --whole-archive is used.
 253     #
 254     # This happens because the rest of the DPDK code doesn't use any symbol in
 255     # the pmd driver objects, and the drivers register themselves using an
 256     # __attribute__((constructor)) function.
 257     #
 258     # These options are specified inside a single -Wl directive to prevent
 259     # autotools from reordering them.
 260     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 261     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 262     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 263   fi
 264
 265   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 266 ])
 267
 268 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 269 dnl
 270 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 271 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 272 dnl <REGEX> translated to uppercase.
 273 AC_DEFUN([OVS_GREP_IFELSE], [
 274   AC_MSG_CHECKING([whether $2 matches in $1])
 275   if test -f $1; then
 276     grep '$2' $1 >/dev/null 2>&1
 277     status=$?
 278     case $status in
 279       0)
 280         AC_MSG_RESULT([yes])
 281         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 282         ;;
 283       1)
 284         AC_MSG_RESULT([no])
 285         $4
 286         ;;
 287       *)
 288         AC_MSG_ERROR([grep exited with status $status])
 289         ;;
 290     esac
 291   else
 292     AC_MSG_RESULT([file not found])
 293     $4
 294   fi
 295 ])
 296
 297 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 298 dnl
 299 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 300 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 301 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 302 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 303 dnl translated to uppercase.
 304 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 305   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 306   if test -f $1; then
 307     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 308     status=$?
 309     case $status in
 310       0)
 311         AC_MSG_RESULT([yes])
 312         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 313         ;;
 314       1)
 315         AC_MSG_RESULT([no])
 316         $5
 317         ;;
 318       *)
 319         AC_MSG_ERROR([grep exited with status $status])
 320         ;;
 321     esac
 322   else
 323     AC_MSG_RESULT([file not found])
 324     $5
 325   fi
 326 ])
 327
 328 dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
 329 dnl
 330 dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
 331 dnl the function signature starting from the line matching FUNCTION
 332 dnl and ending with the line containing the closing parenthesis.  If
 333 dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH.  If
 334 dnl IF-MATCH is empty then it defines to
 335 dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
 336 dnl <REGEX> translated to uppercase.
 337 AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
 338   AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
 339   if test -f $1; then
 340     awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
 341     status=$?
 342     case $status in
 343       0)
 344         AC_MSG_RESULT([yes])
 345         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 346         ;;
 347       1)
 348         AC_MSG_RESULT([no])
 349         $5
 350         ;;
 351       *)
 352         AC_MSG_ERROR([grep exited with status $status])
 353         ;;
 354     esac
 355   else
 356     AC_MSG_RESULT([file not found])
 357     $5
 358   fi
 359 ])
 360
 361 dnl OVS_DEFINE(NAME)
 362 dnl
 363 dnl Defines NAME to 1 in kcompat.h.
 364 AC_DEFUN([OVS_DEFINE], [
 365   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 366 ])
 367
 368 dnl OVS_CHECK_LINUX_COMPAT
 369 dnl
 370 dnl Runs various Autoconf checks on the Linux kernel source in
 371 dnl the directory in $KBUILD.
 372 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 373   rm -f datapath/linux/kcompat.h.new
 374   mkdir -p datapath/linux
 375   : > datapath/linux/kcompat.h.new
 376
 377   echo '#include <linux/version.h>
 378 #ifndef RHEL_RELEASE_CODE
 379 #define RHEL_RELEASE_CODE 0
 380 #define RHEL_RELEASE_VERSION(a, b) 0
 381 #endif' >> datapath/linux/kcompat.h.new
 382
 383   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 384                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 385
 386   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 387                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 388   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 389
 390   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 391   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 392   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
 393
 394   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 395   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 396
 397   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 398   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 399   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 400   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 401   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 402
 403   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 404   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 405   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 406                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 407   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 408                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 409
 410   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 411                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 412   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 413                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 414   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 415                         [ip_do_fragment], [net],
 416                         [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
 417   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
 418                         [ip_local_out], [net],
 419                         [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
 420
 421   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 422
 423   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 424                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 425   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 426   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 427                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 428   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 429                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 430   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 431   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 432                         [frags_work])
 433   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 434                         [rwlock])
 435   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 436                         [list_evictor])
 437   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 438                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 439
 440   dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
 441   dnl OVS does not really need ipv6 label field, but its presence signifies that
 442   dnl the stack has all required ipv6 support.
 443   dnl OVS also does not need dst_cache But this dependency allows us to write
 444   dnl much cleaner code.
 445
 446   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
 447                         [label],
 448                         [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
 449                                          [iptunnel_pull_offloads],
 450                         [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
 451                                          [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])
 452
 453   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 454                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 455   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
 456   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 457   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 458   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 459   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 460   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 461   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 462   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 463   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
 464   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
 465   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 466   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 467   dnl So check type of tstats.
 468   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 469                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 470   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 471                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 472   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 473   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 474                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 475   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 476   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
 477   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
 478                         [netdev_master_upper_dev_link], [upper_priv],
 479                         [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
 480
 481   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 482   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 483   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 484                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 485   OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
 486                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
 487   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
 488                         [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
 489
 490   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 491                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 492
 493   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 494                   [nf_ct_tmpl_alloc], [nf_conntrack_zone],
 495                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 496   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 497                   [nf_ct_get_tuplepr], [struct.net],
 498                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 499   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 500                   [nf_ct_zone_init])
 501   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 502                   [nf_connlabels_get])
 503   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 504                   [nf_connlabels_get], [int bit],
 505                   [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
 506   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 507                   [nf_ct_frag6_consume_orig])
 508   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 509                   [nf_ct_frag6_output])
 510   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
 511   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
 512   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
 513
 514   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 515   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 516
 517   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 518   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 519   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 520                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 521   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 522
 523   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 524                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 525                                    [rcu_read_lock_held])])
 526   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 527
 528   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 529   # is necessary because some versions of this header remove the
 530   # member but retain the kerneldoc comment that describes it (which
 531   # starts with @).  The brackets must be doubled because of m4
 532   # quoting rules.
 533   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 534                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 535   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 536   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 537   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
 538   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
 539   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 540   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_scrub_packet.*xnet],
 541                   [OVS_DEFINE([HAVE_SKB_SCRUB_PACKET_XNET])])
 542   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 543   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 544                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 545   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 546                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 547   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 548                   [skb_copy_from_linear_data_offset])
 549   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 550                   [skb_reset_tail_pointer])
 551   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 552   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 553                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 554   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 555   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 556   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 557   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 558   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 559   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 560   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 561   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
 562                   [OVS_DEFINE([HAVE_SKB_GET_HASH])])
 563   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 564   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 565                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 566   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 567                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 568   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 569   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 570   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 571   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
 572   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
 573
 574   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 575                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 576   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 577                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 578   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 579                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 580
 581   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 582   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 583
 584   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 585   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 586
 587   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 588   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 589   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 590   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 591                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 592   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 593   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 594                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 595   OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
 596                         [genl_notify], [net],
 597                         [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
 598
 599
 600   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 601                         [genl_multicast_group], [id])
 602   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 603
 604   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 605   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 606   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 607   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 608   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 609   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 610                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 611   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 612                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 613
 614   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
 615   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 616   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 617   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 618   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 619   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 620   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 621   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 622   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 623                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 624
 625   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 626
 627   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 628                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 629   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 630   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 631   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 632
 633   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 634
 635   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 636                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 637   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 638                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 639                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 640   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 641   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 642   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
 643                   [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
 644   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
 645                         [gro_receive])
 646
 647   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 648                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 649   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 650                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 651
 652   OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
 653   OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
 654   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 655                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 656
 657   if cmp -s datapath/linux/kcompat.h.new \
 658             datapath/linux/kcompat.h >/dev/null 2>&1; then
 659     rm datapath/linux/kcompat.h.new
 660   else
 661     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 662   fi
 663 ])
 664
 665 dnl Checks for net/if_packet.h.
 666 AC_DEFUN([OVS_CHECK_IF_PACKET],
 667   [AC_CHECK_HEADER([net/if_packet.h],
 668                    [HAVE_IF_PACKET=yes],
 669                    [HAVE_IF_PACKET=no])
 670    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 671    if test "$HAVE_IF_PACKET" = yes; then
 672       AC_DEFINE([HAVE_IF_PACKET], [1],
 673                 [Define to 1 if net/if_packet.h is available.])
 674    fi])
 675
 676 dnl Checks for net/if_dl.h.
 677 dnl
 678 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 679 dnl or NetBSD.)
 680 AC_DEFUN([OVS_CHECK_IF_DL],
 681   [AC_CHECK_HEADER([net/if_dl.h],
 682                    [HAVE_IF_DL=yes],
 683                    [HAVE_IF_DL=no])
 684    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 685    if test "$HAVE_IF_DL" = yes; then
 686       AC_DEFINE([HAVE_IF_DL], [1],
 687                 [Define to 1 if net/if_dl.h is available.])
 688
 689       # On these platforms we use libpcap to access network devices.
 690       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 691    fi])
 692
 693 dnl Checks for buggy strtok_r.
 694 dnl
 695 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 696 dnl with optimization that can cause segfaults:
 697 dnl
 698 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 699 AC_DEFUN([OVS_CHECK_STRTOK_R],
 700   [AC_CACHE_CHECK(
 701      [whether strtok_r macro segfaults on some inputs],
 702      [ovs_cv_strtok_r_bug],
 703      [AC_RUN_IFELSE(
 704         [AC_LANG_PROGRAM([#include <stdio.h>
 705                           #include <string.h>
 706                          ],
 707                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 708                            /* Assume bug is present, because relatively minor
 709                               changes in compiler settings (e.g. optimization
 710                               level) can make it crop up. */
 711                            return 1;
 712                            #else
 713                            char string[] = ":::";
 714                            char *save_ptr = (char *) 0xc0ffee;
 715                            char *token1, *token2;
 716                            token1 = strtok_r(string, ":", &save_ptr);
 717                            token2 = strtok_r(NULL, ":", &save_ptr);
 718                            freopen ("/dev/null", "w", stdout);
 719                            printf ("%s %s\n", token1, token2);
 720                            return 0;
 721                            #endif
 722                           ]])],
 723         [ovs_cv_strtok_r_bug=no],
 724         [ovs_cv_strtok_r_bug=yes],
 725         [ovs_cv_strtok_r_bug=yes])])
 726    if test $ovs_cv_strtok_r_bug = yes; then
 727      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 728                [Define if strtok_r macro segfaults on some inputs])
 729    fi
 730 ])
 731
 732 dnl ----------------------------------------------------------------------
 733 dnl These macros are from GNU PSPP, with the following original license:
 734 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 735 dnl This file is free software; the Free Software Foundation
 736 dnl gives unlimited permission to copy and/or distribute it,
 737 dnl with or without modifications, as long as this notice is preserved.
 738
 739 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 740   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 741   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 742     [ovs_save_CFLAGS="$CFLAGS"
 743      dnl Include -Werror in the compiler options, because without -Werror
 744      dnl clang's GCC-compatible compiler driver does not return a failure
 745      dnl exit status even though it complains about options it does not
 746      dnl understand.
 747      dnl
 748      dnl Also, check stderr as gcc exits with status 0 for options
 749      dnl rejected at getopt level.
 750      dnl    % touch /tmp/a.c
 751      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 752      dnl    gcc: unrecognized option '-Qunused-arguments'
 753      dnl    0
 754      dnl    %
 755      CFLAGS="$CFLAGS $WERROR $1"
 756      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
 757      CFLAGS="$ovs_save_CFLAGS"])
 758   if test $ovs_cv_name = yes; then
 759     m4_if([$2], [], [:], [$2])
 760   else
 761     m4_if([$3], [], [:], [$3])
 762   fi
 763 ])
 764
 765 dnl OVS_CHECK_WERROR
 766 dnl
 767 dnl Check whether the C compiler accepts -Werror.
 768 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 769 AC_DEFUN([OVS_CHECK_WERROR],
 770   [WERROR=
 771    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 772
 773 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 774 dnl Check whether the given C compiler OPTION is accepted.
 775 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 776 AC_DEFUN([OVS_CHECK_CC_OPTION],
 777   [AC_REQUIRE([OVS_CHECK_WERROR])
 778    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 779
 780 dnl OVS_ENABLE_OPTION([OPTION])
 781 dnl Check whether the given C compiler OPTION is accepted.
 782 dnl If so, add it to WARNING_FLAGS.
 783 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 784 AC_DEFUN([OVS_ENABLE_OPTION],
 785   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 786    AC_SUBST([WARNING_FLAGS])])
 787
 788 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 789 dnl Check whether the given C compiler OPTION is accepted.
 790 dnl If so, enable the given Automake CONDITIONAL.
 791
 792 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 793 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 794   [OVS_CHECK_CC_OPTION(
 795     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 796    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 797 dnl ----------------------------------------------------------------------
 798
 799 dnl Check for too-old XenServer.
 800 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 801   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 802     [if test -e /etc/redhat-release; then
 803        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 804      fi
 805      if test -z "$ovs_cv_xsversion"; then
 806        ovs_cv_xsversion=none
 807      fi])
 808   case $ovs_cv_xsversion in
 809     none)
 810       ;;
 811
 812     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 813     [[6-9]]* |                           dnl XenServer 6 or later
 814     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 815     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 816     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 817     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 818       ;;
 819
 820     *)
 821       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 822       ;;
 823   esac])
 824
 825 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 826 dnl
 827 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 828 dnl Runs 'if-true' if so, 'if-false' otherwise.
 829 AC_DEFUN([OVS_CHECK_MAKE_IF],
 830   [AC_CACHE_CHECK(
 831      [whether ${MAKE-make} has GNU make \$(if) extension],
 832      [ovs_cv_gnu_make_if],
 833      [cat <<'EOF' > conftest.mk
 834 conftest.out:
 835         echo $(if x,y,z) > conftest.out
 836 .PHONY: all
 837 EOF
 838       rm -f conftest.out
 839       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 840       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 841       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 842       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 843       result=`cat conftest.out`
 844       rm -f conftest.mk conftest.out
 845       if test "X$result" = "Xy"; then
 846         ovs_cv_gnu_make_if=yes
 847       else
 848         ovs_cv_gnu_make_if=no
 849       fi])])
 850
 851 dnl OVS_CHECK_GNU_MAKE
 852 dnl
 853 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 854 dnl only work with GNU make).
 855 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 856   [AC_CACHE_CHECK(
 857      [whether ${MAKE-make} is GNU make],
 858      [ovs_cv_gnu_make],
 859      [rm -f conftest.out
 860       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 861       ${MAKE-make} --version >conftest.out 2>&1
 862       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 863       result=`cat conftest.out`
 864       rm -f conftest.mk conftest.out
 865
 866       case $result in # (
 867         GNU*) ovs_cv_gnu_make=yes ;; # (
 868         *) ovs_cv_gnu_make=no ;;
 869       esac])
 870    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 871
 872 dnl OVS_CHECK_SPARSE_TARGET
 873 dnl
 874 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 875 dnl target for which the code is being built.  This helps it out.
 876 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 877   [AC_CACHE_CHECK(
 878     [target hint for cgcc],
 879     [ac_cv_sparse_target],
 880     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 881        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 882        [x86_64-*], [ac_cv_sparse_target=x86_64],
 883        [ac_cv_sparse_target=other])])
 884    AS_CASE([$ac_cv_sparse_target],
 885      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 886      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 887      [SPARSEFLAGS= CGCCFLAGS=])
 888    AC_SUBST([SPARSEFLAGS])
 889    AC_SUBST([CGCCFLAGS])])
 890
 891 dnl OVS_SPARSE_EXTRA_INCLUDES
 892 dnl
 893 dnl The cgcc script from "sparse" does not search gcc's default
 894 dnl search path. Get the default search path from GCC and pass
 895 dnl them to sparse.
 896 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 897     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 898            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 899
 900 dnl OVS_ENABLE_SPARSE
 901 AC_DEFUN([OVS_ENABLE_SPARSE],
 902   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 903    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 904    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 905    : ${SPARSE=sparse}
 906    AC_SUBST([SPARSE])
 907    AC_CONFIG_COMMANDS_PRE(
 908      [if test $ovs_cv_gnu_make_if = yes; then
 909         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 910       fi])])
 911
 912 dnl OVS_PTHREAD_SET_NAME
 913 dnl
 914 dnl This checks for three known variants of pthreads functions for setting
 915 dnl the name of the current thread:
 916 dnl
 917 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 918 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 919 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 920 dnl
 921 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 922 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 923 dnl provide to it.
 924 dnl
 925 dnl This macro defines:
 926 dnl
 927 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 928 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 929 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 930 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 931   [AC_CHECK_FUNCS([pthread_set_name_np])
 932    if test $ac_cv_func_pthread_set_name_np != yes; then
 933      AC_CACHE_CHECK(
 934        [for pthread_setname_np() variant],
 935        [ovs_cv_pthread_setname_np],
 936        [AC_LINK_IFELSE(
 937          [AC_LANG_PROGRAM([#include <pthread.h>
 938   ], [pthread_setname_np(pthread_self(), "name");])],
 939          [ovs_cv_pthread_setname_np=glibc],
 940          [AC_LINK_IFELSE(
 941            [AC_LANG_PROGRAM([#include <pthread.h>
 942 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 943            [ovs_cv_pthread_setname_np=netbsd],
 944            [ovs_cv_pthread_setname_np=none])])])
 945      case $ovs_cv_pthread_setname_np in # (
 946        glibc)
 947           AC_DEFINE(
 948             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 949             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 950           ;; # (
 951        netbsd)
 952           AC_DEFINE(
 953             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 954             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 955           ;;
 956      esac
 957    fi])
 958
 959 dnl OVS_CHECK_LINUX_HOST.
 960 dnl
 961 dnl Checks whether we're building for a Linux host, based on the presence of
 962 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 963 dnl LINUX based on the result.
 964 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 965   [AC_CACHE_CHECK(
 966      [whether __linux__ is defined],
 967      [ovs_cv_linux],
 968      [AC_COMPILE_IFELSE(
 969         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 970         [ovs_cv_linux=true],
 971         [ovs_cv_linux=false])])
 972    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])