acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 4; then
 137        if test "$version" = 4 && test "$patchlevel" -le 3; then
 138           : # Linux 4.x
 139        else
 140           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.3.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 143        : # Linux 3.x
 144     else
 145        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 146     fi
 147     if (test ! -e "$KBUILD"/include/linux/version.h && \
 148         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 149        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 150         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 151         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 152     fi
 153     OVS_CHECK_LINUX_COMPAT
 154   fi
 155   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 156 ])
 157
 158 dnl OVS_CHECK_DPDK
 159 dnl
 160 dnl Configure DPDK source tree
 161 AC_DEFUN([OVS_CHECK_DPDK], [
 162   AC_ARG_WITH([dpdk],
 163               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 164                               [Specify the DPDK build directory])])
 165
 166   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 167   if test -z "$with_dpdk" || test "$with_dpdk" = no; then
 168     AC_MSG_RESULT([no])
 169     DPDKLIB_FOUND=false
 170   else
 171     AC_MSG_RESULT([yes])
 172     case "$with_dpdk" in
 173       yes)
 174         DPDK_AUTO_DISCOVER="true"
 175         DPDK_INCLUDE="/usr/local/include/dpdk -I/usr/include/dpdk"
 176         ;;
 177       *)
 178         DPDK_AUTO_DISCOVER="false"
 179         DPDK_INCLUDE="$with_dpdk/include"
 180         # If 'with_dpdk' is passed install directory, point to headers
 181         # installed in $DESTDIR/$prefix/include/dpdk
 182         AC_CHECK_FILE([$DPDK_INCLUDE/rte_config.h], [],
 183                       [AC_CHECK_FILE([$DPDK_INCLUDE/dpdk/rte_config.h],
 184                                      [DPDK_INCLUDE=$DPDK_INCLUDE/dpdk], [])])
 185         DPDK_LIB_DIR="$with_dpdk/lib"
 186         ;;
 187     esac
 188
 189     DPDK_LIB="-ldpdk"
 190     DPDK_EXTRA_LIB=""
 191
 192     ovs_save_CFLAGS="$CFLAGS"
 193     ovs_save_LDFLAGS="$LDFLAGS"
 194     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 195     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 196       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 197     fi
 198
 199     AC_COMPILE_IFELSE([
 200       AC_LANG_PROGRAM(
 201         [
 202           #include <rte_config.h>
 203 #if !RTE_LIBRTE_VHOST_USER
 204 #error
 205 #endif
 206         ], [])
 207       ], [],
 208       [AC_DEFINE([VHOST_CUSE], [1], [DPDK vhost-cuse support enabled, vhost-user disabled.])
 209        DPDK_EXTRA_LIB="-lfuse"])
 210
 211     # On some systems we have to add -ldl to link with dpdk
 212     #
 213     # This code, at first, tries to link without -ldl (""),
 214     # then adds it and tries again.
 215     # Before each attempt the search cache must be unset,
 216     # otherwise autoconf will stick with the old result
 217
 218     DPDKLIB_FOUND=false
 219     save_LIBS=$LIBS
 220     for extras in "" "-ldl"; do
 221         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 222         AC_LINK_IFELSE(
 223            [AC_LANG_PROGRAM([#include <rte_config.h>
 224                              #include <rte_eal.h>],
 225                             [int rte_argc; char ** rte_argv;
 226                              rte_eal_init(rte_argc, rte_argv);])],
 227            [DPDKLIB_FOUND=true])
 228         if $DPDKLIB_FOUND; then
 229             break
 230         fi
 231     done
 232
 233     # If linking unsuccessful
 234     if test "$DPDKLIB_FOUND" = "false" ; then
 235       if $DPDK_AUTO_DISCOVER; then
 236         AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
 237       else
 238         AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 239       fi
 240     fi
 241     CFLAGS="$ovs_save_CFLAGS"
 242     LDFLAGS="$ovs_save_LDFLAGS"
 243     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 244       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 245     fi
 246     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE"
 247     OVS_ENABLE_OPTION([-mssse3])
 248
 249     # DPDK pmd drivers are not linked unless --whole-archive is used.
 250     #
 251     # This happens because the rest of the DPDK code doesn't use any symbol in
 252     # the pmd driver objects, and the drivers register themselves using an
 253     # __attribute__((constructor)) function.
 254     #
 255     # These options are specified inside a single -Wl directive to prevent
 256     # autotools from reordering them.
 257     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 258     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 259     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 260   fi
 261
 262   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 263 ])
 264
 265 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 266 dnl
 267 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 268 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 269 dnl <REGEX> translated to uppercase.
 270 AC_DEFUN([OVS_GREP_IFELSE], [
 271   AC_MSG_CHECKING([whether $2 matches in $1])
 272   if test -f $1; then
 273     grep '$2' $1 >/dev/null 2>&1
 274     status=$?
 275     case $status in
 276       0)
 277         AC_MSG_RESULT([yes])
 278         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 279         ;;
 280       1)
 281         AC_MSG_RESULT([no])
 282         $4
 283         ;;
 284       *)
 285         AC_MSG_ERROR([grep exited with status $status])
 286         ;;
 287     esac
 288   else
 289     AC_MSG_RESULT([file not found])
 290     $4
 291   fi
 292 ])
 293
 294 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 295 dnl
 296 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 297 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 298 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 299 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 300 dnl translated to uppercase.
 301 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 302   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 303   if test -f $1; then
 304     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 305     status=$?
 306     case $status in
 307       0)
 308         AC_MSG_RESULT([yes])
 309         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 310         ;;
 311       1)
 312         AC_MSG_RESULT([no])
 313         $5
 314         ;;
 315       *)
 316         AC_MSG_ERROR([grep exited with status $status])
 317         ;;
 318     esac
 319   else
 320     AC_MSG_RESULT([file not found])
 321     $5
 322   fi
 323 ])
 324
 325 dnl OVS_DEFINE(NAME)
 326 dnl
 327 dnl Defines NAME to 1 in kcompat.h.
 328 AC_DEFUN([OVS_DEFINE], [
 329   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 330 ])
 331
 332 dnl OVS_CHECK_LINUX_COMPAT
 333 dnl
 334 dnl Runs various Autoconf checks on the Linux kernel source in
 335 dnl the directory in $KBUILD.
 336 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 337   rm -f datapath/linux/kcompat.h.new
 338   mkdir -p datapath/linux
 339   : > datapath/linux/kcompat.h.new
 340
 341   echo '#include <linux/version.h>
 342 #ifndef RHEL_RELEASE_CODE
 343 #define RHEL_RELEASE_CODE 0
 344 #define RHEL_RELEASE_VERSION(a, b) 0
 345 #endif' >> datapath/linux/kcompat.h.new
 346
 347   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 348                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 349
 350   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 351                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 352   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 353
 354   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 355   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 356
 357   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 358   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 359
 360   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 361   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 362   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 363   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 364   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 365
 366   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 367   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 368   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 369                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 370   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 371                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 372
 373   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 374                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 375   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 376                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 377   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_do_fragment])
 378   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_is_fragment])
 379   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 380
 381   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 382                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 383   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 384   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 385                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 386   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 387                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 388   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 389   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 390                         [frags_work])
 391   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 392                         [rwlock])
 393   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 394                         [list_evictor])
 395   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 396                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 397
 398   OVS_GREP_IFELSE([$KSRC/include/net/dst_metadata.h], [metadata_dst])
 399
 400   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 401                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 402   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 403   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 404   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 405   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 406   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 407   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 408   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 409   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 410   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 411   dnl So check type of tstats.
 412   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 413                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 414   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 415                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 416   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 417   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 418                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 419   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 420
 421   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 422   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 423   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 424                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 425   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 426                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 427
 428   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 429                   [tmpl_alloc.*conntrack_zone],
 430                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 431   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 432                   [l3num.*struct.net],
 433                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 434   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 435                   [nf_ct_zone_init])
 436   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 437                   [nf_connlabels_get])
 438   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 439                   [nf_ct_frag6_consume_orig])
 440   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 441                   [nf_ct_frag6_output])
 442
 443   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 444   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 445
 446   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 447   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 448   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 449                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 450   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 451
 452   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 453                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 454                                    [rcu_read_lock_held])])
 455   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 456
 457   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 458   # is necessary because some versions of this header remove the
 459   # member but retain the kerneldoc comment that describes it (which
 460   # starts with @).  The brackets must be doubled because of m4
 461   # quoting rules.
 462   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 463                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 464   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 465   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 466   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_mac_header])
 467   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_network_header])
 468   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 469   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_scrub_packet.*xnet],
 470                   [OVS_DEFINE([HAVE_SKB_SCRUB_PACKET_XNET])])
 471   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 472   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 473                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 474   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 475                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 476   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 477                   [skb_copy_from_linear_data_offset])
 478   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 479                   [skb_reset_tail_pointer])
 480   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 481   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_transport_header],
 482                   [OVS_DEFINE([HAVE_SKBUFF_HEADER_HELPERS])])
 483   OVS_GREP_IFELSE([$KSRC/include/linux/icmpv6.h], [icmp6_hdr],
 484                   [OVS_DEFINE([HAVE_ICMP6_HDR])])
 485   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 486                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 487   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 488   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 489   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 490   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 491   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 492   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 493   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 494   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 495   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 496   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 497                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 498   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 499                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 500   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 501   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 502   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 503
 504   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 505                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 506   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 507                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 508   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 509                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 510
 511   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 512   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 513
 514   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 515   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 516
 517   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 518   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 519   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 520   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 521   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 522                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 523   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 524   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 525                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 526
 527   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 528                         [genl_multicast_group], [id])
 529   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 530
 531   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 532   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 533   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 534   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 535   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 536   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 537                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 538   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 539                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 540
 541   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 542   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 543   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 544   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 545   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 546   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 547   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 548   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 549                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 550
 551   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 552
 553   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 554                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 555   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 556   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 557   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 558
 559   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 560
 561   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 562                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 563   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [VXLAN_HF_RCO])
 564   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 565                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 566                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 567   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 568   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum])
 569   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 570   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [ipv6_v6only],
 571                   [OVS_DEFINE([HAVE_UDP_TUNNEL_IPV6])])
 572
 573   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 574                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 575   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 576                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 577
 578   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 579                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 580
 581   if cmp -s datapath/linux/kcompat.h.new \
 582             datapath/linux/kcompat.h >/dev/null 2>&1; then
 583     rm datapath/linux/kcompat.h.new
 584   else
 585     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 586   fi
 587 ])
 588
 589 dnl Checks for net/if_packet.h.
 590 AC_DEFUN([OVS_CHECK_IF_PACKET],
 591   [AC_CHECK_HEADER([net/if_packet.h],
 592                    [HAVE_IF_PACKET=yes],
 593                    [HAVE_IF_PACKET=no])
 594    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 595    if test "$HAVE_IF_PACKET" = yes; then
 596       AC_DEFINE([HAVE_IF_PACKET], [1],
 597                 [Define to 1 if net/if_packet.h is available.])
 598    fi])
 599
 600 dnl Checks for net/if_dl.h.
 601 dnl
 602 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 603 dnl or NetBSD.)
 604 AC_DEFUN([OVS_CHECK_IF_DL],
 605   [AC_CHECK_HEADER([net/if_dl.h],
 606                    [HAVE_IF_DL=yes],
 607                    [HAVE_IF_DL=no])
 608    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 609    if test "$HAVE_IF_DL" = yes; then
 610       AC_DEFINE([HAVE_IF_DL], [1],
 611                 [Define to 1 if net/if_dl.h is available.])
 612
 613       # On these platforms we use libpcap to access network devices.
 614       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 615    fi])
 616
 617 dnl Checks for buggy strtok_r.
 618 dnl
 619 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 620 dnl with optimization that can cause segfaults:
 621 dnl
 622 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 623 AC_DEFUN([OVS_CHECK_STRTOK_R],
 624   [AC_CACHE_CHECK(
 625      [whether strtok_r macro segfaults on some inputs],
 626      [ovs_cv_strtok_r_bug],
 627      [AC_RUN_IFELSE(
 628         [AC_LANG_PROGRAM([#include <stdio.h>
 629                           #include <string.h>
 630                          ],
 631                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 632                            /* Assume bug is present, because relatively minor
 633                               changes in compiler settings (e.g. optimization
 634                               level) can make it crop up. */
 635                            return 1;
 636                            #else
 637                            char string[] = ":::";
 638                            char *save_ptr = (char *) 0xc0ffee;
 639                            char *token1, *token2;
 640                            token1 = strtok_r(string, ":", &save_ptr);
 641                            token2 = strtok_r(NULL, ":", &save_ptr);
 642                            freopen ("/dev/null", "w", stdout);
 643                            printf ("%s %s\n", token1, token2);
 644                            return 0;
 645                            #endif
 646                           ]])],
 647         [ovs_cv_strtok_r_bug=no],
 648         [ovs_cv_strtok_r_bug=yes],
 649         [ovs_cv_strtok_r_bug=yes])])
 650    if test $ovs_cv_strtok_r_bug = yes; then
 651      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 652                [Define if strtok_r macro segfaults on some inputs])
 653    fi
 654 ])
 655
 656 dnl ----------------------------------------------------------------------
 657 dnl These macros are from GNU PSPP, with the following original license:
 658 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 659 dnl This file is free software; the Free Software Foundation
 660 dnl gives unlimited permission to copy and/or distribute it,
 661 dnl with or without modifications, as long as this notice is preserved.
 662
 663 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 664   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 665   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 666     [ovs_save_CFLAGS="$CFLAGS"
 667      dnl Include -Werror in the compiler options, because without -Werror
 668      dnl clang's GCC-compatible compiler driver does not return a failure
 669      dnl exit status even though it complains about options it does not
 670      dnl understand.
 671      dnl
 672      dnl Also, check stderr as gcc exits with status 0 for options
 673      dnl rejected at getopt level.
 674      dnl    % touch /tmp/a.c
 675      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 676      dnl    gcc: unrecognized option '-Qunused-arguments'
 677      dnl    0
 678      dnl    %
 679      CFLAGS="$CFLAGS $WERROR $1"
 680      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
 681      CFLAGS="$ovs_save_CFLAGS"])
 682   if test $ovs_cv_name = yes; then
 683     m4_if([$2], [], [:], [$2])
 684   else
 685     m4_if([$3], [], [:], [$3])
 686   fi
 687 ])
 688
 689 dnl OVS_CHECK_WERROR
 690 dnl
 691 dnl Check whether the C compiler accepts -Werror.
 692 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 693 AC_DEFUN([OVS_CHECK_WERROR],
 694   [WERROR=
 695    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 696
 697 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 698 dnl Check whether the given C compiler OPTION is accepted.
 699 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 700 AC_DEFUN([OVS_CHECK_CC_OPTION],
 701   [AC_REQUIRE([OVS_CHECK_WERROR])
 702    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 703
 704 dnl OVS_ENABLE_OPTION([OPTION])
 705 dnl Check whether the given C compiler OPTION is accepted.
 706 dnl If so, add it to WARNING_FLAGS.
 707 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 708 AC_DEFUN([OVS_ENABLE_OPTION],
 709   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 710    AC_SUBST([WARNING_FLAGS])])
 711
 712 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 713 dnl Check whether the given C compiler OPTION is accepted.
 714 dnl If so, enable the given Automake CONDITIONAL.
 715
 716 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 717 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 718   [OVS_CHECK_CC_OPTION(
 719     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 720    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 721 dnl ----------------------------------------------------------------------
 722
 723 dnl Check for too-old XenServer.
 724 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 725   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 726     [if test -e /etc/redhat-release; then
 727        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 728      fi
 729      if test -z "$ovs_cv_xsversion"; then
 730        ovs_cv_xsversion=none
 731      fi])
 732   case $ovs_cv_xsversion in
 733     none)
 734       ;;
 735
 736     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 737     [[6-9]]* |                           dnl XenServer 6 or later
 738     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 739     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 740     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 741     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 742       ;;
 743
 744     *)
 745       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 746       ;;
 747   esac])
 748
 749 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 750 dnl
 751 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 752 dnl Runs 'if-true' if so, 'if-false' otherwise.
 753 AC_DEFUN([OVS_CHECK_MAKE_IF],
 754   [AC_CACHE_CHECK(
 755      [whether ${MAKE-make} has GNU make \$(if) extension],
 756      [ovs_cv_gnu_make_if],
 757      [cat <<'EOF' > conftest.mk
 758 conftest.out:
 759         echo $(if x,y,z) > conftest.out
 760 .PHONY: all
 761 EOF
 762       rm -f conftest.out
 763       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 764       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 765       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 766       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 767       result=`cat conftest.out`
 768       rm -f conftest.mk conftest.out
 769       if test "X$result" = "Xy"; then
 770         ovs_cv_gnu_make_if=yes
 771       else
 772         ovs_cv_gnu_make_if=no
 773       fi])])
 774
 775 dnl OVS_CHECK_GNU_MAKE
 776 dnl
 777 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 778 dnl only work with GNU make).
 779 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 780   [AC_CACHE_CHECK(
 781      [whether ${MAKE-make} is GNU make],
 782      [ovs_cv_gnu_make],
 783      [rm -f conftest.out
 784       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 785       ${MAKE-make} --version >conftest.out 2>&1
 786       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 787       result=`cat conftest.out`
 788       rm -f conftest.mk conftest.out
 789
 790       case $result in # (
 791         GNU*) ovs_cv_gnu_make=yes ;; # (
 792         *) ovs_cv_gnu_make=no ;;
 793       esac])
 794    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 795
 796 dnl OVS_CHECK_SPARSE_TARGET
 797 dnl
 798 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 799 dnl target for which the code is being built.  This helps it out.
 800 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 801   [AC_CACHE_CHECK(
 802     [target hint for cgcc],
 803     [ac_cv_sparse_target],
 804     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 805        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 806        [x86_64-*], [ac_cv_sparse_target=x86_64],
 807        [ac_cv_sparse_target=other])])
 808    AS_CASE([$ac_cv_sparse_target],
 809      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 810      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 811      [SPARSEFLAGS= CGCCFLAGS=])
 812    AC_SUBST([SPARSEFLAGS])
 813    AC_SUBST([CGCCFLAGS])])
 814
 815 dnl OVS_SPARSE_EXTRA_INCLUDES
 816 dnl
 817 dnl The cgcc script from "sparse" does not search gcc's default
 818 dnl search path. Get the default search path from GCC and pass
 819 dnl them to sparse.
 820 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 821     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 822            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 823
 824 dnl OVS_ENABLE_SPARSE
 825 AC_DEFUN([OVS_ENABLE_SPARSE],
 826   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 827    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 828    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 829    : ${SPARSE=sparse}
 830    AC_SUBST([SPARSE])
 831    AC_CONFIG_COMMANDS_PRE(
 832      [if test $ovs_cv_gnu_make_if = yes; then
 833         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 834       fi])])
 835
 836 dnl OVS_PTHREAD_SET_NAME
 837 dnl
 838 dnl This checks for three known variants of pthreads functions for setting
 839 dnl the name of the current thread:
 840 dnl
 841 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 842 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 843 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 844 dnl
 845 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 846 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 847 dnl provide to it.
 848 dnl
 849 dnl This macro defines:
 850 dnl
 851 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 852 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 853 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 854 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 855   [AC_CHECK_FUNCS([pthread_set_name_np])
 856    if test $ac_cv_func_pthread_set_name_np != yes; then
 857      AC_CACHE_CHECK(
 858        [for pthread_setname_np() variant],
 859        [ovs_cv_pthread_setname_np],
 860        [AC_LINK_IFELSE(
 861          [AC_LANG_PROGRAM([#include <pthread.h>
 862   ], [pthread_setname_np(pthread_self(), "name");])],
 863          [ovs_cv_pthread_setname_np=glibc],
 864          [AC_LINK_IFELSE(
 865            [AC_LANG_PROGRAM([#include <pthread.h>
 866 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 867            [ovs_cv_pthread_setname_np=netbsd],
 868            [ovs_cv_pthread_setname_np=none])])])
 869      case $ovs_cv_pthread_setname_np in # (
 870        glibc)
 871           AC_DEFINE(
 872             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 873             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 874           ;; # (
 875        netbsd)
 876           AC_DEFINE(
 877             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 878             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 879           ;;
 880      esac
 881    fi])
 882
 883 dnl OVS_CHECK_LINUX_HOST.
 884 dnl
 885 dnl Checks whether we're building for a Linux host, based on the presence of
 886 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 887 dnl LINUX based on the result.
 888 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 889   [AC_CACHE_CHECK(
 890      [whether __linux__ is defined],
 891      [ovs_cv_linux],
 892      [AC_COMPILE_IFELSE(
 893         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 894         [ovs_cv_linux=true],
 895         [ovs_cv_linux=false])])
 896    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])