m4/openvswitch.m4

   1 # -*- autoconf -*-
   2
   3 # Copyright (c) 2008, 2009 Nicira Networks.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at:
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 dnl Checks for --enable-coverage and updates CFLAGS and LDFLAGS appropriately.
  18 AC_DEFUN([OVS_CHECK_COVERAGE],
  19   [AC_REQUIRE([AC_PROG_CC])
  20    AC_ARG_ENABLE(
  21      [coverage],
  22      [AC_HELP_STRING([--enable-coverage],
  23                      [Enable gcov coverage tool.])],
  24      [case "${enableval}" in
  25         (lcov) coverage=true lcov=true ;;
  26         (yes) coverage=true lcov=false ;;
  27         (no)  coverage=false lcov=false ;;
  28         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-coverage]) ;;
  29       esac],
  30      [coverage=false lcov=false])
  31    if $coverage; then
  32      CFLAGS="$CFLAGS -O0 --coverage"
  33      LDFLAGS="$LDFLAGS --coverage"
  34    fi
  35    if $lcov; then
  36      if lcov --version >/dev/null 2>&1; then :; else
  37        AC_MSG_ERROR([--enable-coverage=lcov was specified but lcov is not in \$PATH])
  38      fi
  39    fi
  40    AC_SUBST([LCOV], [$lcov])])
  41
  42 dnl Checks for --enable-ndebug and defines NDEBUG if it is specified.
  43 AC_DEFUN([OVS_CHECK_NDEBUG],
  44   [AC_ARG_ENABLE(
  45      [ndebug],
  46      [AC_HELP_STRING([--enable-ndebug],
  47                      [Disable debugging features for max performance])],
  48      [case "${enableval}" in
  49         (yes) ndebug=true ;;
  50         (no)  ndebug=false ;;
  51         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-ndebug]) ;;
  52       esac],
  53      [ndebug=false])
  54    AM_CONDITIONAL([NDEBUG], [test x$ndebug = xtrue])])
  55
  56 dnl Checks for Netlink support.
  57 AC_DEFUN([OVS_CHECK_NETLINK],
  58   [AC_CHECK_HEADER([linux/netlink.h],
  59                    [HAVE_NETLINK=yes],
  60                    [HAVE_NETLINK=no],
  61                    [#include <sys/socket.h>
  62    #include <linux/types.h>
  63    ])
  64    AM_CONDITIONAL([HAVE_NETLINK], [test "$HAVE_NETLINK" = yes])
  65    if test "$HAVE_NETLINK" = yes; then
  66       AC_DEFINE([HAVE_NETLINK], [1],
  67                 [Define to 1 if Netlink protocol is available.])
  68    fi])
  69
  70 dnl Checks for OpenSSL, if --enable-ssl is passed in.
  71 AC_DEFUN([OVS_CHECK_OPENSSL],
  72   [AC_ARG_ENABLE(
  73      [ssl],
  74      [AC_HELP_STRING([--enable-ssl],
  75                      [Enable ssl support (requires libssl)])],
  76      [case "${enableval}" in
  77         (yes) ssl=true ;;
  78         (no)  ssl=false ;;
  79         (*) AC_MSG_ERROR([bad value ${enableval} for --enable-ssl]) ;;
  80       esac],
  81      [ssl=false])
  82
  83    if test "$ssl" = true; then
  84    dnl Make sure that pkg-config is installed.
  85    m4_pattern_forbid([PKG_CHECK_MODULES])
  86    PKG_CHECK_MODULES([SSL], [libssl],
  87      [HAVE_OPENSSL=yes],
  88      [HAVE_OPENSSL=no
  89       AC_MSG_WARN([Cannot find libssl:
  90
  91    $SSL_PKG_ERRORS
  92
  93    OpenFlow connections over SSL will not be supported.])])
  94
  95    fi
  96    AM_CONDITIONAL([HAVE_OPENSSL], [test "$HAVE_OPENSSL" = yes])
  97    if test "$HAVE_OPENSSL" = yes; then
  98       AC_DEFINE([HAVE_OPENSSL], [1], [Define to 1 if OpenSSL is installed.])
  99    fi])
 100
 101 dnl Checks for libraries needed by lib/socket-util.c.
 102 AC_DEFUN([OVS_CHECK_SOCKET_LIBS],
 103   [AC_CHECK_LIB([socket], [connect])
 104    AC_SEARCH_LIBS([gethostbyname], [resolv], [RESOLVER_LIBS=-lresolv])])
 105
 106 dnl Checks for the directory in which to store the PKI.
 107 AC_DEFUN([OVS_CHECK_PKIDIR],
 108   [AC_ARG_WITH(
 109      [pkidir],
 110      AC_HELP_STRING([--with-pkidir=DIR],
 111                     [PKI hierarchy directory [[DATADIR/openvswitch/pki]]]),
 112      [PKIDIR=$withval],
 113      [PKIDIR='${pkgdatadir}/pki'])
 114    AC_SUBST([PKIDIR])])
 115
 116 dnl Checks for the directory in which to store pidfiles.
 117 AC_DEFUN([OVS_CHECK_RUNDIR],
 118   [AC_ARG_WITH(
 119      [rundir],
 120      AC_HELP_STRING([--with-rundir=DIR],
 121                     [directory used for pidfiles [[LOCALSTATEDIR/run]]]),
 122      [RUNDIR=$withval],
 123      [RUNDIR='${localstatedir}/run'])
 124    AC_SUBST([RUNDIR])])
 125
 126 dnl Checks for the directory in which to store logs.
 127 AC_DEFUN([OVS_CHECK_LOGDIR],
 128   [AC_ARG_WITH(
 129      [logdir],
 130      AC_HELP_STRING([--with-logdir=DIR],
 131                     [directory used for logs [[LOCALSTATEDIR/log/PACKAGE]]]),
 132      [LOGDIR=$withval],
 133      [LOGDIR='${localstatedir}/log/${PACKAGE}'])
 134    AC_SUBST([LOGDIR])])
 135
 136 dnl Checks for __malloc_hook, etc., supported by glibc.
 137 AC_DEFUN([OVS_CHECK_MALLOC_HOOKS],
 138   [AC_CACHE_CHECK(
 139     [whether libc supports hooks for malloc and related functions],
 140     [ovs_cv_malloc_hooks],
 141     [AC_COMPILE_IFELSE(
 142       [AC_LANG_PROGRAM(
 143          [#include <malloc.h>
 144          ],
 145          [(void) __malloc_hook;
 146           (void) __realloc_hook;
 147           (void) __free_hook;])],
 148       [ovs_cv_malloc_hooks=yes],
 149       [ovs_cv_malloc_hooks=no])])
 150    if test $ovs_cv_malloc_hooks = yes; then
 151      AC_DEFINE([HAVE_MALLOC_HOOKS], [1],
 152                [Define to 1 if you have __malloc_hook, __realloc_hook, and
 153                 __free_hook in <malloc.h>.])
 154    fi])
 155
 156 dnl Checks for valgrind/valgrind.h.
 157 AC_DEFUN([OVS_CHECK_VALGRIND],
 158   [AC_CHECK_HEADERS([valgrind/valgrind.h])])
 159
 160 dnl Searches for a directory to put lockfiles for tty devices.
 161 dnl Defines C preprocessor variable TTY_LOCK_DIR to a quoted string
 162 dnl for that directory.
 163 AC_DEFUN([OVS_CHECK_TTY_LOCK_DIR],
 164   [AC_CACHE_CHECK([directory used for serial device lockfiles],
 165                   [ovs_cv_path_tty_locks],
 166                   [# This list of candidate directories is from minicom.
 167                    ovs_cv_path_tty_locks=none
 168                    for dir in /etc/locks /var/lock /usr/spool/locks \
 169                               /var/spool/locks /var/spool/lock \
 170                               /usr/spool/uucp /var/spool/uucp /var/run; do
 171                      if test -d $dir; then
 172                        ovs_cv_path_tty_locks=$dir
 173                        break
 174                      fi
 175                    done])
 176    if test "$ovs_cv_path_tty_locks" = none; then
 177      AC_MSG_ERROR([cannot find a directory for tty locks])
 178    fi
 179    AC_DEFINE_UNQUOTED([TTY_LOCK_DIR], "$ovs_cv_path_tty_locks",
 180                       [Directory used for serial device lockfiles])])
 181
 182 dnl The following check is adapted from GNU PSPP.
 183 dnl It searches for the ncurses library.  If it finds it, it sets
 184 dnl HAVE_CURSES to yes and sets NCURSES_LIBS and NCURSES_CFLAGS
 185 dnl appropriate.  Otherwise, it sets HAVE_CURSES to no.
 186 AC_DEFUN([OVS_CHECK_CURSES],
 187   [if test "$cross_compiling" != yes; then
 188      AC_CHECK_PROGS([NCURSES_CONFIG], [ncurses5-config ncurses8-config])
 189    fi
 190    if test "$NCURSES_CONFIG" = ""; then
 191      AC_SEARCH_LIBS([tgetent], [ncurses],
 192          [AC_CHECK_HEADERS([term.h curses.h],
 193                            [HAVE_CURSES=yes],
 194                            [HAVE_CURSES=no])])
 195    else
 196      save_cflags=$CFLAGS
 197      CFLAGS="$CFLAGS $($NCURSES_CONFIG --cflags)"
 198      AC_CHECK_HEADERS([term.h curses.h],
 199                       [HAVE_CURSES=yes],
 200                       [HAVE_CURSES=no])
 201      CFLAGS=$save_cflags
 202      if test "$HAVE_CURSES" = yes; then
 203        NCURSES_LIBS=$($NCURSES_CONFIG --libs)
 204        NCURSES_CFLAGS=$($NCURSES_CONFIG --cflags)
 205        AC_SUBST(NCURSES_CFLAGS)
 206        AC_SUBST(NCURSES_LIBS)
 207      fi
 208    fi
 209    AM_CONDITIONAL([HAVE_CURSES], [test "$HAVE_CURSES" = yes])])
 210
 211 dnl Checks for linux/vt.h.
 212 AC_DEFUN([OVS_CHECK_LINUX_VT_H],
 213   [AC_CHECK_HEADER([linux/vt.h],
 214                    [HAVE_LINUX_VT_H=yes],
 215                    [HAVE_LINUX_VT_H=no])
 216    AM_CONDITIONAL([HAVE_LINUX_VT_H], [test "$HAVE_LINUX_VT_H" = yes])
 217    if test "$HAVE_LINUX_VT_H" = yes; then
 218       AC_DEFINE([HAVE_LINUX_VT_H], [1],
 219                 [Define to 1 if linux/vt.h is available.])
 220    fi])
 221
 222 dnl Checks for libpcre.
 223 AC_DEFUN([OVS_CHECK_PCRE],
 224   [dnl Make sure that pkg-config is installed.
 225    m4_pattern_forbid([PKG_CHECK_MODULES])
 226    PKG_CHECK_MODULES([PCRE], [libpcre >= 7.2], [HAVE_PCRE=yes], [HAVE_PCRE=no])
 227    AM_CONDITIONAL([HAVE_PCRE], [test "$HAVE_PCRE" = yes])
 228    if test "$HAVE_PCRE" = yes; then
 229       AC_DEFINE([HAVE_PCRE], [1], [Define to 1 if libpcre is installed.])
 230    fi])
 231
 232 dnl Checks for Python 2.x, x >= 4.
 233 AC_DEFUN([OVS_CHECK_PYTHON],
 234   [AC_CACHE_CHECK(
 235      [for Python 2.x for x >= 4],
 236      [ovs_cv_python],
 237      [if test -n "$PYTHON"; then
 238         ovs_cv_python=$PYTHON
 239       else
 240         ovs_cv_python=no
 241         for binary in python python2.4 python2.5; do
 242           ovs_save_IFS=$IFS; IFS=$PATH_SEPARATOR
 243           for dir in $PATH; do
 244             IFS=$ovs_save_IFS
 245             test -z "$dir" && dir=.
 246             if test -x $dir/$binary && $dir/$binary -c 'import sys
 247 if sys.hexversion >= 0x02040000 and sys.hexversion < 0x03000000:
 248     sys.exit(0)
 249 else:
 250     sys.exit(1)'; then
 251               ovs_cv_python=$dir/$binary
 252               break 2
 253             fi
 254           done
 255         done
 256       fi])
 257    AM_MISSING_PROG([PYTHON], [python])
 258    if test $ovs_cv_python != no; then
 259      PYTHON=$ovs_cv_python
 260    fi])