tests/system-common-macros.at

   1 # DEL_NAMESPACES(ns [, ns ... ])
   2 #
   3 # Delete namespaces from the running OS
   4 m4_define([DEL_NAMESPACES],
   5    [m4_foreach([ns], [$@],
   6                [ip netns del ns
   7 ])
   8    ]
   9 )
  10
  11 # ADD_NAMESPACES(ns [, ns ... ])
  12 #
  13 # Add new namespaces, if ns exists, the old one
  14 # will be remove before new ones are installed.
  15 m4_define([ADD_NAMESPACES],
  16    [m4_foreach([ns], [$@],
  17                [DEL_NAMESPACES(ns)
  18                 AT_CHECK([ip netns add ns])
  19                 on_exit 'DEL_NAMESPACES(ns)'
  20                ])
  21    ]
  22 )
  23
  24 # NS_EXEC([namespace], [command])
  25 #
  26 # Execute 'command' in 'namespace'
  27 m4_define([NS_EXEC],
  28     [ip netns exec $1 sh << NS_EXEC_HEREDOC
  29 $2
  30 NS_EXEC_HEREDOC])
  31
  32 # NS_CHECK_EXEC([namespace], [command], other_params...)
  33 #
  34 # Wrapper for AT_CHECK that executes 'command' inside 'namespace'.
  35 # 'other_params' as passed as they are to AT_CHECK.
  36 m4_define([NS_CHECK_EXEC],
  37     [ AT_CHECK([NS_EXEC([$1], [$2])], m4_shift(m4_shift($@))) ]
  38 )
  39
  40 # ADD_BR([name], [vsctl-args])
  41 #
  42 # Expands into the proper ovs-vsctl commands to create a bridge with the
  43 # appropriate type, and allows additional arguments to be passed.
  44 m4_define([ADD_BR], [ovs-vsctl _ADD_BR([$1]) -- $2])
  45
  46 # ADD_INT([port], [namespace], [ovs-br], [ip_addr])
  47 #
  48 # Add an internal port to 'ovs-br', then shift it into 'namespace' and
  49 # configure it with 'ip_addr' (specified in CIDR notation).
  50 m4_define([ADD_INT],
  51     [ AT_CHECK([ovs-vsctl add-port $3 $1 -- set int $1 type=internal])
  52       AT_CHECK([ip link set $1 netns $2])
  53       NS_CHECK_EXEC([$2], [ip addr add $4 dev $1])
  54       NS_CHECK_EXEC([$2], [ip link set dev $1 up])
  55     ]
  56 )
  57
  58 # ADD_VETH([port], [namespace], [ovs-br], [ip_addr])
  59 #
  60 # Add a pair of veth ports. 'port' will be added to name space 'namespace',
  61 # and "ovs-'port'" will be added to ovs bridge 'ovs-br'.
  62 #
  63 # The 'port' in 'namespace' will be brought up with static IP address
  64 # with 'ip_addr' in CIDR notation.
  65 #
  66 # The existing 'port' or 'ovs-port' will be removed before new ones are added.
  67 #
  68 m4_define([ADD_VETH],
  69     [ AT_CHECK([ip link add $1 type veth peer name ovs-$1])
  70       AT_CHECK([ip link set $1 netns $2])
  71       AT_CHECK([ip link set dev ovs-$1 up])
  72       AT_CHECK([ovs-vsctl add-port $3 ovs-$1])
  73       NS_CHECK_EXEC([$2], [ip addr add $4 dev $1])
  74       NS_CHECK_EXEC([$2], [ip link set dev $1 up])
  75       on_exit 'ip link del ovs-$1'
  76     ]
  77 )
  78
  79 # ADD_VLAN([port], [namespace], [vlan-id], [ip-addr])
  80 #
  81 # Add a VLAN device named 'port' within 'namespace'. It will be configured
  82 # with the ID 'vlan-id' and the address 'ip-addr'.
  83 m4_define([ADD_VLAN],
  84     [ NS_CHECK_EXEC([$2], [ip link add link $1 name $1.$3 type vlan id $3])
  85       NS_CHECK_EXEC([$2], [ip link set dev $1.$3 up])
  86       NS_CHECK_EXEC([$2], [ip addr add dev $1.$3 $4])
  87     ]
  88 )
  89
  90 # ADD_OVS_TUNNEL([type], [bridge], [port], [remote-addr], [overlay-addr])
  91 #
  92 # Add an ovs-based tunnel device in the root namespace, with name 'port' and
  93 # type 'type'. The tunnel device will be configured as point-to-point with the
  94 # 'remote-addr' as the underlay address of the remote tunnel endpoint.
  95 #
  96 # 'port will be configured with the address 'overlay-addr'.
  97 #
  98 m4_define([ADD_OVS_TUNNEL],
  99    [AT_CHECK([ovs-vsctl add-port $2 $3 -- \
 100               set int $3 type=$1 options:remote_ip=$4])
 101     AT_CHECK([ip addr add dev $2 $5])
 102     AT_CHECK([ip link set dev $2 up])
 103     AT_CHECK([ip link set dev $2 mtu 1450])
 104     on_exit 'ip addr del dev $2 $5'
 105    ]
 106 )
 107
 108 # ADD_NATIVE_TUNNEL([type], [port], [namespace], [remote-addr], [overlay-addr],
 109 #                   [link-args])
 110 #
 111 # Add a native tunnel device within 'namespace', with name 'port' and type
 112 # 'type'. The tunnel device will be configured as point-to-point with the
 113 # 'remote-addr' as the underlay address of the remote tunnel endpoint (as
 114 # viewed from the perspective of that namespace).
 115 #
 116 # 'port' will be configured with the address 'overlay-addr'. 'link-args' is
 117 # made available so that additional arguments can be passed to "ip link",
 118 # for instance to configure the vxlan destination port.
 119 #
 120 m4_define([ADD_NATIVE_TUNNEL],
 121    [NS_CHECK_EXEC([$3], [ip link add dev $2 type $1 remote $4 $6])
 122     NS_CHECK_EXEC([$3], [ip addr add dev $2 $5])
 123     NS_CHECK_EXEC([$3], [ip link set dev $2 up])
 124     NS_CHECK_EXEC([$3], [ip link set dev $2 mtu 1450])
 125    ]
 126 )
 127
 128 # FORMAT_PING([])
 129 #
 130 # Strip variant pieces from ping output so the output can be reliably compared.
 131 #
 132 m4_define([FORMAT_PING], [grep "transmitted" | sed 's/time.*ms$/time 0ms/'])
 133
 134 # FORMAT_CT([ip-addr])
 135 #
 136 # Strip content from the piped input which would differ from test to test
 137 # and limit the output to the rows containing 'ip-addr'.
 138 #
 139 m4_define([FORMAT_CT],
 140     [[grep "dst=$1" | sed -e 's/port=[0-9]*/port=<cleared>/g' -e 's/id=[0-9]*/id=<cleared>/g' | sort | uniq]])
 141
 142 # NETNS_DAEMONIZE([namespace], [command], [pidfile])
 143 #
 144 # Run 'command' as a background process within 'namespace' and record its pid
 145 # to 'pidfile' to allow cleanup on exit.
 146 #
 147 m4_define([NETNS_DAEMONIZE],
 148    [ip netns exec $1 $2 & echo $! > $3
 149      echo "kill \`cat $3\`" >> cleanup
 150    ]
 151 )
 152
 153 # OVS_CHECK_VXLAN()
 154 #
 155 # Do basic check for vxlan functionality, skip the test if it's not there.
 156 m4_define([OVS_CHECK_VXLAN],
 157     [AT_SKIP_IF([! ip link add foo type vxlan help 2>&1 | grep dstport >/dev/null])])