m4/openvswitch.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009, 2010 Nicira Networks.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl Checks for --enable-coverage and updates CFLAGS and LDFLAGS appropriately.
  18 AC_DEFUN([OVS_CHECK_COVERAGE],
  19   [AC_REQUIRE([AC_PROG_CC])
  20    AC_ARG_ENABLE(
  21      [coverage],
  22      [AC_HELP_STRING([--enable-coverage],
  23                      [Enable gcov coverage tool.])],
  24      [case "${enableval}" in
  25         (lcov|yes) coverage=true ;;
  26         (no)  coverage=false ;;
  27         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-coverage]) ;;
  28       esac],
  29      [coverage=false])
  30    if $coverage; then
  31      CFLAGS="$CFLAGS -O0 --coverage"
  32      LDFLAGS="$LDFLAGS --coverage"
  33    fi])
  34
  35 dnl Checks for --enable-ndebug and defines NDEBUG if it is specified.
  36 AC_DEFUN([OVS_CHECK_NDEBUG],
  37   [AC_ARG_ENABLE(
  38      [ndebug],
  39      [AC_HELP_STRING([--enable-ndebug],
  40                      [Disable debugging features for max performance])],
  41      [case "${enableval}" in
  42         (yes) ndebug=true ;;
  43         (no)  ndebug=false ;;
  44         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-ndebug]) ;;
  45       esac],
  46      [ndebug=false])
  47    AM_CONDITIONAL([NDEBUG], [test x$ndebug = xtrue])])
  48
  49 dnl Checks for Netlink support.
  50 AC_DEFUN([OVS_CHECK_NETLINK],
  51   [AC_CHECK_HEADER([linux/netlink.h],
  52                    [HAVE_NETLINK=yes],
  53                    [HAVE_NETLINK=no],
  54                    [#include <sys/socket.h>
  55    #include <linux/types.h>
  56    ])
  57    AM_CONDITIONAL([HAVE_NETLINK], [test "$HAVE_NETLINK" = yes])
  58    if test "$HAVE_NETLINK" = yes; then
  59       AC_DEFINE([HAVE_NETLINK], [1],
  60                 [Define to 1 if Netlink protocol is available.])
  61    fi])
  62
  63 dnl Checks for OpenSSL, if --enable-ssl is passed in.
  64 AC_DEFUN([OVS_CHECK_OPENSSL],
  65   [AC_ARG_ENABLE(
  66      [ssl],
  67      [AC_HELP_STRING([--enable-ssl],
  68                      [Enable ssl support (requires libssl)])],
  69      [case "${enableval}" in
  70         (yes) ssl=true ;;
  71         (no)  ssl=false ;;
  72         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-ssl]) ;;
  73       esac],
  74      [ssl=false])
  75
  76    if test "$ssl" = true; then
  77        dnl Make sure that pkg-config is installed.
  78        m4_pattern_forbid([PKG_CHECK_MODULES])
  79        PKG_CHECK_MODULES([SSL], [libssl],
  80          [HAVE_OPENSSL=yes],
  81          [HAVE_OPENSSL=no
  82           AC_MSG_WARN([Cannot find libssl:
  83
  84 $SSL_PKG_ERRORS
  85
  86 OpenFlow connections over SSL will not be supported.])])
  87    else
  88        HAVE_OPENSSL=no
  89    fi
  90    AC_SUBST([HAVE_OPENSSL])
  91    AM_CONDITIONAL([HAVE_OPENSSL], [test "$HAVE_OPENSSL" = yes])
  92    if test "$HAVE_OPENSSL" = yes; then
  93       AC_DEFINE([HAVE_OPENSSL], [1], [Define to 1 if OpenSSL is installed.])
  94    fi])
  95
  96 dnl Checks for libraries needed by lib/socket-util.c.
  97 AC_DEFUN([OVS_CHECK_SOCKET_LIBS],
  98   [AC_CHECK_LIB([socket], [connect])
  99    AC_SEARCH_LIBS([gethostbyname], [resolv], [RESOLVER_LIBS=-lresolv])])
 100
 101 dnl Checks for the directory in which to store the PKI.
 102 AC_DEFUN([OVS_CHECK_PKIDIR],
 103   [AC_ARG_WITH(
 104      [pkidir],
 105      AC_HELP_STRING([--with-pkidir=DIR],
 106                     [PKI hierarchy directory [[DATADIR/openvswitch/pki]]]),
 107      [PKIDIR=$withval],
 108      [PKIDIR='${pkgdatadir}/pki'])
 109    AC_SUBST([PKIDIR])])
 110
 111 dnl Checks for the directory in which to store pidfiles.
 112 AC_DEFUN([OVS_CHECK_RUNDIR],
 113   [AC_ARG_WITH(
 114      [rundir],
 115      AC_HELP_STRING([--with-rundir=DIR],
 116                     [directory used for pidfiles
 117                     [[LOCALSTATEDIR/run/openvswitch]]]),
 118      [RUNDIR=$withval],
 119      [RUNDIR='${localstatedir}/run/openvswitch'])
 120    AC_SUBST([RUNDIR])])
 121
 122 dnl Checks for the directory in which to store logs.
 123 AC_DEFUN([OVS_CHECK_LOGDIR],
 124   [AC_ARG_WITH(
 125      [logdir],
 126      AC_HELP_STRING([--with-logdir=DIR],
 127                     [directory used for logs [[LOCALSTATEDIR/log/PACKAGE]]]),
 128      [LOGDIR=$withval],
 129      [LOGDIR='${localstatedir}/log/${PACKAGE}'])
 130    AC_SUBST([LOGDIR])])
 131
 132 dnl Checks for __malloc_hook, etc., supported by glibc.
 133 AC_DEFUN([OVS_CHECK_MALLOC_HOOKS],
 134   [AC_CACHE_CHECK(
 135     [whether libc supports hooks for malloc and related functions],
 136     [ovs_cv_malloc_hooks],
 137     [AC_COMPILE_IFELSE(
 138       [AC_LANG_PROGRAM(
 139          [#include <malloc.h>
 140          ],
 141          [(void) __malloc_hook;
 142           (void) __realloc_hook;
 143           (void) __free_hook;])],
 144       [ovs_cv_malloc_hooks=yes],
 145       [ovs_cv_malloc_hooks=no])])
 146    if test $ovs_cv_malloc_hooks = yes; then
 147      AC_DEFINE([HAVE_MALLOC_HOOKS], [1],
 148                [Define to 1 if you have __malloc_hook, __realloc_hook, and
 149                 __free_hook in <malloc.h>.])
 150    fi])
 151
 152 dnl Checks for valgrind/valgrind.h.
 153 AC_DEFUN([OVS_CHECK_VALGRIND],
 154   [AC_CHECK_HEADERS([valgrind/valgrind.h])])
 155
 156 dnl Searches for a directory to put lockfiles for tty devices.
 157 dnl Defines C preprocessor variable TTY_LOCK_DIR to a quoted string
 158 dnl for that directory.
 159 AC_DEFUN([OVS_CHECK_TTY_LOCK_DIR],
 160   [AC_CACHE_CHECK([directory used for serial device lockfiles],
 161                   [ovs_cv_path_tty_locks],
 162                   [# This list of candidate directories is from minicom.
 163                    ovs_cv_path_tty_locks=none
 164                    for dir in /etc/locks /var/lock /usr/spool/locks \
 165                               /var/spool/locks /var/spool/lock \
 166                               /usr/spool/uucp /var/spool/uucp /var/run; do
 167                      if test -d $dir; then
 168                        ovs_cv_path_tty_locks=$dir
 169                        break
 170                      fi
 171                    done])
 172    if test "$ovs_cv_path_tty_locks" = none; then
 173      AC_MSG_ERROR([cannot find a directory for tty locks])
 174    fi
 175    AC_DEFINE_UNQUOTED([TTY_LOCK_DIR], "$ovs_cv_path_tty_locks",
 176                       [Directory used for serial device lockfiles])])
 177
 178 dnl The following check is adapted from GNU PSPP.
 179 dnl It searches for the ncurses library.  If it finds it, it sets
 180 dnl HAVE_CURSES to yes and sets NCURSES_LIBS and NCURSES_CFLAGS
 181 dnl appropriate.  Otherwise, it sets HAVE_CURSES to no.
 182 AC_DEFUN([OVS_CHECK_CURSES],
 183   [if test "$cross_compiling" != yes; then
 184      AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 185    fi
 186    if test "$NCURSES_CONFIG" = ""; then
 187      AC_SEARCH_LIBS([tgetent], [ncurses],
 188          [AC_CHECK_HEADERS([term.h curses.h],
 189                            [HAVE_CURSES=yes],
 190                            [HAVE_CURSES=no])])
 191    else
 192      save_cflags=$CFLAGS
 193      CFLAGS="$CFLAGS $($NCURSES_CONFIG --cflags)"
 194      AC_CHECK_HEADERS([term.h curses.h],
 195                       [HAVE_CURSES=yes],
 196                       [HAVE_CURSES=no])
 197      CFLAGS=$save_cflags
 198      if test "$HAVE_CURSES" = yes; then
 199        NCURSES_LIBS=$($NCURSES_CONFIG --libs)
 200        NCURSES_CFLAGS=$($NCURSES_CONFIG --cflags)
 201        AC_SUBST(NCURSES_CFLAGS)
 202        AC_SUBST(NCURSES_LIBS)
 203      fi
 204    fi
 205    AM_CONDITIONAL([HAVE_CURSES], [test "$HAVE_CURSES" = yes])])
 206
 207 dnl Checks for linux/vt.h.
 208 AC_DEFUN([OVS_CHECK_LINUX_VT_H],
 209   [AC_CHECK_HEADER([linux/vt.h],
 210                    [HAVE_LINUX_VT_H=yes],
 211                    [HAVE_LINUX_VT_H=no])
 212    AM_CONDITIONAL([HAVE_LINUX_VT_H], [test "$HAVE_LINUX_VT_H" = yes])
 213    if test "$HAVE_LINUX_VT_H" = yes; then
 214       AC_DEFINE([HAVE_LINUX_VT_H], [1],
 215                 [Define to 1 if linux/vt.h is available.])
 216    fi])
 217
 218 dnl Checks for libpcre.
 219 dnl
 220 dnl ezio-term wants libpcre that supports the PCRE_PARTIAL feature,
 221 dnl which is libpcre 7.2 or later.
 222 AC_DEFUN([OVS_CHECK_PCRE],
 223   [dnl Make sure that pkg-config is installed.
 224    m4_pattern_forbid([PKG_CHECK_MODULES])
 225    PKG_CHECK_MODULES([PCRE],
 226                      [libpcre >= 7.2],
 227                      [HAVE_PCRE_PARTIAL=yes],
 228                      [HAVE_PCRE_PARTIAL=no])
 229    AM_CONDITIONAL([HAVE_PCRE_PARTIAL], [test "$HAVE_PCRE_PARTIAL" = yes])
 230    AC_SUBST([HAVE_PCRE_PARTIAL])
 231 ])
 232
 233 dnl Checks for Python 2.x, x >= 4.
 234 AC_DEFUN([OVS_CHECK_PYTHON],
 235   [AC_CACHE_CHECK(
 236      [for Python 2.x for x >= 4],
 237      [ovs_cv_python],
 238      [if test -n "$PYTHON"; then
 239         ovs_cv_python=$PYTHON
 240       else
 241         ovs_cv_python=no
 242         for binary in python python2.4 python2.5; do
 243           ovs_save_IFS=$IFS; IFS=$PATH_SEPARATOR
 244           for dir in $PATH; do
 245             IFS=$ovs_save_IFS
 246             test -z "$dir" && dir=.
 247             if test -x $dir/$binary && $dir/$binary -c 'import sys
 248 if sys.hexversion >= 0x02040000 and sys.hexversion < 0x03000000:
 249     sys.exit(0)
 250 else:
 251     sys.exit(1)'; then
 252               ovs_cv_python=$dir/$binary
 253               break 2
 254             fi
 255           done
 256         done
 257       fi])
 258    AC_SUBST([HAVE_PYTHON])
 259    AM_MISSING_PROG([PYTHON], [python])
 260    if test $ovs_cv_python != no; then
 261      PYTHON=$ovs_cv_python
 262      HAVE_PYTHON=yes
 263    else
 264      HAVE_PYTHON=no
 265    fi
 266    AM_CONDITIONAL([HAVE_PYTHON], [test "$HAVE_PYTHON" = yes])])
 267
 268 dnl Checks for pyuic4.
 269 AC_DEFUN([OVS_CHECK_PYUIC4],
 270   [AC_CACHE_CHECK(
 271     [for pyuic4],
 272     [ovs_cv_pyuic4],
 273     [if (pyuic4 --version) >/dev/null 2>&1; then
 274        ovs_cv_pyuic4=pyuic4
 275      else
 276        ovs_cv_pyuic4=no
 277      fi])
 278    AM_MISSING_PROG([PYUIC4], [pyuic4])
 279    if test $ovs_cv_pyuic4 != no; then
 280      PYUIC4=$ovs_cv_pyuic4
 281    fi])
 282
 283 dnl Checks whether $PYTHON supports the module given as $1
 284 AC_DEFUN([OVS_CHECK_PYTHON_MODULE],
 285   [AC_REQUIRE([OVS_CHECK_PYTHON])
 286    AC_CACHE_CHECK(
 287      [for $1 Python module],
 288      [ovs_cv_py_[]AS_TR_SH([$1])],
 289      [ovs_cv_py_[]AS_TR_SH([$1])=no
 290       if test $HAVE_PYTHON = yes; then
 291         AS_ECHO(["running $PYTHON -c 'import $1
 292 import sys
 293 sys.exit(0)'..."]) >&AS_MESSAGE_LOG_FD 2>&1
 294         if $PYTHON -c 'import $1
 295 import sys
 296 sys.exit(0)' >&AS_MESSAGE_LOG_FD 2>&1; then
 297           ovs_cv_py_[]AS_TR_SH([$1])=yes
 298         fi
 299       fi])])
 300
 301 dnl Checks for Python modules needed by ovsdbmonitor.
 302 AC_DEFUN([OVS_CHECK_OVSDBMONITOR],
 303   [OVS_CHECK_PYTHON_MODULE([PySide.QtCore])
 304    OVS_CHECK_PYTHON_MODULE([PyQt4.QtCore])
 305    OVS_CHECK_PYTHON_MODULE([twisted.conch.ssh])
 306    OVS_CHECK_PYTHON_MODULE([twisted.internet])
 307    OVS_CHECK_PYTHON_MODULE([twisted.application])
 308    OVS_CHECK_PYTHON_MODULE([json])
 309    OVS_CHECK_PYTHON_MODULE([zope.interface])
 310    if (test $ovs_cv_py_PySide_QtCore = yes \
 311        || test $ovs_cv_py_PyQt4_QtCore = yes) \
 312       && test $ovs_cv_py_twisted_conch_ssh = yes \
 313       && test $ovs_cv_py_twisted_internet = yes \
 314       && test $ovs_cv_py_twisted_application = yes \
 315       && test $ovs_cv_py_json = yes \
 316       && test $ovs_cv_py_zope_interface = yes; then
 317      BUILD_OVSDBMONITOR=yes
 318    else
 319      BUILD_OVSDBMONITOR=no
 320    fi
 321    AC_MSG_CHECKING([whether to build ovsdbmonitor])
 322    AC_MSG_RESULT([$BUILD_OVSDBMONITOR])
 323    AM_CONDITIONAL([BUILD_OVSDBMONITOR], [test $BUILD_OVSDBMONITOR = yes])])