acinclude.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015 Nicira, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl OVS_ENABLE_WERROR
  18 AC_DEFUN([OVS_ENABLE_WERROR],
  19   [AC_ARG_ENABLE(
  20      [Werror],
  21      [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
  22      [], [enable_Werror=no])
  23    AC_CONFIG_COMMANDS_PRE(
  24      [if test "X$enable_Werror" = Xyes; then
  25         OVS_CFLAGS="$OVS_CFLAGS -Werror"
  26       fi])])
  27
  28 dnl OVS_CHECK_LINUX
  29 dnl
  30 dnl Configure linux kernel source tree
  31 AC_DEFUN([OVS_CHECK_LINUX], [
  32   AC_ARG_WITH([linux],
  33               [AC_HELP_STRING([--with-linux=/path/to/linux],
  34                               [Specify the Linux kernel build directory])])
  35   AC_ARG_WITH([linux-source],
  36               [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
  37                               [Specify the Linux kernel source directory
  38                                (usually figured out automatically from build
  39                                directory)])])
  40
  41   # Deprecated equivalents to --with-linux, --with-linux-source.
  42   AC_ARG_WITH([l26])
  43   AC_ARG_WITH([l26-source])
  44
  45   if test X"$with_linux" != X; then
  46     KBUILD=$with_linux
  47   elif test X"$with_l26" != X; then
  48     KBUILD=$with_l26
  49     AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
  50   else
  51     KBUILD=
  52   fi
  53
  54   if test X"$KBUILD" != X; then
  55     if test X"$with_linux_source" != X; then
  56       KSRC=$with_linux_source
  57     elif test X"$with_l26_source" != X; then
  58       KSRC=$with_l26_source
  59       AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
  60     else
  61       KSRC=
  62     fi
  63   elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
  64     AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
  65   fi
  66
  67   if test -n "$KBUILD"; then
  68     KBUILD=`eval echo "$KBUILD"`
  69     case $KBUILD in
  70         /*) ;;
  71         *) KBUILD=`pwd`/$KBUILD ;;
  72     esac
  73
  74     # The build directory is what the user provided.
  75     # Make sure that it exists.
  76     AC_MSG_CHECKING([for Linux build directory])
  77     if test -d "$KBUILD"; then
  78         AC_MSG_RESULT([$KBUILD])
  79         AC_SUBST(KBUILD)
  80     else
  81         AC_MSG_RESULT([no])
  82         AC_ERROR([source dir $KBUILD doesn't exist])
  83     fi
  84
  85     # Debian breaks kernel headers into "source" header and "build" headers.
  86     # We want the source headers, but $KBUILD gives us the "build" headers.
  87     # Use heuristics to find the source headers.
  88     AC_MSG_CHECKING([for Linux source directory])
  89     if test -n "$KSRC"; then
  90       KSRC=`eval echo "$KSRC"`
  91       case $KSRC in
  92           /*) ;;
  93           *) KSRC=`pwd`/$KSRC ;;
  94       esac
  95       if test ! -e $KSRC/include/linux/kernel.h; then
  96         AC_MSG_ERROR([$KSRC is not a kernel source directory])
  97       fi
  98     else
  99       KSRC=$KBUILD
 100       if test ! -e $KSRC/include/linux/kernel.h; then
 101         # Debian kernel build Makefiles tend to include a line of the form:
 102         # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
 103         # First try to extract the source directory from this line.
 104         KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
 105         if test ! -e "$KSRC"/include/linux/kernel.h; then
 106           # Didn't work.  Fall back to name-based heuristics that used to work.
 107           case `echo "$KBUILD" | sed 's,/*$,,'` in # (
 108             */build)
 109               KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
 110               ;; # (
 111             *)
 112               KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
 113               ;;
 114           esac
 115         fi
 116       fi
 117       if test ! -e "$KSRC"/include/linux/kernel.h; then
 118         AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
 119       fi
 120     fi
 121     AC_MSG_RESULT([$KSRC])
 122
 123     AC_MSG_CHECKING([for kernel version])
 124     version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
 125     patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
 126     sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
 127     if test X"$version" = X || test X"$patchlevel" = X; then
 128        AC_ERROR([cannot determine kernel version])
 129     elif test X"$sublevel" = X; then
 130        kversion=$version.$patchlevel
 131     else
 132        kversion=$version.$patchlevel.$sublevel
 133     fi
 134     AC_MSG_RESULT([$kversion])
 135
 136     if test "$version" -ge 4; then
 137        if test "$version" = 4 && test "$patchlevel" -le 3; then
 138           : # Linux 4.x
 139        else
 140           AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.3.x is not supported (please refer to the FAQ for advice)])
 141        fi
 142     elif test "$version" = 3 && test "$patchlevel" -ge 10; then
 143        : # Linux 3.x
 144     else
 145        AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
 146     fi
 147     if (test ! -e "$KBUILD"/include/linux/version.h && \
 148         test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
 149        (test ! -e "$KBUILD"/include/linux/autoconf.h && \
 150         test ! -e "$KBUILD"/include/generated/autoconf.h); then
 151         AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
 152     fi
 153     OVS_CHECK_LINUX_COMPAT
 154   fi
 155   AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
 156 ])
 157
 158 dnl OVS_CHECK_DPDK
 159 dnl
 160 dnl Configure DPDK source tree
 161 AC_DEFUN([OVS_CHECK_DPDK], [
 162   AC_ARG_WITH([dpdk],
 163               [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
 164                               [Specify the DPDK build directory])])
 165
 166   AC_MSG_CHECKING([whether dpdk datapath is enabled])
 167   if test -z "$with_dpdk" || test "$with_dpdk" = no; then
 168     AC_MSG_RESULT([no])
 169     DPDKLIB_FOUND=false
 170   else
 171     AC_MSG_RESULT([yes])
 172     case "$with_dpdk" in
 173       yes)
 174         DPDK_AUTO_DISCOVER="true"
 175         DPDK_INCLUDE="/usr/local/include/dpdk -I/usr/include/dpdk"
 176         ;;
 177       *)
 178         DPDK_AUTO_DISCOVER="false"
 179         DPDK_INCLUDE="$with_dpdk/include"
 180         # If 'with_dpdk' is passed install directory, point to headers
 181         # installed in $DESTDIR/$prefix/include/dpdk
 182         AC_CHECK_FILE([$DPDK_INCLUDE/rte_config.h], [],
 183                       [AC_CHECK_FILE([$DPDK_INCLUDE/dpdk/rte_config.h],
 184                                      [DPDK_INCLUDE=$DPDK_INCLUDE/dpdk], [])])
 185         DPDK_LIB_DIR="$with_dpdk/lib"
 186         ;;
 187     esac
 188
 189     DPDK_LIB="-ldpdk"
 190     DPDK_EXTRA_LIB=""
 191
 192     ovs_save_CFLAGS="$CFLAGS"
 193     ovs_save_LDFLAGS="$LDFLAGS"
 194     CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
 195     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 196       LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
 197     fi
 198
 199     AC_COMPILE_IFELSE([
 200       AC_LANG_PROGRAM(
 201         [
 202           #include <rte_config.h>
 203 #if !RTE_LIBRTE_VHOST_USER
 204 #error
 205 #endif
 206         ], [])
 207       ], [],
 208       [AC_DEFINE([VHOST_CUSE], [1], [DPDK vhost-cuse support enabled, vhost-user disabled.])
 209        DPDK_EXTRA_LIB="-lfuse"])
 210
 211     # On some systems we have to add -ldl to link with dpdk
 212     #
 213     # This code, at first, tries to link without -ldl (""),
 214     # then adds it and tries again.
 215     # Before each attempt the search cache must be unset,
 216     # otherwise autoconf will stick with the old result
 217
 218     DPDKLIB_FOUND=false
 219     save_LIBS=$LIBS
 220     for extras in "" "-ldl"; do
 221         LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
 222         AC_LINK_IFELSE(
 223            [AC_LANG_PROGRAM([#include <rte_config.h>
 224                              #include <rte_eal.h>],
 225                             [int rte_argc; char ** rte_argv;
 226                              rte_eal_init(rte_argc, rte_argv);])],
 227            [DPDKLIB_FOUND=true])
 228         if $DPDKLIB_FOUND; then
 229             break
 230         fi
 231     done
 232
 233     # If linking unsuccessful
 234     if test "$DPDKLIB_FOUND" = "false" ; then
 235       if $DPDK_AUTO_DISCOVER; then
 236         AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
 237       else
 238         AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
 239       fi
 240     fi
 241     CFLAGS="$ovs_save_CFLAGS"
 242     LDFLAGS="$ovs_save_LDFLAGS"
 243     if test "$DPDK_AUTO_DISCOVER" = "false"; then
 244       OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
 245     fi
 246     OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE"
 247     OVS_ENABLE_OPTION([-mssse3])
 248
 249     # DPDK pmd drivers are not linked unless --whole-archive is used.
 250     #
 251     # This happens because the rest of the DPDK code doesn't use any symbol in
 252     # the pmd driver objects, and the drivers register themselves using an
 253     # __attribute__((constructor)) function.
 254     #
 255     # These options are specified inside a single -Wl directive to prevent
 256     # autotools from reordering them.
 257     DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
 258     AC_SUBST([DPDK_vswitchd_LDFLAGS])
 259     AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
 260   fi
 261
 262   AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
 263 ])
 264
 265 dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 266 dnl
 267 dnl Greps FILE for REGEX.  If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
 268 dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
 269 dnl <REGEX> translated to uppercase.
 270 AC_DEFUN([OVS_GREP_IFELSE], [
 271   AC_MSG_CHECKING([whether $2 matches in $1])
 272   if test -f $1; then
 273     grep '$2' $1 >/dev/null 2>&1
 274     status=$?
 275     case $status in
 276       0)
 277         AC_MSG_RESULT([yes])
 278         m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
 279         ;;
 280       1)
 281         AC_MSG_RESULT([no])
 282         $4
 283         ;;
 284       *)
 285         AC_MSG_ERROR([grep exited with status $status])
 286         ;;
 287     esac
 288   else
 289     AC_MSG_RESULT([file not found])
 290     $4
 291   fi
 292 ])
 293
 294 dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
 295 dnl
 296 dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
 297 dnl structure definition. If this is successful, runs IF-MATCH, otherwise
 298 dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
 299 dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
 300 dnl translated to uppercase.
 301 AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
 302   AC_MSG_CHECKING([whether $2 has member $3 in $1])
 303   if test -f $1; then
 304     awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
 305     status=$?
 306     case $status in
 307       0)
 308         AC_MSG_RESULT([yes])
 309         m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
 310         ;;
 311       1)
 312         AC_MSG_RESULT([no])
 313         $5
 314         ;;
 315       *)
 316         AC_MSG_ERROR([grep exited with status $status])
 317         ;;
 318     esac
 319   else
 320     AC_MSG_RESULT([file not found])
 321     $5
 322   fi
 323 ])
 324
 325 dnl OVS_DEFINE(NAME)
 326 dnl
 327 dnl Defines NAME to 1 in kcompat.h.
 328 AC_DEFUN([OVS_DEFINE], [
 329   echo '#define $1 1' >> datapath/linux/kcompat.h.new
 330 ])
 331
 332 dnl OVS_CHECK_LINUX_COMPAT
 333 dnl
 334 dnl Runs various Autoconf checks on the Linux kernel source in
 335 dnl the directory in $KBUILD.
 336 AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
 337   rm -f datapath/linux/kcompat.h.new
 338   mkdir -p datapath/linux
 339   : > datapath/linux/kcompat.h.new
 340
 341   echo '#include <linux/version.h>
 342 #ifndef RHEL_RELEASE_CODE
 343 #define RHEL_RELEASE_CODE 0
 344 #define RHEL_RELEASE_VERSION(a, b) 0
 345 #endif' >> datapath/linux/kcompat.h.new
 346
 347   OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
 348                   [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
 349
 350   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
 351                   [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
 352   OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
 353
 354   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
 355   OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
 356
 357   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
 358   OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
 359
 360   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
 361   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
 362   OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
 363   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
 364   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
 365
 366   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
 367   OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
 368   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
 369                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
 370   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
 371                   [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
 372
 373   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
 374                   [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
 375   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
 376                   [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
 377   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_do_fragment])
 378   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
 379
 380   OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
 381                   [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
 382   OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
 383   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
 384                   [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
 385   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
 386                   [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
 387   OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
 388   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 389                         [frags_work])
 390   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
 391                         [rwlock])
 392   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
 393                         [list_evictor])
 394   OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
 395                   [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
 396
 397   OVS_GREP_IFELSE([$KSRC/include/net/dst_metadata.h], [metadata_dst])
 398
 399   OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
 400                   [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
 401   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
 402   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
 403   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
 404   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
 405   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
 406   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
 407   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
 408   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
 409   dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
 410   dnl So check type of tstats.
 411   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
 412                   [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
 413   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
 414                   [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
 415   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
 416   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
 417                   [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
 418   OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
 419
 420   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
 421   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
 422   OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
 423                   [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
 424   OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
 425                         [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
 426
 427   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 428                   [tmpl_alloc.*conntrack_zone],
 429                   [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
 430   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
 431                   [l3num.*struct.net],
 432                   [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
 433   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
 434                   [nf_ct_zone_init])
 435   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
 436                   [nf_connlabels_get])
 437   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 438                   [nf_ct_frag6_consume_orig])
 439   OVS_GREP_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
 440                   [nf_ct_frag6_output])
 441
 442   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
 443   OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
 444
 445   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
 446   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
 447   OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
 448                   [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
 449   OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
 450
 451   OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
 452                   [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
 453                                    [rcu_read_lock_held])])
 454   OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
 455
 456   # Check for the proto_data_valid member in struct sk_buff.  The [^@]
 457   # is necessary because some versions of this header remove the
 458   # member but retain the kerneldoc comment that describes it (which
 459   # starts with @).  The brackets must be doubled because of m4
 460   # quoting rules.
 461   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
 462                   [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
 463   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
 464   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
 465   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_mac_header])
 466   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_network_header])
 467   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
 468   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_scrub_packet.*xnet],
 469                   [OVS_DEFINE([HAVE_SKB_SCRUB_PACKET_XNET])])
 470   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
 471   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
 472                   [OVS_DEFINE([HAVE_U16_RXHASH])])
 473   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
 474                   [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
 475   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 476                   [skb_copy_from_linear_data_offset])
 477   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
 478                   [skb_reset_tail_pointer])
 479   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
 480   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
 481                   [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
 482   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
 483   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
 484   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
 485   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
 486   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
 487   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
 488   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
 489   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash])
 490   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
 491   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
 492                   [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
 493   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
 494                   [OVS_DEFINE([HAVE_L4_RXHASH])])
 495   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
 496   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
 497   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
 498
 499   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
 500                   [OVS_DEFINE([HAVE_BOOL_TYPE])])
 501   OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
 502                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 503   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
 504                   [OVS_DEFINE([HAVE_CSUM_TYPES])])
 505
 506   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
 507   OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
 508
 509   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
 510   OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
 511
 512   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
 513   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
 514   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
 515   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_new_unicast])
 516   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
 517                   [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
 518   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
 519   OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
 520                   [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
 521
 522   OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
 523                         [genl_multicast_group], [id])
 524   OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
 525
 526   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
 527   OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
 528   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
 529   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
 530   OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
 531   OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
 532                   [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
 533   OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
 534                   [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
 535
 536   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
 537   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
 538   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
 539   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
 540   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
 541   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
 542   OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
 543   OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
 544                   [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
 545
 546   OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
 547
 548   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
 549                   [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
 550   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
 551   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
 552   OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
 553
 554   OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
 555
 556   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
 557                   [OVS_DEFINE([HAVE_VXLAN_METADATA])])
 558   OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [VXLAN_HF_RCO])
 559   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
 560                   [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
 561                                    [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
 562   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
 563   OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_set_csum])
 564   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
 565   OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [ipv6_v6only],
 566                   [OVS_DEFINE([HAVE_UDP_TUNNEL_IPV6])])
 567
 568   OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
 569                   [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
 570   OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
 571                   [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
 572
 573   OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
 574                   [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
 575
 576   if cmp -s datapath/linux/kcompat.h.new \
 577             datapath/linux/kcompat.h >/dev/null 2>&1; then
 578     rm datapath/linux/kcompat.h.new
 579   else
 580     mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
 581   fi
 582 ])
 583
 584 dnl Checks for net/if_packet.h.
 585 AC_DEFUN([OVS_CHECK_IF_PACKET],
 586   [AC_CHECK_HEADER([net/if_packet.h],
 587                    [HAVE_IF_PACKET=yes],
 588                    [HAVE_IF_PACKET=no])
 589    AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
 590    if test "$HAVE_IF_PACKET" = yes; then
 591       AC_DEFINE([HAVE_IF_PACKET], [1],
 592                 [Define to 1 if net/if_packet.h is available.])
 593    fi])
 594
 595 dnl Checks for net/if_dl.h.
 596 dnl
 597 dnl (We use this as a proxy for checking whether we're building on FreeBSD
 598 dnl or NetBSD.)
 599 AC_DEFUN([OVS_CHECK_IF_DL],
 600   [AC_CHECK_HEADER([net/if_dl.h],
 601                    [HAVE_IF_DL=yes],
 602                    [HAVE_IF_DL=no])
 603    AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
 604    if test "$HAVE_IF_DL" = yes; then
 605       AC_DEFINE([HAVE_IF_DL], [1],
 606                 [Define to 1 if net/if_dl.h is available.])
 607
 608       # On these platforms we use libpcap to access network devices.
 609       AC_SEARCH_LIBS([pcap_open_live], [pcap])
 610    fi])
 611
 612 dnl Checks for buggy strtok_r.
 613 dnl
 614 dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
 615 dnl with optimization that can cause segfaults:
 616 dnl
 617 dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
 618 AC_DEFUN([OVS_CHECK_STRTOK_R],
 619   [AC_CACHE_CHECK(
 620      [whether strtok_r macro segfaults on some inputs],
 621      [ovs_cv_strtok_r_bug],
 622      [AC_RUN_IFELSE(
 623         [AC_LANG_PROGRAM([#include <stdio.h>
 624                           #include <string.h>
 625                          ],
 626                          [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
 627                            /* Assume bug is present, because relatively minor
 628                               changes in compiler settings (e.g. optimization
 629                               level) can make it crop up. */
 630                            return 1;
 631                            #else
 632                            char string[] = ":::";
 633                            char *save_ptr = (char *) 0xc0ffee;
 634                            char *token1, *token2;
 635                            token1 = strtok_r(string, ":", &save_ptr);
 636                            token2 = strtok_r(NULL, ":", &save_ptr);
 637                            freopen ("/dev/null", "w", stdout);
 638                            printf ("%s %s\n", token1, token2);
 639                            return 0;
 640                            #endif
 641                           ]])],
 642         [ovs_cv_strtok_r_bug=no],
 643         [ovs_cv_strtok_r_bug=yes],
 644         [ovs_cv_strtok_r_bug=yes])])
 645    if test $ovs_cv_strtok_r_bug = yes; then
 646      AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
 647                [Define if strtok_r macro segfaults on some inputs])
 648    fi
 649 ])
 650
 651 dnl ----------------------------------------------------------------------
 652 dnl These macros are from GNU PSPP, with the following original license:
 653 dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
 654 dnl This file is free software; the Free Software Foundation
 655 dnl gives unlimited permission to copy and/or distribute it,
 656 dnl with or without modifications, as long as this notice is preserved.
 657
 658 AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
 659   m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-=], [__])])dnl
 660   AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
 661     [ovs_save_CFLAGS="$CFLAGS"
 662      dnl Include -Werror in the compiler options, because without -Werror
 663      dnl clang's GCC-compatible compiler driver does not return a failure
 664      dnl exit status even though it complains about options it does not
 665      dnl understand.
 666      dnl
 667      dnl Also, check stderr as gcc exits with status 0 for options
 668      dnl rejected at getopt level.
 669      dnl    % touch /tmp/a.c
 670      dnl    % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
 671      dnl    gcc: unrecognized option '-Qunused-arguments'
 672      dnl    0
 673      dnl    %
 674      CFLAGS="$CFLAGS $WERROR $1"
 675      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,)], [if test -s conftest.err && grep "unrecognized option" conftest.err; then ovs_cv_name[]=no; else ovs_cv_name[]=yes; fi], [ovs_cv_name[]=no])
 676      CFLAGS="$ovs_save_CFLAGS"])
 677   if test $ovs_cv_name = yes; then
 678     m4_if([$2], [], [:], [$2])
 679   else
 680     m4_if([$3], [], [:], [$3])
 681   fi
 682 ])
 683
 684 dnl OVS_CHECK_WERROR
 685 dnl
 686 dnl Check whether the C compiler accepts -Werror.
 687 dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
 688 AC_DEFUN([OVS_CHECK_WERROR],
 689   [WERROR=
 690    _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
 691
 692 dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
 693 dnl Check whether the given C compiler OPTION is accepted.
 694 dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
 695 AC_DEFUN([OVS_CHECK_CC_OPTION],
 696   [AC_REQUIRE([OVS_CHECK_WERROR])
 697    _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
 698
 699 dnl OVS_ENABLE_OPTION([OPTION])
 700 dnl Check whether the given C compiler OPTION is accepted.
 701 dnl If so, add it to WARNING_FLAGS.
 702 dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
 703 AC_DEFUN([OVS_ENABLE_OPTION],
 704   [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
 705    AC_SUBST([WARNING_FLAGS])])
 706
 707 dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
 708 dnl Check whether the given C compiler OPTION is accepted.
 709 dnl If so, enable the given Automake CONDITIONAL.
 710
 711 dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
 712 AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
 713   [OVS_CHECK_CC_OPTION(
 714     [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
 715    AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
 716 dnl ----------------------------------------------------------------------
 717
 718 dnl Check for too-old XenServer.
 719 AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
 720   [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
 721     [if test -e /etc/redhat-release; then
 722        ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
 723      fi
 724      if test -z "$ovs_cv_xsversion"; then
 725        ovs_cv_xsversion=none
 726      fi])
 727   case $ovs_cv_xsversion in
 728     none)
 729       ;;
 730
 731     [[1-9]][[0-9]]* |                    dnl XenServer 10 or later
 732     [[6-9]]* |                           dnl XenServer 6 or later
 733     5.[[7-9]]* |                         dnl XenServer 5.7 or later
 734     5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* |  dnl XenServer 5.6.1000 or later
 735     5.6.[[2-9]][[0-9]][[0-9]]* |         dnl XenServer 5.6.200 or later
 736     5.6.1[[0-9]][[0-9]])                 dnl Xenserver 5.6.100 or later
 737       ;;
 738
 739     *)
 740       AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported.  (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
 741       ;;
 742   esac])
 743
 744 dnl OVS_MAKE_HAS_IF([if-true], [if-false])
 745 dnl
 746 dnl Checks whether make has the GNU make $(if condition,then,else) extension.
 747 dnl Runs 'if-true' if so, 'if-false' otherwise.
 748 AC_DEFUN([OVS_CHECK_MAKE_IF],
 749   [AC_CACHE_CHECK(
 750      [whether ${MAKE-make} has GNU make \$(if) extension],
 751      [ovs_cv_gnu_make_if],
 752      [cat <<'EOF' > conftest.mk
 753 conftest.out:
 754         echo $(if x,y,z) > conftest.out
 755 .PHONY: all
 756 EOF
 757       rm -f conftest.out
 758       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} -f conftest.mk all:"]) >&AS_MESSAGE_LOG_FD 2>&1
 759       ${MAKE-make} -f conftest.mk conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 760       AS_ECHO(["$as_me:$LINENO: conftest.out contains:"]) >&AS_MESSAGE_LOG_FD 2>&1
 761       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 762       result=`cat conftest.out`
 763       rm -f conftest.mk conftest.out
 764       if test "X$result" = "Xy"; then
 765         ovs_cv_gnu_make_if=yes
 766       else
 767         ovs_cv_gnu_make_if=no
 768       fi])])
 769
 770 dnl OVS_CHECK_GNU_MAKE
 771 dnl
 772 dnl Checks whether make is GNU make (because Linux kernel Makefiles
 773 dnl only work with GNU make).
 774 AC_DEFUN([OVS_CHECK_GNU_MAKE],
 775   [AC_CACHE_CHECK(
 776      [whether ${MAKE-make} is GNU make],
 777      [ovs_cv_gnu_make],
 778      [rm -f conftest.out
 779       AS_ECHO(["$as_me:$LINENO: invoking ${MAKE-make} --version:"]) >&AS_MESSAGE_LOG_FD 2>&1
 780       ${MAKE-make} --version >conftest.out 2>&1
 781       cat conftest.out >&AS_MESSAGE_LOG_FD 2>&1
 782       result=`cat conftest.out`
 783       rm -f conftest.mk conftest.out
 784
 785       case $result in # (
 786         GNU*) ovs_cv_gnu_make=yes ;; # (
 787         *) ovs_cv_gnu_make=no ;;
 788       esac])
 789    AM_CONDITIONAL([GNU_MAKE], [test $ovs_cv_gnu_make = yes])])
 790
 791 dnl OVS_CHECK_SPARSE_TARGET
 792 dnl
 793 dnl The "cgcc" script from "sparse" isn't very good at detecting the
 794 dnl target for which the code is being built.  This helps it out.
 795 AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
 796   [AC_CACHE_CHECK(
 797     [target hint for cgcc],
 798     [ac_cv_sparse_target],
 799     [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
 800        [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
 801        [x86_64-*], [ac_cv_sparse_target=x86_64],
 802        [ac_cv_sparse_target=other])])
 803    AS_CASE([$ac_cv_sparse_target],
 804      [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
 805      [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
 806      [SPARSEFLAGS= CGCCFLAGS=])
 807    AC_SUBST([SPARSEFLAGS])
 808    AC_SUBST([CGCCFLAGS])])
 809
 810 dnl OVS_SPARSE_EXTRA_INCLUDES
 811 dnl
 812 dnl The cgcc script from "sparse" does not search gcc's default
 813 dnl search path. Get the default search path from GCC and pass
 814 dnl them to sparse.
 815 AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
 816     AC_SUBST([SPARSE_EXTRA_INCLUDES],
 817            [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
 818
 819 dnl OVS_ENABLE_SPARSE
 820 AC_DEFUN([OVS_ENABLE_SPARSE],
 821   [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
 822    AC_REQUIRE([OVS_CHECK_MAKE_IF])
 823    AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
 824    : ${SPARSE=sparse}
 825    AC_SUBST([SPARSE])
 826    AC_CONFIG_COMMANDS_PRE(
 827      [if test $ovs_cv_gnu_make_if = yes; then
 828         CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'
 829       fi])])
 830
 831 dnl OVS_PTHREAD_SET_NAME
 832 dnl
 833 dnl This checks for three known variants of pthreads functions for setting
 834 dnl the name of the current thread:
 835 dnl
 836 dnl   glibc: int pthread_setname_np(pthread_t, const char *name);
 837 dnl   NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
 838 dnl   FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
 839 dnl
 840 dnl For glibc and FreeBSD, the arguments are just a thread and its name.  For
 841 dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
 842 dnl provide to it.
 843 dnl
 844 dnl This macro defines:
 845 dnl
 846 dnl    glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
 847 dnl    NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
 848 dnl    FreeBSD: HAVE_PTHREAD_SET_NAME_NP
 849 AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
 850   [AC_CHECK_FUNCS([pthread_set_name_np])
 851    if test $ac_cv_func_pthread_set_name_np != yes; then
 852      AC_CACHE_CHECK(
 853        [for pthread_setname_np() variant],
 854        [ovs_cv_pthread_setname_np],
 855        [AC_LINK_IFELSE(
 856          [AC_LANG_PROGRAM([#include <pthread.h>
 857   ], [pthread_setname_np(pthread_self(), "name");])],
 858          [ovs_cv_pthread_setname_np=glibc],
 859          [AC_LINK_IFELSE(
 860            [AC_LANG_PROGRAM([#include <pthread.h>
 861 ], [pthread_setname_np(pthread_self(), "%s", "name");])],
 862            [ovs_cv_pthread_setname_np=netbsd],
 863            [ovs_cv_pthread_setname_np=none])])])
 864      case $ovs_cv_pthread_setname_np in # (
 865        glibc)
 866           AC_DEFINE(
 867             [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
 868             [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
 869           ;; # (
 870        netbsd)
 871           AC_DEFINE(
 872             [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
 873             [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
 874           ;;
 875      esac
 876    fi])
 877
 878 dnl OVS_CHECK_LINUX_HOST.
 879 dnl
 880 dnl Checks whether we're building for a Linux host, based on the presence of
 881 dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
 882 dnl LINUX based on the result.
 883 AC_DEFUN([OVS_CHECK_LINUX_HOST],
 884   [AC_CACHE_CHECK(
 885      [whether __linux__ is defined],
 886      [ovs_cv_linux],
 887      [AC_COMPILE_IFELSE(
 888         [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
 889         [ovs_cv_linux=true],
 890         [ovs_cv_linux=false])])
 891    AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])